DataMuseum.dk

top - metrics - download

    Length: 6656 (0x1a00)
    Types: TextFile
    Names: »GESTART.CMD«

└─⟦07be67046⟧ Bits:30008916 LINDA1 75MC
    └─⟦this⟧ »GESTART.CMD« 

TextFile

* 0.BEGIN.PROGRAM
*------------------------------------------------------------------------------
* PROGRAM       :  GESTART.CMD    V.0
* UDARBEJDET AF :  John Knudsen, Juni 1984
* FUNKTION      :
*                  Generelt dBASE II program, der skal understøtte udvikling
*                  af mindre STAND ALONE systemer for informationssøgning/-
*                  behandling.
*                  Systemet består af :
*                           Hovedmenu  for valg af Registervedligeholdelse
*                                                  Udskrivning
*                                                  Vejledning
*                           De valgte menu-dele vil efter udførelse vende
*                           tilbage til hovedmenu.
*
*                   Systemet baseres på een bruger-data-fil, der forudsættes
*                   indexeret a.h.t. til søgning.
*                   Udskrivnings-delen kan for så vidt godt skrædersyes helt
*                   til bruger-opgaven for såvel menu-billedet for valg af
*                   lister, som for disses evt. særlige forberedelse - her
*                   tænkes på etablering af styrende index pr. liste og for
*                   valg af særlige udskrifts(selekt)-betingelser.
*
*                   Alle record-felter, som ikke indgår i beregning, totaler
*                   forventes(skal) af typen C (karakterer) også key-felt(er).
*
*                   For at få brugerens system til at starte automatisk, når
*                   disketten loades - køres CP/M programmet AUTOEXEC.
*                   Der angives DBASE GESTART.
*
* VARIABEL-OVERSIGT :
*                   STYRE-VARIABLER OG IKKE BRUGER-AFHÆNGIGE VARIABLER:
*                   XALTID, XFUNK, XKEY, XLIN0, XLIN2, XLIN18, XLISTE
*                   XLOOP, XMSG, , XNOTOK, XPOS, XRECNR, XVALG
*
*                   VARIABLER, DER FÅR TILFØRT BRUGER-SYSTEM ORIENTEREDE VÆRDI
*                   XFILNAVN, XKEYINFO, XKEYINFO2, XKEYLGD, XPROMT1, XSYSNAVN
*
*                   VARIABLER, DER INITIERES UDFRA BRUGER-DATAFILENS RECORD-
*                   BESKRIVELSE
*                   XNAVN, XPERIODE, XSALDO
*
* FIL-OVERSIGT :    SYSTEMETS FILER (SKAL IKKE ÆNDRES I F.M. BRUGERSYSTEM)
*                   GESTART.CMD      .. HOVEDMENU
*                   REGVEDLH.CMD     .. REGISTER-BEHANDLING. OPRET/RET/VIS/SLET
*
*                   ØVRIGE FILER, DER TILRETTES ALT AFHÆNGIGT AF AKTUELT BRUGER
*                   SYSTEM
*                   BRINIT.CMD       .. GLOBALE BRUGER-VARIABLER
*                   DEMO1.FRM        .. LISTE1-TRIMNING
*                   DEMO2.FRM        .. LISTE2-TRIMNING
*                   DEMOREG.DBF      .. BRUGER-SYSTEMETS DATA.FIL
*                   FELTFLYT.CMD     .. RECORDFELTER TIL X_VARIABLER
*                   GEPANOPR.FMT     .. OPRET/RET SKÆRMBILLED
*                   GEPANVIS.FMT     .. VIS SKÆRMBILLED
*                   KONTONR.NDX      .. INDEX FIL TIL DEMOREG.DBF
*                   UDSKRIV.CMD      .. LISTE-MENU
*                   VEJLED.CMD       .. DISPLAYER BRUGER-TILPASSET VEJLEDNING
*------------------------------------------------------------------------------
* INITIERING *
*------------------------------------------------------------------------------
CLEAR
ERASE
*initiering af start parametrer og brugerfil m.m.
*------------------------------------------------
* PARAMETRER:
*-------------------
SET ALTERNATE OFF
SET BELL ON
SET CARRY OFF
SET COLON ON
SET CONFIRM OFF
SET CONSOLE ON
SET DEBUG OFF
SET DELETE ON
SET ECHO OFF
SET EJECT OFF
SET ESCAPE OFF
SET EXACT OFF
SET INTENSITY OFF
SET LINKAGE OFF
SET PRINT OFF
SET RAW OFF
SET STEP OFF
SET TALK OFF
*-------------------
* INITIERING AF SYSTEMETS GLOBALE MEMORY VARIABLE
*-------------------------------------------------
STORE "@ 0,0 SAY 'RC                             REGISTER-SYSTEM'" TO XLIN0
STORE "@ 2,30 SAY CHR(133)+XSYSNAVN+CHR(128)" TO XLIN2
STORE "'Funktions-valg O(pret), R(et), S(let), V(is), " TO XLIN18
STORE XLIN18+"H(op til menu) ' GET XFUNK PICTURE '!'" TO XLIN18
STORE "@ 18,0 SAY "+XLIN18 TO XLIN18
*--------------------------------------
* INITIERE BRUGER-ORIENTEREDE VARIABLE
DO BRINIT
IF FILE(XFILNAVN)
   USE &XFILNAVN
