DataMuseum.dk

top - metrics - download

    Length: 6144 (0x1800)
    Types: TextFile
    Names: »SYSINIT.CMD«

└─⟦9c8e44efc⟧ Bits:30005957 Std. Rammesystem
    └─⟦this⟧ »SYSINIT.CMD« 
└─⟦ae6bd3087⟧ Bits:30005879 RC Register-system generering
    └─⟦this⟧ »SYSINIT.CMD« 

TextFile

* SYSINIT.CMD
RELEASE ALL
ERASE
? 'RC                   BRUGER-SERVICE-CENTER               EDB-AFDELINGEN'
? '                   *** SYSTEMGENERERING ***'
SET TALK OFF
set intensity off
IF .NOT. FILE('PANELOPR.DBF')
   ? 'FILEN PANELOPR.DBF MGL.           DEFINER FELT : LINIE,C,80'
   CREATE PANELOPR
   ERASE
ENDIF
USE PANELOPR
DELETE ALL
PACK
STORE '                    ' TO XSYSNAVN
store '          ' to feltnavn
store ' ' to XPICT
STORE ' ' TO XKEYLGD
store 1 to LGD
?
?
@ 10,1 SAY 'HVAD HEDDER DIT SYSTEM ? ' GET XSYSNAVN PICT '!!!!!!!!!!!!!!!!!!!!'
READ
erase
?
? 'Nu skal du beskrive alle dine register-/kartoteks-felter ....'
? 'Det kaldes også en STRUCTUR.'
? 'Først giver du feltet et navn (max 10 bogstaver), herefter en TYPE ..'
? 'Felter, der ikke skal indgå i beregninger/summer o.l. skal have TYPE C'
? 'Felter, der skal indgå i beregninger skal have TYPE N og kan suppleres'
? 'med et antal decimaler'
? 'Længden på feltet, dvs antal tegn feltet kan rumme ved f.eks. indtastning'
? 'angives efter TYPE. Kaldes også WIDTH'
? 'Når du har beskrevet alle nødvendige felter, taster du blot return .. så'
? 'er dit register beskrevet. OK så går vi igang..'
? 'BEMÆRK, at når structuren ER færdig, spørges der om INPUT DATA NOW?'
? 'men du taster blot return'
? '(brug aldrig æ,ø,å i feltnavnet !! det giver fejl !!)'
create register
? '--------------------------------------------------------------------------'
? 'Ok - det varer et øjeblik....'
USE REGISTER
COPY TO WORKFIL STRUCTURE EXTENDED
USE WORKFIL
STORE ' ' TO FELTER
DO WHILE .NOT. EOF
   STORE FELTER+FIELD:NAME TO FELTER
   SKIP
ENDDO
STORE $(FELTER,2,10) TO FELTNAVN
GOTO top
STORE FIELD:LEN to LGD
STORE 0 TO LOOP
DO WHILE LOOP<=LGD
    STORE LOOP+1 TO LOOP
    STORE '!'+XPICT TO XPICT
    STORE ' '+XKEYLGD TO XKEYLGD
ENDDO
STORE $(XKEYLGD,1,LGD) TO XKEYLGD
STORE "'"+$(XPICT,1,LGD)+"'" TO XPICT
store trim(feltnavn) to feltnavn
STORE FELTNAVN TO XFELTNAVN
store "'Tast &feltnavn ' get XKEY PICT &XPICT" to XPROMT1
STORE "REGISTER INDEX REGISTER" TO XFILNAVN
STORE '&FELTNAVN'+'=XKEY' TO XKEYINFO
STORE '&FELTNAVN'+' WITH XKEY' TO XKEYINFO2
? 'NU dannes skærmbilled for VIS-funktionen ....'
set console off
USE REGISTER
INDEX ON &FELTNAVN TO REGISTER
USE PANELOPR
DELETE ALL
PACK
STORE "@ 0,0 SAY 'RC                          REGISTER-SYSTEM'" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE "@ 2,25 SAY CHR(133)+'&XSYSNAVN'+CHR(128)" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE 1 TO LOOP
DO WHILE LOOP<=INT(LEN(FELTER)/10) .OR. LOOP>13
   APPEND BLANK
   STORE STR(LOOP+3,2) TO LINENO
   STORE $(FELTER,INT(LOOP*10)-9,10) TO FELT
   STORE "@ &LINENO,0 SAY '&FELT  :'" TO PANLINE
   IF @(FELTNAVN,trim(FELT))<>0
      STORE PANLINE+"+XKEY" TO PANLINE
   ELSE
      REPLACE LINIE WITH PANLINE
      APPEND BLANK
      STORE "@ &LINENO,13 SAY &FELT" TO PANLINE
   ENDIF
   REPLACE LINIE WITH PANLINE
   STORE LOOP+1 TO LOOP
