|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/36 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/36 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 22272 (0x5700)
Notes: MEMBER_P, Member_Text
Names: »MIGRATE «
└─⟦c8ae05145⟧ Bits:30009820 AS/ENTRY - S/36 SYST SUPP PROG IDENT. S/36 PTFDK3900 FC 1991/9074/9084 Refer to Memo 36714 Product Number 5727SS6 Rel 05 5 Created 19950301 Level 01 Seq 001 of 011
└─⟦9496929ef⟧
└─⟦this⟧ ».MIGRATE «
// LIBRARY NAME-#MYLIB
*
* SET UP THE MESSAGE MEMBERS
*
// MEMBER USER1-#MY#1MSG,PROGRAM1-#MY#1MSG,LIBRARY-#MYLIB
// MEMBER USER2-#MY#2MSG,PROGRAM2-#MY#2MSG,LIBRARY-#MYLIB
*
* INITIALIZE THE SYSTEM LOCAL DATA AREA
*
* PUT MIGRATE INTO THE FIRST 8 BYTES OF LDA
// LOCAL AREA-SYSTEM,OFFSET-1,DATA-'MIGRATE',BLANK-8
* PUT THE USER ID IN THE LDA
// LOCAL AREA-SYSTEM,OFFSET-327,DATA-'?USER?',BLANK-8
* PUT THE DEFAULT AUDIT FILE NAME IN THE LDA
// LOCAL AREA-SYSTEM,OFFSET-117,DATA-'$MYAUD',BLANK-8
*
* ERROR CHECK 1ST PARM AND ROUTE TO PROPER ROUTINE
*
// IF ?1?/EXPORT GOTO EXPORT
// IF ?1?/CREATE GOTO CREATE
// IF ?1?/SELECT GOTO SELECT
// IF ?1?/ANALYZE GOTO ANALYZE
// IF ?1?/SAVE36 GOTO SAVE36
// IF ?1?/REPORT GOTO REPORTS
// IF ?1?/ GOTO MENU
*
* PARM 1 IS BAD, ISSUE ERROR MESSAGE
*
BADPARM MIGRATE,01
// RETURN
*
* IF PARM 1 IS BLANK, PUT UP MAIN MENU SCREEN
*
// TAG MENU
// LIBRARY NAME-#MYLIB,SESSION-YES
// IFF DSPLY-IGC MENU MYM001
// IF DSPLY-IGC MENU MYD001
// RETURN
*
***********************************************************************
* MIGRATE CREATE *
***********************************************************************
*
// TAG CREATE
*
* MAKE SURE USER ENTERED A SELECTION FILE NAME
// IF ?2?/ #ERR 1512,3,MIGR
*
* PUT SELECTION FILE NAME IS THE LDA
// LOCAL AREA-SYSTEM,OFFSET-101,DATA-'?2?',BLANK-8
*
* MAKE SURE THE SELECTION FILE DOES NOT START WITH $MY
// IF ?L'101,3'?=$MY #ERR 1501,3,MIGR,?2?
*
* CHECK IF SELECTION FILE EXISTS, IT SHOULD NOT
// IF DATAF1-?2? #ERR 1510,3,MIGR,?2?
*
* USE BLDFILE PROC TO CREATE SELECTION FILE
*
BLDFILE ?2?,I,R,?4'80'?,32,,,1,9,,DUPKEY,80
*
* PUT MIGRATION RUN DESCRIPTION IN LDA
// LOCAL AREA-SYSTEM,OFFSET-125,DATA-'?3?',BLANK-40
*
* SET UP #MYCR OPCODE (MYLDCUOP) TO CREATE A NEW SELECTION FILE
* MYLDCUOP = MYLDCRET
// LOCAL AREA-SYSTEM,OFFSET-239,DATA-'1'
*
* CALL SELECTION FILE UPDATE PROGRAM TO WRITE HEADER RECORDS
// LOAD #MYCR,#MYLIB
// FILE NAME-SELECT,LABEL-?2?,DISP-OLD
// RUN
// RETURN
*
***********************************************************************
* MIGRATE SELECT *
***********************************************************************
*
// TAG SELECT
*
// LOCAL AREA-SYSTEM,OFFSET-1,DATA-'MIGRATE',BLANK-512
// LOCAL AREA-SYSTEM,OFFSET-117,DATA-'$MYAUD',BLANK-8
// LOCAL AREA-SYSTEM,OFFSET-327,DATA-'?USER?',BLANK-8
*
* MAKE SURE USER ENTERED A SELECTION FILE NAME
// IF ?8?/ #ERR 1512,3,MIGR
*
* PUT SELECTION FILE NAME IS THE LDA
// LOCAL AREA-SYSTEM,OFFSET-101,DATA-'?8?',BLANK-8
*
* MAKE SURE THE SELECTION FILE DOES NOT START WITH $MY
// IF ?L'101,3'?=$MY #ERR 1501,3,MIGR,?8?
*
* CHECK IF SELECTION FILE EXISTS, IT SHOULD
// IFF DATAF1-?8? #ERR 1511,3,MIGR,?8?
*
* ERROR CHECK PARM 2
*
// IFF ?2?/ IFF ?2?/ALL IFF ?2?/LIBRARY IFF ?2?/FILE IFF ?2?/USER GOTO SL2MORE1
// GOTO SLCHK5
*
// TAG SL2MORE1
// IFF ?2?/FOLDER IFF ?2?/SPELDICT IFF ?2?/DATADICT IFF ?2?/NRD GOTO SL2MORE2
// GOTO SLCHK5
*
// TAG SL2MORE2
// IFF ?2?/MASTER BADPARM SELECT,2
*
* ERROR CHECK PARM 5
*
// TAG SLCHK5
// IFF ?5?/ IFF ?5?/DATA IFF ?5?/FCT IFF ?5?/STREAM GOTO SL5MORE
// GOTO SLCOMBO
*
// TAG SL5MORE
// IFF ?5?/UNFORMAT IFF ?5?/BGUGDIF IFF ?5?/APF BADPARM SELECT,5
*
* ERROR CHECK FOR ILLEGAL COMBINATIONS
*
// TAG SLCOMBO
// IFF ?3?='' IF ?2?=NRD #ERR 1520,3,MIGR
// IFF ?3?='' IF ?2?=MASTER #ERR 1521,3,MIGR
// IFF ?4?='' IFF ?2?=FILE #ERR 1525,3,MIGR
// IFF ?5?='' IFF ?2?=FILE #ERR 1526,3,MIGR
// IFF ?6?='' IFF ?2?=LIBRARY #ERR 1527,3,MIGR
// IFF ?7?='' IFF ?2?=LIBRARY #ERR 1528,3,MIGR
*
* IF PARMS WERE BLANK, DEFAULT THEM
*
// IF ?2?='' EVALUATE P2=LIBRARY
// IF ?7?='' EVALUATE P7=COMP
*
* PUT PARMS IN THE LDA
*
* SELECTION TYPE
// LOCAL AREA-SYSTEM,OFFSET-213,BLANK-1
// IF ?2?=ALL LOCAL AREA-SYSTEM,OFFSET-213,DATA-'A'
// IF ?2?=LIBRARY LOCAL AREA-SYSTEM,OFFSET-213,DATA-'L'
// IF ?2?=FILE LOCAL AREA-SYSTEM,OFFSET-213,DATA-'F'
// IF ?2?=USER LOCAL AREA-SYSTEM,OFFSET-213,DATA-'U'
// IF ?2?=FOLDER LOCAL AREA-SYSTEM,OFFSET-213,DATA-'W'
// IF ?2?=SPELDICT LOCAL AREA-SYSTEM,OFFSET-213,DATA-'P'
// IF ?2?=DATADICT LOCAL AREA-SYSTEM,OFFSET-213,DATA-'D'
// IF ?2?=NRD LOCAL AREA-SYSTEM,OFFSET-213,DATA-'N'
// IF ?2?=MASTER LOCAL AREA-SYSTEM,OFFSET-213,DATA-'M'
*
* ITEM NAME
// LOCAL AREA-SYSTEM,OFFSET-214,DATA-'?3?',BLANK-8
*
* DATE
// LOCAL AREA-SYSTEM,OFFSET-222,DATA-'?4?',BLANK-6
*
* FILE TYPE
// LOCAL AREA-SYSTEM,OFFSET-228,BLANK-1
// IF ?5?=DATA LOCAL AREA-SYSTEM,OFFSET-228,DATA-'1'
// IF ?5?=FCT LOCAL AREA-SYSTEM,OFFSET-228,DATA-'2'
// IF ?5?=STREAM LOCAL AREA-SYSTEM,OFFSET-228,DATA-'3'
// IF ?5?=UNFORMAT LOCAL AREA-SYSTEM,OFFSET-228,DATA-'4'
// IF ?5?=BGUGDIF LOCAL AREA-SYSTEM,OFFSET-228,DATA-'5'
// IF ?5?=APF LOCAL AREA-SYSTEM,OFFSET-228,DATA-'6'
*
* LOADLIB
// LOCAL AREA-SYSTEM,OFFSET-229,DATA-'?6?',BLANK-8
*
* COMP/NOCOMP
// IF ?7?=COMP LOCAL AREA-SYSTEM,OFFSET-237,DATA-'1',BLANK-1
// ELSE LOCAL AREA-SYSTEM,OFFSET-237,DATA-'2',BLANK-1
*
* SELECTION FILE NAME
// LOCAL AREA-SYSTEM,OFFSET-101,DATA-'?8?',BLANK-8
*
// IF ?2?=ALL GOTO SALL
*
* SET UP #MYCR OPCODE (MYLDCUOP) TO ADD A NEW RECORD TO SELECTION FILE
* MYLDCUOP = MYLDUPDT
// LOCAL AREA-SYSTEM,OFFSET-239,DATA-'2'
*
* CALL SELECTION FILE UPDATE PROGRAM
*
// LOAD #MYCR,#MYLIB
// FILE NAME-SELECT,LABEL-?8?,DISP-OLD
// RUN
// RETURN
*
// TAG SALL
*
* CALL SELECT ALL PROGRAM
*
// LOAD #MYSA,#MYLIB
// RUN
// RETURN
*
***********************************************************************
* MIGRATE ANALYZE *
***********************************************************************
*
// TAG ANALYZE
*
* ERROR CHECK PARM 2
*
// IFF ?2?/ IFF ?2?/LISTALL IFF ?2?/SYSTEM IFF ?2?/LIBRARY GOTO AN2MORE
// GOTO ANCHK4
*
// TAG AN2MORE
// IFF ?2?/SECURITY IFF ?2?/DATADICT IFF ?2?/MASTER BADPARM ANALYZE,2
*
* ERROR CHECK PARM 4
*
// TAG ANCHK4
// IFF ?4?/ IFF ?4?/ALL IFF ?4?/RPG IFF ?4?/OCL IFF ?4?/COBOL GOTO AN4MORE
// GOTO ANCOMBO
*
// TAG AN4MORE
// IFF ?4?/SOURCE IFF ?4?/LIBRCNF IFF ?4?/QUERY BADPARM ANALYZE,4
*
* ERROR CHECK COMBINATIONS OF PARMS
*
// TAG ANCOMBO
// IFF ?3?='' IF ?2?=LISTALL #ERR 1530,3,MIGR
// IFF ?3?='' IF ?2?=SYSTEM #ERR 1530,3,MIGR
// IFF ?3?='' IF ?2?=SECURITY #ERR 1530,3,MIGR
// IFF ?3?='' IF ?2?=MASTER #ERR 1530,3,MIGR
// IFF ?3?='' IFF ?2?=LIBRARY IFF ?2?=DATADICT BADPARM ANALYSIS,3
// IF ?2?=LIBRARY IF ?3?/ BADPARM ANALYSIS,3
// IF ?2?=DATADICT IF ?3?/ BADPARM ANALYSIS,3
// IFF ?4?='' IFF ?2?=LIBRARY #ERR 1531,3,MIGR
*
* DEFAULT THE BLANK PARMS
*
// IF ?2?='' EVALUATE P2=LISTALL
// IF ?2?=LIBRARY IF ?4?/ EVALUATE P4=ALL
*
* SAVE AUDIT FILE NAME IN LDA
*
// IFF ?5?/ LOCAL AREA-SYSTEM,OFFSET-117,DATA-'?5?',BLANK-8
*
* CALL THE COMPONENT ANALYSES REQUESTED
*
* LISTALL
// IF ?2?/LISTALL INCLUDE MYREPLST
// IF ?2?/LISTALL RETURN
*
* SYSTEM
// IF ?2?/SYSTEM INCLUDE ANLZ001
// IF ?2?/SYSTEM RETURN
*
* LIBRARY
* RPG
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZRPG ?3?,?5?
// IF ?2?/LIBRARY IF ?4?=RPG INCLUDE ANLZRPG ?3?,?5?
* COBOL
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZCBL ?3?,?5?
// IF ?2?/LIBRARY IF ?4?=COBOL INCLUDE ANLZCBL ?3?,?5?
* OCL
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZOCL ?3?,?5?
// IF ?2?/LIBRARY IF ?4?=OCL INCLUDE ANLZOCL ?3?,?5?
* MISSING SOURCE
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZSRC ?3?,?5?
// IF ?2?/LIBRARY IF ?4?=SOURCE INCLUDE ANLZSRC ?3?,?5?
* QUERY
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZQRY ?3?,?5?
// IF ?2?/LIBRARY IF ?4?=QUERY INCLUDE ANLZQRY ?3?,?5?
* CONFIG
// IF ?2?/LIBRARY IF ?4?=ALL INCLUDE ANLZCNFG CNFGMBRS,?3?,?5?
// IF ?2?/LIBRARY IF ?4?=LIBRCNF INCLUDE ANLZCNFG CNFGMBRS,?3?,?5?
// IF ?2?/LIBRARY RETURN
*
* SECURITY
// IF ?2?/SECURITY INCLUDE ANLZSECP ?5?
// IF ?2?/SECURITY RETURN
*
* MASTER CONFIG
// IF ?2?/MASTER INCLUDE ANLZCNFG MASTER,,?5?
// IF ?2?/MASTER INCLUDE ANLZCNFG CNFGFILE,,?5?
// IF ?2?/MASTER RETURN
*
* DATADICT
// IF ?2?/DATADICT INCLUDE ANLZIDDP ?3?,?5?
// IF ?2?/DATADICT RETURN
*
// RETURN
*
***********************************************************************
* MIGRATE SAVE36 *
***********************************************************************
*
// TAG SAVE36
*
* IF $MYSYSID DOES NOT EXIST, ERROR MESSAGE
*
// IFF DATAF1-$MYSYSID #ERR 1312,3,MIGR,$MYSYSID
*
* ERROR CHECK THE PARMS
*
* IF NO MEDIA SPECIFIED DEFAULT TO DISKETTE
// IF ?2?/ EVALUATE P2=DISKETTE
*
* ERROR CHECK MIGRATION MEDIA
// IFF ?2?/DISKETTE IFF ?2?/TAPE IFF ?2?/DISK IFF ?2?/DATALINK +
BADPARM EXPORT,2
*
* MAKE SURE VOLUME ID IS FILLED IN IF NOT DISK OR DATALINK
// IFF ?2?=DISK IFF ?2?=DATALINK IF ?3?/ BADPARM EXPORT,3
// IF ?2?=DISK IFF ?3?='' BADPARM EXPORT,3
// IF ?2?=DATALINK IFF ?3?='' BADPARM EXPORT,3
*
* FILL IN DEFAULT LOCATION IF NOT SPECIFIED
// IF ?2?/DISKETTE IF ?4?='' EVALUATE P4=S1
// IF ?2?/TAPE IF ?4?='' EVALUATE P4=T1
// IF ?2?/DISK IF ?4?='' EVALUATE P4=A1
// IF ?2?=DATALINK IFF ?4?='' BADPARM EXPORT,4
*
* ERROR CHECK DISKETTE LOCATION
// IF ?2?=DISKETTE +
IFF ?4?=S1 IFF ?4?=S2 IFF ?4?=S3 +
IFF ?4?=M1 IFF ?4?=M1.01 IFF ?4?=M1.02 IFF ?4?=M1.03 +
IFF ?4?=M1.04 IFF ?4?=M1.05 IFF ?4?=M1.06 IFF ?4?=M1.07 +
IFF ?4?=M1.08 IFF ?4?=M1.09 IFF ?4?=M1.10 +
IFF ?4?=M2 IFF ?4?=M2.01 IFF ?4?=M2.02 IFF ?4?=M2.03 +
IFF ?4?=M2.04 IFF ?4?=M2.05 IFF ?4?=M2.06 IFF ?4?=M2.07 +
IFF ?4?=M2.08 IFF ?4?=M2.09 IFF ?4?=M2.10 +
BADPARM EXPORT,4
*
* ERROR CHECK TAPE LOCATION
// IF ?2?=TAPE +
IFF ?4?=T1 IFF ?4?=T2 IFF ?4?=TC +
BADPARM EXPORT,4
*
* ERROR CHECK DISK LOCATION
// IF ?2?=DISK +
IFF ?4?=A1 IFF ?4?=A2 IFF ?4?=A3 IFF ?4?=A4 +
BADPARM EXPORT,4
*
* ERROR CHECK AUTO/NOAUTO FLAG
// IFF ?2?=DISK IFF ?2?=DATALINK IF ?5?='' EVALUATE P5=AUTO
// IF ?2?=DISK IFF ?5?='' BADPARM EXPORT,5
// IF ?2?=DATALINK IFF ?5?='' BADPARM EXPORT,5
// IFF ?2?=DISK IFF ?4?=TC IFF ?5?/AUTO IFF ?5?/NOAUTO +
IFF ?2?=DATALINK BADPARM EXPORT,5
*
* ENSURE TAPE PARAMETERS ARE FILLED IN
// IF ?2?=TAPE IF ?6?='' EVALUATE P6=REWIND
// IF ?2?=TAPE IFF ?6?=REWIND IFF ?6?=LEAVE IFF ?6?=UNLOAD +
BADPARM EXPORT,6
// IFF ?2?=TAPE IFF ?6?='' BADPARM EXPORT,6
*
// IF ?2?=TAPE IF ?7?='' BADPARM EXPORT,7
// IFF ?2?=TAPE IFF ?7?='' BADPARM EXPORT,7
*
* ERROR CHECK SECURITY FLAG
// IF ?8?='' EVALUATE P8=SECURE
// IFF ?8?/SECURE IFF ?8?/NOSECURE BADPARM EXPORT,8
*
* DEFAULT AS/400 LIBRARY FOR S/36FILES TO QS36F IF NOT FILLED IN
// IF ?9?='' EVALUATE P9=QS36F
*
* MAKE SURE SELECTION FILE NAME IS FILLED IN
// IF ?10?='' BADPARM EXPORT,10
*
* DEFAULT AUDIT FILE NAME TO $MYAUD IF NOT FILLED IN
// IF ?11?='' EVALUATE P11=$MYAUD
*
* ERROR CHECK COMMUNICATIONS PROCEDURE PARAMETERS
// IF ?2?=DISK IF ?12?='' BADPARM EXPORT,12
// IF ?2?=DISK IF ?13?='' EVALUATE P13=#LIBRARY
*
* ERROR CHECK DBCS FLAG
// IF ?14?='' EVALUATE P14=SBCS
// IFF ?14?=SBCS IFF ?14?=DBCS BADPARM EXPORT,14
* CHANGE PARAMETER 14 TO MATCH THE LDA N=SBCS AND Y=DBCS
// IF ?14?=SBCS EVALUATE P14=N
// IF ?14?=DBCS EVALUATE P14=Y
*
* CHECK DATA LINK PARAMETERS IF NECCESSARY
// IFF ?2?=DATALINK GOTO EXPORT
// IF ?15?='' IF ?16?='' IF ?17?='' IF ?18?='' +
IF ?19?='' IF ?20?='' IF ?21?='' BADPARM EXPORT,15
*
// IFF ?C15?=002 IFF ?C15?=000 BADPARM EXPORT,15
// IFF ?C16?=002 IFF ?C16?=000 BADPARM EXPORT,16
// IFF ?C17?=002 IFF ?C17?=000 BADPARM EXPORT,17
// IFF ?C18?=002 IFF ?C18?=000 BADPARM EXPORT,18
// IFF ?C19?=002 IFF ?C19?=000 BADPARM EXPORT,19
// IFF ?C20?=002 IFF ?C20?=000 BADPARM EXPORT,20
// IFF ?C21?=002 IFF ?C21?=000 BADPARM EXPORT,21
*
// IF ?22?='' EVALUATE P22=QMGRDTA01
// LOCAL AREA-SYSTEM,OFFSET-472,DATA-'?15?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-474,DATA-'?16?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-476,DATA-'?17?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-478,DATA-'?18?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-480,DATA-'?19?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-482,DATA-'?20?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-484,DATA-'?21?',BLANK-2
// LOCAL AREA-SYSTEM,OFFSET-486,DATA-'?22?',BLANK-10
*
***********************************************************************
* ENTRY POINT FOR INTERACTIVE SAVE (SKIPS ERROR CHECKING SINCE *
* SAVE36 PROC ALREADY DID IT *
***********************************************************************
*
// TAG EXPORT
*
* DELETE THE TAPE SELECTION FILE IF IT EXISTS
// IF DATAF1-$MYMIGR DELETE $MYMIGR,F1
*
* DELETE ACTION FILE IF IT EXISTS
// IF DATAF1-$MYACT DELETE $MYACT,F1
*
* DELETE END FILE IF IT EXISTS
// IF DATAF1-$MYEND DELETE $MYEND,F1
*
* MAKE THE ACTION FILE 80 RECORDS BIGGER THAN THE SELECTION FILE
// EVALUATE P59,8=?F'S,?10?'?+80
*
* USE BLDFILE PROC TO CREATE ACTION FILE
*
BLDFILE $MYACT,I,R,?59?,32,,,1,9,,DUPKEY,80
*
* IF THE MEDIA IS TAPE, THEN CREATE THE TAPE SELECTION FILE
*
// IF ?2?=TAPE BLDFILE $MYMIGR,I,R,?59?,15,,,1,14,DFILE,,40
*
* USE BLDFILE PROC TO CREATE END FILE
*
BLDFILE $MYEND,S,R,1,1
*
* ALLOCATE THE ACTION FILE OUTSIDE A LOAD-RUN TO KEEP IT ALLOCATED
* // FILE NAME-$MYACT,DISP-SHRMR
*
* SET UP THE LDA WITH THE PARMS
*
* MEDIA TYPE
// LOCAL AREA-SYSTEM,OFFSET-293,BLANK-1
// IF ?2?=DISKETTE LOCAL AREA-SYSTEM,OFFSET-293,DATA-'1'
// IF ?2?=TAPE LOCAL AREA-SYSTEM,OFFSET-293,DATA-'2'
// IF ?2?=DISK LOCAL AREA-SYSTEM,OFFSET-293,DATA-'3'
// IF ?2?=DATALINK LOCAL AREA-SYSTEM,OFFSET-293,DATA-'4'
*
* VOLID
// LOCAL AREA-SYSTEM,OFFSET-294,DATA-'?3?',BLANK-6
*
* LOCATION
// LOCAL AREA-SYSTEM,OFFSET-300,DATA-'?4?',BLANK-5
*
* AUTO/NOAUTO
// IF ?5?=AUTO LOCAL AREA-SYSTEM,OFFSET-305,DATA-'1',BLANK-1
// ELSE LOCAL AREA-SYSTEM,OFFSET-305,DATA-'2',BLANK-1
*
* USER PROC AND LIBRARY
// LOCAL AREA-SYSTEM,OFFSET-421,BLANK-8,DATA-'?12?'
// LOCAL AREA-SYSTEM,OFFSET-429,BLANK-8,DATA-'?13?'
*
* SECURE/NOSECURE
// IF ?8?=SECURE LOCAL AREA-SYSTEM,OFFSET-308,DATA-'1',BLANK-1
// ELSE LOCAL AREA-SYSTEM,OFFSET-308,DATA-'2',BLANK-1
*
* TARGET LIBRARY
// LOCAL AREA-SYSTEM,OFFSET-317,DATA-'?9?',BLANK-10
*
* DBCS INDICATOR
// LOCAL AREA-SYSTEM,OFFSET-343,DATA-'?14?',BLANK-1
*
* CHECK VOLID AND TARGET LIBRARY NAME FOR ACCURACY
// LOAD #MYEC,#MYLIB
// RUN
// IF ?L'336,1'?/2 #ERR 1545,3,MIGR,?9?
// IF ?L'337,1'?/2 IF ?2?/DISKETTE #ERR 1546,3,MIGR,?3?
*
* SELECTION FILE MUST EXIST
// IFF DATAF1-?10? #ERR 1511,3,MIGR,?10?
*
* SELECTION FILE NAME
* (INTERACTIVE PATH MUST FILL IN PARM 10)
// LOCAL AREA-SYSTEM,OFFSET-101,DATA-'?10?',BLANK-8
*
* AUDIT FILE NAME (IF BLANK, 117 WILL CONTAIN DEFAULT $MYAUD)
// IFF ?11?/ LOCAL AREA-SYSTEM,OFFSET-117,DATA-'?11?',BLANK-8
*
* DELETE TEMP FILES AND LIBRARIES IF THEY EXIST
// IF DATAF1-$MYPROF DELETE $MYPROF,F1,SCRATCH,,ALL
// IF DATAF1-#MYLIB2 DELETE #MYLIB2,F1,SCRATCH,,LIBR
// IF DATAF1-#MYLIB4 DELETE #MYLIB4,F1,SCRATCH,,LIBR
* CREATE TEMP LIBRARY #MYLIB4
// LOAD $MAINT
// RUN
// ALLOCATE STATUS-CREATE,LIBRNAME-#MYLIB4,LIBRSIZE-100,DIRSIZE-10
// END
*
* PUT OUT TRANSPORTATION IN PROGRESS MESSAGE
// * 1183
*
* CALL THE ACTION FILE BUILD PROGRAM
// LOAD #MYEA,#MYLIB
// FILE NAME-ACTION,LABEL-$MYACT,DISP-SHRMR
// FILE NAME-SELECT,LABEL-?L'101,8'?,DISP-OLD
// RUN
*
* IF A PARM 11 IS GIVEN (USER AUDIT FILE) PUT THIS IN LOCAL DATA AREA
// IFF ?11?/ LOCAL AREA-SYSTEM,OFFSET-117,BLANK-8,DATA-'?11?'
* CREATE AUDIT FILE IF IT DOESN'T EXIST (DEFAULT-$MYAUD IN 117 OF LDA)
// IFF DATAF1-?L'117,8'? BLDFILE ?L'117,8'?,I,R,100,32,,,1,10,,DUPKEY,80
*
* CALL THE EXPORT PROGRAM
// LOAD #MYEX,#MYLIB
// FILE NAME-AUDIT,LABEL-?L'117,8'?,DISP-SHRMM
// RUN
*
* DELETE TEMP LIBRARY IF IT EXISTS
// IF DATAF1-#MYLIB4 DELETE #MYLIB4,F1,SCRATCH,,LIBR
*
* CALL #MYCT TO DELETE SELECTION FILE RECORD IN CONTROL FILE
// LOCAL AREA-SYSTEM,OFFSET-238,DATA-'4'
// LOAD #MYCT
// RUN
*
* DELETE SELECTION FILE
// IF DATAF1-?L'101,8'? DELETE ?L'101,8'?,F1
*
* CALL EXCEPTION REPORT GENERATION PROGRAM
// INCLUDE MYREPEXP
*
* DELETE ACTION FILE NOW
// IF DATAF1-$MYACT DELETE $MYACT,F1
*
* DELETE ENDING FILE NOW
// IF DATAF1-$MYEND DELETE $MYEND,F1
*
// RETURN
*
***********************************************************************
* MIGRATE REPORTS *
***********************************************************************
*
// TAG REPORTS
*
// IF DATAF1-$MYWK0 DELETE $MYWK0,F1
// IF DATAF1-$MYWK1 DELETE $MYWK1,F1
// IF DATAF1-$MYIND DELETE $MYIND,F1
// IF DATAF1-$MYVTOC DELETE $MYVTOC,F1
*
* IF PARMS WERE BLANK, DEFAULT THEM
*
// IF ?2?='' EVALUATE P2=MIGRATED
// IF ?3?='' IF ?2?=MIGRATED EVALUATE P3=SORTRUN
// IF ?4?='' IF ?2?=MIGRATED EVALUATE P4=LAST
// IF ?5?='' IFF ?2?=ANALYZED EVALUATE P5=ALL
*
* ERROR CHECK COMBINATIONS OF PARAMETERS
*
// IFF ?2?=MIGRATED IFF ?3?='' #ERR 1550,3,MIGR
// IFF ?2?=MIGRATED IFF ?4?='' #ERR 1551,3,MIGR
// IF ?2?=ANALYZED IFF ?5?='' #ERR 1552,3,MIGR
// IF ?4?=ALL IFF ?7?='' #ERR 1553,3,MIGR
*
* HANDLE BATCH INTERFACE IF NECCESSARY
*
// LOCAL AREA-SYSTEM,DATA-' ',OFFSET-359
// IF ?4?=FILE GOTO ALLRUNS
// IF ?4?=ALL GOTO ALLRUNS
// IFF ?4?=LAST GOTO NOTLAST
// LOCAL AREA-SYSTEM,DATA-'L',OFFSET-359
// GOTO MYRRTAG
// TAG NOTLAST
// LOCAL AREA-SYSTEM,DATA-'F',OFFSET-359
// LOCAL AREA-SYSTEM,DATA-'?4?',OFFSET-378,BLANK-8
// TAG MYRRTAG
// LOAD #MYRR,#MYLIB
// RUN
// EVALUATE P7=?L'378,8'?
// EVALUATE P4=FILE
// TAG ALLRUNS
*
* MYEC PUTS SESSION DATE FORMAT INTO LDA (AS WELL AS THE CHECKING FUNCT)
// LOAD #MYEC,#MYLIB
// RUN
*
* ERROR CHECK THE PARMS
// IFF ?2?/MIGRATED IFF ?2?/NOTMIGR IFF ?2?/ANALYZED BADPARM REPORTS,2
// IFF ?3?/SORTRUN IFF ?3?/SORTITEM IFF ?3?/ BADPARM REPORTS,3
// IF ?2?/ANALYZED GOTO RECOMBO
// IFF ?5?/LDA IFF ?5?/LIBRARY IFF ?5?/FILE IFF ?5?/USER GOTO RE5MORE1
// GOTO RECOMBO
*
// TAG RE5MORE1
// IFF ?5?/FOLDER IFF ?5?/SPELDICT IFF ?5?/DATADICT IFF ?5?/NRD GOTO RE5MORE2
// GOTO RECOMBO
*
// TAG RE5MORE2
// IFF ?5?/MASTER IFF ?5?/ALL BADPARM EXPORT,5
// TAG RECOMBO
*
* SET UP THE LDA WITH THE PARMS
*
* REPORT TYPE
// LOCAL AREA-SYSTEM,OFFSET-357,BLANK-1
// IF ?2?=MIGRATED LOCAL AREA-SYSTEM,OFFSET-357,DATA-'M'
// IF ?2?=NOTMIGR LOCAL AREA-SYSTEM,OFFSET-357,DATA-'N'
// IF ?2?=ANALYZED LOCAL AREA-SYSTEM,OFFSET-357,DATA-'A'
*
* SORT TYPE
// IF ?3?=SORTRUN LOCAL AREA-SYSTEM,OFFSET-358,DATA-'R',BLANK-1
// ELSE LOCAL AREA-SYSTEM,OFFSET-358,DATA-'I',BLANK-1
*
* RUN FLAG
// IF ?4?=ALL LOCAL AREA-SYSTEM,OFFSET-359,DATA-'A'
// ELSE LOCAL AREA-SYSTEM,OFFSET-359,DATA-'F'
*
* RUN NUMBER FILE IN LDA
// LOCAL AREA-SYSTEM,OFFSET-378,BLANK-8,DATA-'?7?'
*
* PUT USER AUDIT FILE IN LDA IF PRESENT (ELSE WILL USE $MYAUD)
// IFF ?6?/ LOCAL AREA-SYSTEM,OFFSET-117,BLANK-8,DATA-'?6?'
*
* MIGRATION OBJECT TO REPORT ON (LDA MEANS LDA ALREADY SET UP)
// IF ?5?=LDA IFF ?8?/ LOCAL AREA-SYSTEM,OFFSET-360,BLANK-18,DATA-'?8?'
// IF ?5?=LDA GOTO REPROGS
// LOCAL AREA-SYSTEM,OFFSET-360,BLANK-18
// IF ?5?=ALL LOCAL AREA-SYSTEM,DATA-'1',OFFSET-360
// IF ?5?=LIBRARY LOCAL AREA-SYSTEM,DATA-'1',OFFSET-361
// IF ?5?=FILE LOCAL AREA-SYSTEM,DATA-'1',OFFSET-362
// IF ?5?=USER LOCAL AREA-SYSTEM,DATA-'1',OFFSET-363
// IF ?5?=FOLDER LOCAL AREA-SYSTEM,DATA-'1',OFFSET-364
// IF ?5?=SPELDICT LOCAL AREA-SYSTEM,DATA-'1',OFFSET-365
// IF ?5?=DATADICT LOCAL AREA-SYSTEM,DATA-'1',OFFSET-366
// IF ?5?=NRD LOCAL AREA-SYSTEM,DATA-'1',OFFSET-367
// IF ?5?=MASTER LOCAL AREA-SYSTEM,DATA-'1',OFFSET-368
*
* CALL THE REPORT PROGRAMS
// TAG REPROGS
*
* MIGRATED
// IF ?2?=MIGRATED INCLUDE MYREPMIG
// IF ?2?=MIGRATED GOTO DONEREP
*
* NOT MIGRATED
// IF ?2?=NOTMIGR INCLUDE MYREPNMG
// IF ?2?=NOTMIGR GOTO DONEREP
*
* ANALYZED
MYREPANL
*
* DELETE ANY WORK FILES
// TAG DONEREP
// IF DATAF1-$MYWK0 DELETE $MYWK0,F1
// IF DATAF1-$MYWK1 DELETE $MYWK1,F1
// IF DATAF1-$MYIND DELETE $MYIND,F1
// IF DATAF1-$MYVTOC DELETE $MYVTOC,F1
// IFF ?L'378,8'?/ IF DATAF1-?L'378,8'? DELETE ?L'378,8'?,F1
// RETURN
**********************************************************************
*
* TITLE : MIGRATE
*
* DESCRIPTIVE NAME : MIGRATION BATCH INTERFACE PROCEDURE
*
* FUNCTION : THIS PROC PROVIDES A SCREEN-LESS INTERFACE TO MIGRATION
* FOR THE ADVANCED PROGRAMMER. IT IS ALSO USED BY SOME OF THE
* INTERACTIVE PATHS FOR FUNCTIONS SUCH AS EXPORT OR REPORTS.
*
* FUNCTION FLOW: THE FIRST PARAMETER IS USED TO ROUTE CONTROL TO THE
* DESIRED FUNCTION
*
*
* GOTO MAIN MENU:
* MIGRATE
*
* CREATE A SELECTION FILE:
* MIGRATE CREATE, SELECTION_FILE, SEL_FILE_DESCRIPTION, NUMBER_OF_RECS
*
* ADD A SELECTION TO A SELECTION FILE:
* MIGRATE SELECT, ITEM_TYPE, ITEM_NAME, ITEM_DATE, FILE_TYPE,
* ALTERNATE_LIBRAY, COMPILE_FLAG, SELECTION_FILE
*
* ANALYZE FOR UNMIGRATABLE ITEMS:
* MIGRATE ANALYZE, ANLZ_TYPE, ITEM_NAME, LIBRARY_ANLZ_TYPE, AUDIT_FILE
*
* EXPORT ITEMS TO TARGET MACHINE:
* MIGRATE EXPORT, MEDIA, VOLID, LOCATION, AUTO_FLAG, TAPE_END,
* SEQUENCE_NUMBER, SECURITY_FLAG, TARGET_LIBRARY_FOR_FILES,
* SELECTION_FILE, AUDIT_FILE
*
* PRODUCE REPORTS ON MIGRATION:
* MIGRATE REPORTS,REPORT_TYPE, SORT_TYPE, RUN_NUMBER_FLAG, ITEM_TYPE,
* AUDIT_FILE, RUN_NUMBER_FILE
*
*
* INVOCATION: USER-CODED PROCEDURES, USER INPUT, INTERACTIVE PATHS
*
* MIGRATE PARM1,PARM2, ... FROM
* OR // INCLUDE MIGRATE PARM1,PARM2, ... OCL
*
*
*
* PARAMETERS
* ---------------------------------------------------------------
* PARM 1 - MIGRATION FUNCTION
* PARM 2 ... - FUNCTION DEPENDENT PARAMETERS (SEE ABOVE)
*
*
* SCREENS DISPLAYED : NONE
*
* FILES ACCESSED : CONTROL FILE - GET NEXT TEMP FILE NAME
* SELECTION FILE - CREATE, UPDATE, PROCESS
* ACTION FILE - CREATE, UPDATE, PROCESS
* AUDIT FILE - ADD RECORDS
*
* NORMAL MODULE EXIT : RETURN TO CALLER OR COMMAND PROCESSOR
*
* ABNORMAL MOD EXIT : SYSLOG HALT
*
* RETURN CODE : NONE
*
* MESSAGES ISSUED :
* MIC DESCRIPTION
* ------------ --------------------------------------------------
* $MICXXXX DESCRIPTION
*
* CROSS REFERENCE:
*
* CALLED BY DESCRIPTION
* --------- ----------------------------------
* EXPORT EXPORT PROCEDURE
* REPORTS REPORTS PROCEDURE
*
*
**********************************************************************