ELSE
   ERASE
   ? 'BRUGERENS DATAFIL EKSISTERER IKKE .. UNDERSØG DET NÆRMERE ...'
   ? '*** VI STOPPER HER ***'
   ? 'FILNAVNET VAR : '+XFILNAVN
   QUIT
ENDIF
*------------------------------------------------------------------------------
* 1.BEGIN.HOVEDMENU
*------------------------------------------------------------------------------
* H O V E D M E N U
*------------------------------------------------------------------------------
STORE T TO XALTID
DO WHILE XALTID

  STORE ' ' TO XVALG
  STORE 15 TO xpos
  &XLIN0
  &XLIN2
  @ 10,xpos SAY '1.   Register-vedligeholdelse (Opret,Ret,Slet,Vis)'
  @ 12,xpos SAY '2.   Udskriv lister'
  @ 14,xpos SAY '3.   Vejledning'

  STORE T TO XNOTOK
  DO WHILE XNOTOK

    STORE F TO XNOTOK
    @ 20,50   SAY 'MENU-VALG ' GET XVALG PICTURE 'X'
    READ

    IF @(XVALG,'0123')=0
       @ 24,0 SAY '*** UKENDT MENUVALG, - prøv igen'+CHR(7)
       STORE T TO XNOTOK
    ENDIF
  ENDDO

  IF XVALG = '0'
     CLEAR
     ERASE
     @ 12,20 SAY CHR(172)+' OK, VI STOPPER HER - FARVEL OG TAK'+CHR(128)
     ACCEPT '' TO XVALG
     QUIT TO 'DO GESTART'
  ENDIF

*2./BEGIN.VEJLEDNING
*------------------------------------------------------------------------------
  IF XVALG = '3'
     DO VEJLED
  ENDIF
*2. END.VEJLEDNING
*------------------------------------------------------------------------------

*2./BEGIN.REGISTERVEDLIGEHOLDELSE
*------------------------------------------------------------------------------
  IF XVALG = '1'
     DO REGVEDLH
  ENDIF
*2. END.REGISTERVEDLIGEHOLDELSE
*------------------------------------------------------------------------------

*2./BEGIN.UDSKRIVNING
*------------------------------------------------------------------------------
  IF XVALG = '2'
     DO UDSKRIV
  ENDIF
*2. END.UDSKRIVNING
*------------------------------------------------------------------------------

  ERASE
  LOOP
ENDDO
*
*1.END.HOVEDMENU
*------------------------------------------------------------------------------
*0.END.PROGRAM
*------------------------------------------------------------------------------

«eof»