DataMuseum.dk

top - metrics - download

    Length: 3584 (0xe00)
    Types: TextFile
    Names: »EXTTOINT.CMD«

└─⟦9c8e44efc⟧ Bits:30005957 Std. Rammesystem
    └─⟦this⟧ »EXTTOINT.CMD« 

TextFile

*exttoint
* formål : ajourføring af ENKELT-BRUGER-SYSTEM register (INTERN FIL) med en ny
*          extern register-version fra f.eks. RC8000.
* regel  : Den interne fil /register består af 2 gruppe felter. EEN feltgruppe
*          der er fælles med den eksterne fil's og en ANDEN, der kun eksisterer
*          i ENKELT-BRUGER-SYSTEMet's fil.
*          Det forudsættes, at feltgruppe 1 vedligeholdelse via værts-systemet
*          f.eks. RC8000 og feltgruppe 2 vedligeholdes på mikro-systemet.
*          Derfor "rettes" feltgruppe 1 i mikro-systemets record med sammen-
*          faldende record (key) fra værtssystemet.
*          Nye record fra værtssystemet tilføjes ligesom "gamle" uberørte
*          record i mikro-systemet "lever" videre, idet evt. sletning heraf
*          skal ske i mikro-systemet.
* Der er således tale om en ENKELT-BRUGER-SYSTEM bruger, der af og til får et
* ajourført register over i sit system, kombineret med egne data.
* fil-overførslen kan evt. ske via ACP. Det forventes udført inden programmet
* starter - filnavnet kan evt. være EXTFIL.TXT
*------------------------------------------------------------------------------
erase

* nu åbnes INTERN FIL
use kunder
* der dannes en tom fil med samme felt-beskrivelse (STRUCTUR) som intern fil
copy to extfil struc

* den nydannede tomme fil åbnes
use extfil
? 'nu indlæses extern fil..'
append from extfil.txt sdf deli

* den interne fil (med det gamle register) åbnes med index
use kunder index kunder
? 'nu, opdateres intern fil med extern fils felter...'
update from extfil on knr;
       replace navn with navn
* svarer til tidligere omtalte feltgruppe 1

* den interne fils feltgruppe 1 ER nu ajourført, men evt. nye record i extern
* fil mangler at blive overført, det sker IKKE med update-kommandoen.

* den externe fil åbnes og der etableres en index-fil
use extfil
index on knr to extfil

? 'nu, opdateres extern fil med intern fils egne felter ...'

update from kunder on knr;
       replace grp with grp

* record, der både findes i intern fil og extern fil er nu gjort ens.
* for at få glæde af evt. tilkomne record i den externe fil udfører vi et lille
* tricks, idet vi overfører alle record fra den interne fil til den externe og
* senere komprimerer vi den externe fil og danner en ny intern fil. Sådan!

? 'og nu indlægges de interne record i extern fil ..'

append from kunder

? 'nu komprimeres record på key-niveau og skrives i ny intern fil ...'

total to nykunder on knr

use nykunder
index on knr to nykunder

? 'Så er dit register nu ajourført ..'
? 'vi lister lige de ny-tilkomne record ..'
accept 'Skal de udskrives på printer ? (J/N) ' to svar
if !(svar)='J'
   accept '... tast return, når printeren er klar .. ' to svar
   if len(svar)>0
      set print on
   else
      set print off
   endif
endif
list for grp='   '
? '------------------------------------------'
accept 'Er du tilfreds med resultatet, så tast J, ellers return ' to svar
if !(svar)='J'
   use
   delete file kunder.dbf
   delete file kunder.ndx
   rename nykunder.dbf to kunder.dbf
   rename nykunder.ndx to kunder.ndx
else
? 'Javel så, men så kan du køre programmet igen, når du har udført rettelsen..'
endif

«eof»