DataMuseum.dk

top - metrics - download

    Length: 5632 (0x1600)
    Types: TextFile
    Names: »VEDLIG.CMD«

└─⟦871340d2f⟧ Bits:30005949 RC Organisationsplan Diskette A 15/01-86
    └─⟦this⟧ »VEDLIG.CMD« 

TextFile

*****************************************************************************
*    COMMANDO FILE TIL  RC    ORGANISATIONS PLAN                            *
*    NAVN : VEDLIG.CMD    SIDST ÆNDRET DATO: 86.01.07   KL..: 14.40         *
*    KALDES FRA START.CMD VIA O1.MEN OG O2.MEN                              *
*****************************************************************************
USE
set escape on
store '  ' to ok
set talk off
use
erase
? ' ***   RC    ORGANISATIONS PLAN              VEDLIGEHOLD    O 2   ***'
? ' --------------------------------------------------------------------'
? ' ***   nulstiller IKKE afdelings oplysninger som i OPDAT          ***'
? ' '
? ' 1. SKAL DER VEDLIGEHOLDES UD FRA BESTÅENDE REGISTRE   ?'
accept '     SÅ TAST  OK  ELLER  FORTRYD  SÅ RETUR  ........... ' to ok
if !(OK) <> 'OK'
    erase
    return
endif
*
store '  ' to ok
? ' '
? '    Er PRINTEREN klar ?  Skal anvendes i dette program !'
accept '     SÅ TAST  OK  ELLER  FORTRYD  SÅ RETUR  ........... ' to ok
if !(OK) <> 'OK'
    erase
    return
endif
*
store '  ' to ok
? ' '
*
? ' 2. DE GAMLE REGISTRE SKAL NULSTILLES          ,  VENT !'
set talk on
? ' '
? '    2  FILER SKAL SLETTES   ( DELETES )              '
? ' '
DELETE FILE AFDTOT.NDX
*
use AFDTOT
copy to aftowork structure
use
delete file AFDTOT
rename aftowork to AFDTOT
use AFDTOT
*
? ' '
? ' 3. OG SÅ TOTAL PÅ AFDELINGS-NR I AFDTOT       ,  VENT !'
? ' '
use med index med
total on afnu to afdtot fields afnu, sted
? ' '
? '    LAV INDEX PÅ AFDELINGS-NR I AFDTOT         ,  VENT !'
? ' '
use afdtot
index on afnu to afdtot
? ' '
set talk off
? ' '
? ' 4. VEDLIGEHOLD AF ORGANISATIONS DATABASE      ,  VENT !'
? ' '
? ' 4A. FØRST SLETTES AFGÅEDE AFDELINGER          ,  VENT !'
? ' '
* STYR er en variabel, som hvis første position i org.afnu er blankt = ja
*                      og hvis første position i org.afnu ej er blankt = no
use org index org
go top
store afnu to nogle
store 'no' to styr
if $(afnu,1,1) = ' '
   store 'ja' to styr
   store difok + 1 to difok
endif
store 1 to diflast
store 0 to difok
store 0 to difslet
store F to slet
store T to nif
set print on
DO WHILE NIF
use afdtot index afdtot
find '&nogle'
 if # = 0
    if styr = 'no'
       store T to slet
    endif
 else
    store difok + 1 to difok
 endif
*
use org index org
find '&nogle'
 if # = 0
    ? ' '
    ? ' antal læste    afdelinger  ............... '      , diflast
    ? ' antal uændrede afdelinger  ............... '      , difok
    ? ' antal slettede afdelinger  ............... '      , difslet
    ? ' >>> FEJL  ved næste læs af ORG...........  tast retur '
    ? ' '
    wait
    store F to nif
    return
 endif
 if slet
    ? ' slettet afdelings nummer ................. '      , nogle
    DELETE
    store difslet + 1 to difslet
    store F to slet
 endif slet
 skip 1
 if eof 
    store F to nif
    ? ' '
    ? ' antal læste    afdelinger  ............... '      , diflast
    ? ' antal uændrede afdelinger  ............... '      , difok
    ? ' antal slettede afdelinger  ............... '      , difslet
    ? ' '
 endif eof
 store diflast + 1 to diflast
 store afnu to nogle
 store 'no' to styr
 if $(afnu,1,1) = ' '
    store 'ja' to styr
    store difok + 1 to difok
 endif
loop
enddo nif
set print off
if difslet <> 0
   set talk on
   ? ' '
   ? ' 4B.    SLETTEDE AFDELINGER FJERNES         ,  VENT !'
   ? ' '
   use org index org
   pack
   set talk off
   ? ' '
endif difslet
? ' '
? ' 5. SÅ OPRETTES NYE AFDELINGER                 ,  VENT !'
? ' '
use afdtot index afdtot
go top
store afnu to nogle
store sted to wsted
store 1 to diflast
store 0 to difok
store 0 to difny
store T to nif
set print on
DO WHILE NIF
use org index org
find '&nogle'
 if # = 0
    append blank
    replace afnu with nogle
    replace sted with wsted
    replace navn with '     '
    replace chef with '     '
    replace over with 'NY'
    ? ' afdelings nummer oprettet  ............... '      , nogle
    store difny + 1 to difny
 else
   if sted <> wsted
      replace sted with wsted
   endif sted
   store difok + 1 to difok
 endif
*
use afdtot index afdtot
find '&nogle'
 if # = 0
    ? ' '
    ? ' antal læste afdelinger  .................. '      , diflast
    ? ' antal ok    afdelinger  .................. '      , difok
    ? ' antal nye   afdelinger  .................. '      , difny
    ? ' >>> FEJL  ved næste læs af AFDTOT  ......  tast retur '
    ? ' '
    wait
    store F to nif
    return
 endif
 skip 1
 if eof 
    store F to nif
    ? ' '
    ? ' antal læste afdelinger  .................. '      , diflast
    ? ' antal ok    afdelinger  .................. '      , difok
    ? ' antal nye   afdelinger  .................. '      , difny
    ? ' '
 endif eof
 store diflast + 1 to diflast
 store afnu to nogle
 store sted to wsted
loop
enddo nif
set print off
release nogle, slet, nif, diflast, difok, difslet, difny, wsted, styr
set talk off
*
? ' '
? ' 7. SLUT VEDLIGEHOLD  RC ORGANISATIONS  PLAN          '
? '    HUSK AT AJOURFØRE AFDELINGS OPLYSNINGER, NYE AF- !'
? '    DELINGER ER MARKERET MED ORDET NY I OVERORDNET,  !'
? '    SAMT FUNKTION 3 PÅ SKÆRMBILLEDE O 2 SKAL UDFØRES !'
? '                                            TAST RETUR'
? ' -----------------------------------------------------'
set console off
wait
set console on
set escape off
store '  ' to ok
return
«eof»