|
DataMuseum.dkPresents historical artifacts from the history of: RegneCentralen RC850 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about RegneCentralen RC850 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 8704 (0x2200)
Types: TextFile
Names: »LISTE1.CMD«
└─⟦c252abf18⟧ Bits:30008917 RCTOAX RC TIME OG OMKOSTNINGS OVERSIGT ARBEJDSDISK
└─⟦this⟧ »LISTE1.CMD«
*****************************************************************************
* COMMANDO FILE TIL RC TIME OG OMKOSTNINGS OVERSIGT *
* NAVN : LISTE1.CMD SIDST ÆNDRET DATO: 86.02.24 KL..: 09.15 *
* KALDES FRA START.CMD, T1.MEN OG T5.MEN *
*****************************************************************************
set talk off
set format to screen
store T to lok6
*
DO WHILE lok6
store ' ' to dagsdato
store ' ' to per
store ' ' to fra
store ' ' to til
store ' ' to gemkode2
store 'nej' to funk
store ' ' to ok
store ' ' to svars
erase
text
RC TIME OG OMKOSTNINGS OVERSIGT LISTE 1
----------------------------------------------------------------------------
OVERSIGT TIMER OG OMKOSTNINGER
----------------------------------------------------------------------------
0 = RETUR TIL HOVEDMENU
1 = OVERSIGTS LISTE FOR EN PERIODE (format: A4-høj)
HVIS ALT ØNSKES SKREVET UD, SÅ TAST $$ I FRA PROJEKTGRUPPE
----------------------------------------------------------------------------
endtext
@ 17,0 say '* TAST * nummer ......................... ' get svars
read
*
if svars='0'
store F to lok6
loop
endif 2.0
*
if svars <> '1'
loop
endif 2.1
*
@ 18,0 say ' ---- udskrifts dato ................. ' get dagsdato
@ 19,0 say ' ---- PERIODE ÅR OG MÅNED (ÅRMD) ..... ' get per
@ 20,0 say ' ---- FRA projektgruppekode 2 ........ ' get fra
@ 21,0 say ' ---- TIL projektgruppekode 2 ........ ' get til
@ 22,0 say ' ---- OK hvis printer er klar ....... ' get ok
read
if !(OK) <> 'OK'
loop
endif
store 'gout' + per to navn1
store 'gind' + per to navn2
store ' ' to ok
*
*******************************************************************************
*** HER STARTER UDSKRIFTEN ( funk er lig med nex ) ***
*******************************************************************************
*
if .not. file ('&navn1')
@ 22,0 say '>>>> periode ikke fundet ! TAST RETUR <<<< ' get ok
read
loop
endif
use &navn1 index &navn2
*
go top
if art = '0'
store STR(prim,8,1) to helpe
store $(helpe,3,4) to perbeg
endif
skip 1
*
store ' ' to ok
if '&fra' = '$$'
store '00' to fra
store '99' to til
endif
if '&fra' <> '00'
store '&fra' + '0' + '00' to nogle
find '&nogle'
if # = 0
@ 22,0 say ' >>>> FRA NUMMER IKKE FUNDET ! TAST RETUR <<<< ' get ok
read
loop
endif
endif
*
@ 22,0 say ' **** LISTEN ER PÅ VEJ , VENT ****'
SET CONSOLE OFF
do fside
store 99 to linie
set format to print
set print on
store 'nex' to funk
*
DO WHILE FUNK <> ' '
*
*******************************************************************************
*** funk = nex næste record læses ***
*******************************************************************************
if funk = 'nex'
if EOF
store 'END' to funk
loop
endif sidste record laest
*
if kode2 < '&fra'
skip
loop
endif kode2 mindre end start vaerdi
*
if kode2 > '&til'
store 'END' to funk
loop
endif kode2 storre end til vaerdi
*
if kode2 <> '&gemkode2'
store kode2 to gemkode2
store 1 to art
store 01 to linie
? CHR(30)
? chr(31)
@ linie,02 say 'RC TIME- OG OMKOSTNINGS OVERSIGT'
store linie + 2 to linie
? chr(29)
@ linie,05 say 'LISTE 1'
@ linie,21 say 'TOTALT TIMEFORBRUG PÅ AKTUELLE PROJEKTER'
@ linie,86 say 'FOR PERIODE'
@ linie,100 say 'ÅR/MÅNED:'
@ linie,117 say perbeg using 'XXXX'
store linie + 2 to linie
@ linie,05 say 'PROJEKTGRUPPE KODE2 :'
@ linie,47 say kode2 using 'XX'
@ linie,51 say tekst using 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ linie,100 say 'DATO'
@ linie,115 say dagsdato using 'XXXXXX'
store linie + 2 to linie
@ linie,47 say '* - - - - - - - - -'
@ linie,75 say ' T I M E R '
@ linie,93 say '- - - - - - - - - *'
store linie + 1 to linie
@ linie,05 say 'K6 PROJEKTNR. & NAVN'
@ linie,56 say 'PRIMO'
@ linie,69 say 'PERIODE'
@ linie,85 say 'ULTIMO'
@ linie,100 say 'B.REST'
@ linie,117 say 'PLAN'
store linie + 3 to linie
skip
loop
endif kode2 ej gammel kode2
*
if linie > 64
eject
store 02 to linie
@ linie,05 say 'RC TIME- OG OMKOSTNINGS OVERSIGT'
@ linie,80 say '--- forsat fra forrige side ---'
store linie + 2 to linie
endif side 2
*
if art = '1'
if kode6 = '999'
@ linie,47 say '--------------------------------------'
@ linie,85 say '------------------------------------'
store linie + 1 to linie
@ linie,09 say tekst using 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ linie,53 say prim
@ linie,68 say peri
@ linie,83 say ulti
@ linie,98 say rest
@ linie,113 say plan
store linie + 1 to linie
@ linie,47 say '======================================'
@ linie,85 say '===================================='
store linie + 2 to linie
@ linie,47 say '* - O M K O S T N I N G E R 1000 KR. '
@ linie,85 say ' I N D E V Æ R E N D E Å R - - *'
store linie + 1 to linie
@ linie,05 say 'GR TEKST'
@ linie,56 say 'PRIMO'
@ linie,69 say 'PERIODE'
@ linie,85 say 'ULTIMO'
@ linie,96 say 'PER. BUDG.'
@ linie,111 say 'REST BUDG.'
store linie + 3 to linie
skip
loop
endif total linie for timer
if kode6 <> '999'
@ linie,05 say kode6 using 'XX'
@ linie,09 say tekst using 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ linie,53 say prim
@ linie,68 say peri
@ linie,83 say ulti
@ linie,98 say rest
@ linie,113 say plan
store linie + 2 to linie
skip
loop
endif almindelig detaillinie timer
endif art 1 timer
if art = '2'
if kode6 = '50'
@ linie,47 say '--------------------------------------'
@ linie,85 say '------------------------------------'
store linie + 1 to linie
@ linie,09 say tekst using 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ linie,54 say int(prim)
@ linie,69 say int(peri)
@ linie,84 say int(ulti)
@ linie,99 say int(plan)
@ linie,114 say int(rest)
store linie + 1 to linie
@ linie,47 say '======================================'
@ linie,85 say '===================================='
store linie + 2 to linie
skip
loop
endif total linie kroner omkostningsgrupper 40 til 48
if kode6 <> '50'
@ linie,05 say kode6 using 'XX'
@ linie,09 say tekst using 'XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX'
@ linie,54 say int(prim)
@ linie,69 say int(peri)
@ linie,84 say int(ulti)
@ linie,99 say int(plan)
@ linie,114 say int(rest)
store linie + 2 to linie
skip
loop
endif investerings kroner
endif art 2
endif nex
*
*******************************************************************************
*** funk = end slut på liste ***
*******************************************************************************
if funk = 'END'
? chr(30)
eject
set print off
set format to screen
do lside
SET CONSOLE ON
@ 22,0 say ' **** LISTEN ER FÆRDIG ----->> TAST RETUR !!' get ok
read
store ' ' to funk
loop
endif end
*
ENDDO FUNK
*
ENDDO lok6
*
erase
release lok6, svars, fra, til, dagsdato, gemkode2, nogle, funk, linie
release navn1, navn2, per, perbeg, helpe
store ' ' to ok
RETURN
«eof»