DataMuseum.dk

top - metrics - download

    Length: 3456 (0xd80)
    Types: TextFile
    Names: »LISTE3.CMD«

└─⟦c252abf18⟧ Bits:30008917 RCTOAX RC TIME OG OMKOSTNINGS OVERSIGT ARBEJDSDISK
    └─⟦this⟧ »LISTE3.CMD« 

TextFile

*****************************************************************************
*    COMMANDO FILE TIL  RC TIME OG OMKOSTNINGS OVERSIGT                     *
*    NAVN : LISTE3.CMD  SIDST ÆNDRET    DATO: 86.02.24       KL..: 14.00    *
*    KALDES I START.CMD, T1.MEN OG T5.MEN                                   *
*****************************************************************************
SET TALK OFF
SET ESCAPE ON
STORE T TO LOK8
*
DO WHILE LOK8
   store ' ' to SVARS
   store '  ' to ok
   store '    ' to begyn
   store '    ' to til
   store '      ' to dagsdato
   erase
   text
          RC  TIME OG OMKOSTNINGS OVERSIGT                           LISTE 3

----------------------------------------------------------------------------

          PRODUKTLINIE OG TILHØRENDE PROJEKTER

----------------------------------------------------------------------------


          0  =  SLUT PÅ UDSKRIFT OG RETUR 

          3  =  SKRIV PRODUKTLINIENS PROJEKTER UD

          HVIS ALT ØNSKES SKREVET UD, SÅ TAST $$$$ I FRA KODE 2 & 6,
          MEN DET KAN BLIVE EN MEGET STOR LISTE !!!
          ELLERS TAST ØNSKET FRA-VÆRDI, EVT. FYLD OP MED $ ! 

----------------------------------------------------------------------------

endtext
@ 20,0 say 'vælg nummer   ' get SVARS
read
*
  if SVARS = '0'
     store F to LOK8
     loop
  endif 8.0
*
  if SVARS = '3'
     USE WPROTIME INDEX WKODPROJ
     go top
     @ 21,0 say 'tast fra kode 2 & 6  ' get begyn
     @ 22,0 say '     til kode 2 & 6  ' get til
     @ 22,40 say 'Kørselsdato ' get dagsdato
     @ 23,0 say 'TAST  OK, når printeren er klar (A4-høj)' get ok
     read
     if !(OK) <> 'OK'
        LOOP
     ENDIF
     store '  ' to ok
     if begyn = '$$$$'
        @ 23,0 say '- - - - - - - - - - - -   listen er på vej , vent - '
        do fside
        set console off
        set heading to    KØRSELSDATO : &dagsdato
        report form skrivpro to print
        do lside
        set console on
        loop
     endif
     *
     store '    ' to fra
     if $(begyn,4,1) = '$'
        store $(begyn,1,3) to fra
     endif
     if $(begyn,3,1) = '$'
        store $(begyn,1,2) to fra
     endif
     if $(begyn,2,1) = '$'
        store $(begyn,1,1) to fra
     endif
     if $(begyn,1,1) <> '$' .and. fra = '    '
        store begyn to fra
     endif
     *
     find '&fra'
     if # = 0
        @ 23,0 say '>>>    START NUMMER IKKE FUNDET ,   TAST RETUR   !!'
        set console off
        wait
        set console on
        loop
     endif
     @ 23,0 say '- - - - - - - - - - - -   listen er på vej , vent - '
     do fside
     set console off
     store 0 to fundne
     store T to sog
     do while sog
        if koder26 > '&til'
           store F to sog
           loop
        endif
        store fundne + 1 to fundne
        if eof
           store F to sog
           loop
        endif
        skip
        loop
     enddo
     find '&fra'
     set heading to     KØRSELSDATO : &dagsdato
     store "report form skrivpro next"+str(fundne,5)+" to print" to kom
     SET PRINT ON
     ? chr(29)
     &kom
     do lside
     set console on
     loop
  endif 8.3
enddo lok8
*
release lok8, svars, begyn, fra, til, dagsdato, sog
store '  ' to ok
return
«eof»