ENDDO
STORE "@ 18,0 SAY " TO PANLINE
store panline+;
"'Funktions-valg O(pret), R(et), S(let), V(is), H(op til menu) '" to panline
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE "@ 18,63  GET XFUNK PICT '!'" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE "@ 20,0 SAY XMSG" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
GOTO TOP
SET ALTERNATE TO GEPANVIS.FMT
SET ALTERNATE ON
LIST OFF
SET ALTERNATE TO
SET ALTERNATE OFF
set console on
? 'Og nu dannes skærmbilled for OPRET/RET ...'
set console off
DELETE ALL
PACK
STORE "@ 0,0 SAY 'RC                          REGISTER-SYSTEM'" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE "@ 2,25 SAY CHR(133)+'&XSYSNAVN'+CHR(128)" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE 1 TO LOOP
DO WHILE LOOP<=INT(LEN(FELTER)/10) .OR. LOOP>13
   APPEND BLANK
   STORE STR(LOOP+3,2) TO LINENO
   STORE $(FELTER,INT(LOOP*10)-9,10) TO FELT
   STORE "@ &LINENO,0 SAY '&FELT   '" TO PANLINE
   IF @(FELTNAVN,trim(FELT))<>0
      STORE PANLINE+'+XKEY' TO PANLINE
   ELSE
      REPLACE LINIE WITH PANLINE
      APPEND BLANK
      STORE "@ &LINENO,13 GET &FELT" TO PANLINE
   ENDIF
   REPLACE LINIE WITH PANLINE
   STORE LOOP+1 TO LOOP
ENDDO
STORE "@ 18,0 SAY " TO PANLINE
store panline+;
"'Funktions-valg O(pret), R(et), S(let), V(is), H(op til menu) '" to panline
APPEND BLANK
REPLACE LINIE WITH PANLINE
STORE "@ 18,63  GET XFUNK PICT '!'" TO PANLINE
APPEND BLANK
REPLACE LINIE WITH PANLINE
GOTO TOP
SET ALTERNATE TO GEPANOPR.FMT
SET ALTERNATE ON
LIST OFF
SET ALTERNATE TO
SET ALTERNATE OFF
set console on
erase
USE REGISTER INDEX REGISTER
DELETE ALL
PACK
? 'Du kan nu danne 2 LISTER  ..'
if  file('LISTE1.FRM')
   delete file LISTE1.FRM
ENDIF
IF FILE('LISTE2.FRM')
   DELETE FILE LISTE2.FRM
ENDIF
? 'Følgende felter er tilgængelige ved dannelse af listerne : '
? '--------------------------------------------------------------------------'
LIST STRUC
? '--------------------------------------------------------------------------'
STORE '                    ' TO XRAP1,XRAP2
ACCEPT 'LISTE 1 skal hedde ?' TO XRAP1
? 'FOR SKÆRM-UDSKRIFT .. Tast M=1,L=22,W=79'
? 'FOR PAPIR-UDSKRIFT .. Tast M=1,L=62,W=72'
REPORT FORM LISTE1
? '----------------------'
ERASE
list struc
? '----------------------'
ACCEPT 'LISTE 2 skal hedde ?' TO XRAP2
? 'FOR SKÆRM-UDSKRIFT .. Tast M=1,L=22,W=79'
? 'FOR PAPIR-UDSKRIFT .. Tast M=1,L=62,W=72'
REPORT FORM LISTE2
* HUSK VEJLEDNING
ERASE
STORE '     ' TO XPASSWORD
ACCEPT 'Tast den IDENT (PASSWORD), der skal give adgang til DIT system';
       to XPASSWORD
ERASE
? '**************'
? '* TILLYKKE   *'
? '* MED DIT NYE*'
? '* SYSTEM     *'
? '**************'
? 'senere ..'
? 'ændringer eller udvidelse af dit system, kan udføres efter aftale med'
? 'EDB-afdelingens  BRUGER-SERVICE-CENTER'
SAVE TO SYSFIL ALL LIKE X*
store ' ' to igang
DELETE FILE WORKFIL.DBF
ACCEPT 'Tast enter for at fortsætte ...' to igang
ERASE
return

«eof»