|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/36 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/36 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 10752 (0x2a00)
Notes: MEMBER_P, Member_Text
Names: »MIGRNAME«
└─⟦7f4ab32d0⟧ Bits:30009823 AS/ENTRY - S/36 SYST SUPP PROG IDENT. S/36 PTFDK3900 FC 1991/9074/9084 Refer to Memo 36714 Product Number 5727SS6 Rel 05 11 Created 19950301 Level 01 Seq 001 of 011
└─⟦820ffa6c4⟧
└─⟦this⟧ ».MIGRNAME«
// LIBRARY NAME-#MYLIB
// MEMBER USER1-#MY#1MSG
// MEMBER USER2-#MY#2MSG
* FLAG REASON VERS. DATE WHO CHANGE DESCRIPTION
* ---- ------ ----- -------- --- ---------------------------------
* $A0 1239785 H10C 07/08/88 MPW ADDED DISP-SHR TO OFFICE FILES
*
* CALL PSDID TO FIND DEFAULT SYSTEM NAME AND ADDRESS
*
* P56 = DISP FOR $MYSYSID
* P57 = DISP FOR $OUDRFL
* P58 = LDA 204 SYSTEM NAME
* P59 = LDA 212 SYSTEM ADDRESS
* LDA 220 - 1 = $MYSYSID EXISTS
* 2 = $OUDRFL EXISTS
* 0 = NEITHER EXISTS
*
// EVALUATE P56='OLD'
// EVALUATE P57='SHR'
// IFF DATAF1-$OUDRFL EVALUATE P57='NEW'
// IFF DATAF1-$MYSYSID EVALUATE P56='NEW'
// IFF DATAF1-$MYSYSID GOTO CHKDRFL
// LOCAL OFFSET-031,DATA-'1',BLANK-1
// GOTO GETDFTID
// TAG CHKDRFL
// IFF DATAF1-$OUDRFL GOTO EVLP1
// LOCAL OFFSET-031,DATA-'2',BLANK-1
// GOTO GETDFTID
// LOCAL OFFSET-031,DATA-'0',BLANK-1
// EVALUATE P58='' P59=''
// GOTO EVLP1
// TAG GETDFTID
// LOAD PSDID,#MYLIB
// FILE NAME-$MYSYSID,UNIT-F1,DISP-?56?
// FILE NAME-$OUDRFL,UNIT-F1,DISP-?57?
// RUN
// EVALUATE P58='?L'204,8'?'
// EVALUATE P59='?L'212,8'?'
*
// TAG EVLP1
// IF ?1?/ EVALUATE P1='$MYSC000'
// IFF ?1?/$MYSC000 EVALUATE P1='$MYSC000'
// EVALUATE P60='?1?'
// IF DATAF1-?1? GOTO PRE300
// LOAD #RRS1
// RUN
*
* The following procedure displays the media transport screen, and evokes
* the proper media screen depending upon operator choice.
*
// TAG PRE300
// EVALUATE P1='1' P2='' P41='' P61='1'
*
* CALL $PSIN TO CHECK SYSCOMM FOR KANJI AND/OR SINGLE DISKETTE SYSTEM
* LDA 200 - 0 = NON KANJI SYSTEM
* 1 = KANJI SYSTEM
* LDA 201 - 1 = SINGLE DISKETTE DRIVE SYSTEM
* 2 = MULTIPLE DRIVE SYSTEM
* P62 = LDA 200
* P63 = LDA 201
* UPSI 8 ON = SINGLE DRIVE
*
// LOAD $PSIN,#MYLIB
// RUN
// EVALUATE P62=?L'200,1'?
// EVALUATE P63=?L'201,1'?
// SWITCH XXXXXXXX
// IF ?L'201,1'?='1' SWITCH XXXXXXX1
// TAG SYS300
// EVALUATE P1='?61?'
// IFF ?62?='1' GOTO MAS300
// PROMPT MEMBER-#MY$FMT2,FORMAT-MAS300,LENGTH-'1,78'
// GOTO EVL300
// TAG MAS300
// PROMPT MEMBER-#MY@FMT2,FORMAT-MAS300,LENGTH-'1,78'
// TAG EVL300
// EVALUATE P41='' P2=''
// IF ?CD?=2007 CANCEL
// IF ?CD?=2003 CANCEL
// IFF ?CD?=0000 GOTO PRE300
// EVALUATE P61='?1?'
// IF '?1?'=1 GOTO PRE310
// IF '?1?'=2 GOTO PRE320
// IF '?1?'=3 GOTO PRE330
// GOTO SYS300 ?2F'2004'? ?41F'C'?
*
* The following procedure displays the diskette transport screen.
*
// TAG PRE310
// EVALUATE P1='' P2='S1 ' P3='AUTO ' P4='2' P5=''
// EVALUATE P40='' P42='' P43='' P44='' P45=''
// LOCAL OFFSET-1,AREA-SYSTEM
*
* CHECK P62 FOR KANJI PREFERRED
*
// TAG SYS310
// IFF ?62?='1' GOTO MAS310
// PROMPT MEMBER-#MY$FMT2,FORMAT-MAS310,LENGTH-'6,5,6,1,78',UPSI-YES
// GOTO EVL310
// TAG MAS310
// PROMPT MEMBER-#MY@FMT2,FORMAT-MAS310,LENGTH-'6,5,6,1,78',UPSI-YES
// TAG EVL310
// EVALUATE P5='' P40='' P42='' P43='' P44='' P45=''
// IF ?CD?=2003 EVALUATE P2=''
// IF ?CD?=2003 GOTO SYS300 ?1F'?L'293,1'?'?
// IF ?CD?=2007 CANCEL
// IFF ?CD?=0000 GOTO PRE310
// IF '?1?'/ GOTO SYS310 ?40F'1'? ?42F'C'? ?5F'1181'?
// LOCAL OFFSET-294,DATA-'?1?',AREA-SYSTEM,BLANK-6
// LOAD #MYEC,#MYLIB
// RUN
// IFF ?L'337,1'?/1 GOTO SYS310 ?5F'1185'? ?40F'1'? ?42F'C'?
// IF '?2?'/ GOTO SYS310 ?5F'1085'? ?43F'C'?
// IF '?3?'/ EVALUATE P3=AUTO
// IF '?4?'/ GOTO SYS310 ?37F'1'? ?45F'C'?
// IFF '?2?'=S1 IFF '?2?'=S2 IFF '?2?'=S3 IFF '?2?'=M1 +
IFF '?2?'=M2 IFF '?2?'=M1.01 IFF '?2?'=M1.02 IFF '?2?'=M1.03 +
IFF '?2?'=M1.04 IFF '?2?'=M1.05 IFF '?2?'=M1.06 IFF '?2?'=M1.07 +
IFF '?2?'=M1.08 IFF '?2?'=M1.09 IFF '?2?'=M1.10 IFF '?2?'=M2.01 +
IFF '?2?'=M2.02 IFF '?2?'=M2.03 IFF '?2?'=M2.04 IFF '?2?'=M2.05 +
IFF '?2?'=M2.06 IFF '?2?'=M2.07 IFF '?2?'=M2.08 IFF '?2?'=M2.09 +
IFF '?2?'=M2.10 GOTO SYS310 ?5F'1085'? ?43F'C'?
// LOCAL OFFSET-300,DATA-'?2?',AREA-SYSTEM,BLANK-5
// IF '?3?'=' AUTO' EVALUATE P3=AUTO
// IF '?3?'=' AUTO ' EVALUATE P3=AUTO
// IFF '?3?'='AUTO ' IFF '?3?'='NOAUTO' GOTO SYS310 ?5F'1182'? ?44F'C'?
// LOCAL OFFSET-305,DATA-'?3?',AREA-SYSTEM,BLANK-6
// IFF ?4?=1 IFF ?4?=2 GOTO SYS310 ?37F'1'? ?45F'C'?
// LOCAL OFFSET-311,DATA-'?4?',AREA-SYSTEM
// EVALUATE P21='?1?'
// EVALUATE P22='?2?'
// EVALUATE P23='?3?'
*
* Prepare the operator to initialize diskettes (as requested on screen
* MAS310).
*
// IF ?4?=2 GOTO PRE330
* Initialize diskette(s)
// HELP INIT ?1?,OWNERID,RENAME,?2?
// IF ?CD?=2143 GOTO PRE310
// GOTO PRE330
*
* The following procedure displays the tape transport screen, and evokes
* the PSTAPE procedure to obtain all DRU data.
*
// TAG PRE320
// EVALUATE P1='' P2='T1' P3='REWIND' P4='AUTO ' P5='2' P6=''
// EVALUATE P46='' P47='' P48='' P49='' P50=''
*
* CHECK P62 FOR KANJI PREFERRED
*
// TAG SYS320
// IFF ?62?='1' GOTO MAS320
// PROMPT MEMBER-#MY$FMT2,FORMAT-MAS320,LENGTH-'6,2,6,6,1,78'
// GOTO EVL320
// TAG MAS320
// PROMPT MEMBER-#MY@FMT2,FORMAT-MAS320,LENGTH-'6,2,6,6,1,78'
// TAG EVL320
// EVALUATE P6='' P46='' P47='' P48='' P49='' P50=''
// IF ?CD?=2003 EVALUATE P2=''
// IF ?CD?=2003 GOTO SYS300 ?1F'?L'293,1'?'?
// IF ?CD?=2007 CANCEL
// IFF ?CD?=0000 GOTO SYS320
// IF '?1?'/ GOTO SYS320 ?6F'1181'? ?54F'C'?
// LOCAL OFFSET-294,DATA-'?1?',AREA-SYSTEM,BLANK-6
// LOAD #MYEC,#MYLIB
// RUN
// IFF ?L'337,1'?/1 GOTO SYS320 ?6F'1185'? ?46F'1'? ?54F'C'?
// IF '?2?'/ GOTO SYS320 ?6F'1086'? ?47F'C'?
// IF '?3?'/ GOTO SYS320 ?6F'1516'? ?49F'C'?
// IF '?4?'/ EVALUATE P4=AUTO
// IF '?5?'/ EVALUATE P5=2
// LOCAL OFFSET-312,DATA-'?1?',AREA-SYSTEM,BLANK-6
// IFF '?2?'='T1' IFF '?2?'='T2' IFF '?2?'='TC' +
GOTO SYS320 ?6F'1086'? ?47F'C'?
// LOCAL OFFSET-318,DATA-'?2?',AREA-SYSTEM,BLANK-2
// IF '?4?'=' AUTO' EVALUATE P4='AUTO '
// IF '?4?'=' AUTO ' EVALUATE P4='AUTO '
// IFF '?4?'='AUTO ' IFF '?4?'='NOAUTO' GOTO SYS320 ?6F'1182'? ?48F'C'?
// LOCAL OFFSET-326,DATA-'?4?',AREA-SYSTEM,BLANK-6
// IFF '?3?'='REWIND' IFF '?3?'='LEAVE ' IFF '?3?'='UNLOAD' +
GOTO SYS320 ?6F'3335'? ?49F'C'?
// LOCAL OFFSET-320,DATA-'?3?',AREA-SYSTEM,BLANK-6
// IFF ?5?=1 IFF ?5?=2 GOTO SYS320 ?6F'3334'? ?50F'C'?
// EVALUATE P21='?1?'
// EVALUATE P22='?2?'
// EVALUATE P23='?4?'
// EVALUATE P24='?3?'
*
* Prepare the operator to initialize tapes (as requested on screen
* MAS320).
*
// IF ?5?=2 GOTO PRE330
// HELP TAPEINIT ?2?,SL,?1?,,OWNERID,,?3?
// IF ?CD?=2143 GOTO PRE320
*
* Prompt DRU screen MAS330 requesting operator to enter the system-id
* and address (REN and RGN).
*
// TAG PRE330
// EVALUATE P1='?59?' P2='?58?' P3='' P51='' P52=''
// EVALUATE P35='1'
*
* CHECK P62 FOR KANJI PREFERRED
*
// TAG SYS330
// IFF ?62?='1' GOTO MAS330
// PROMPT MEMBER-#MY$FMT2,FORMAT-MAS330,LENGTH-'8,8,78'
// GOTO EVL330
// TAG MAS330
// PROMPT MEMBER-#MY@FMT2,FORMAT-MAS330,LENGTH-'8,8,78'
// TAG EVL330
// EVALUATE P3='' P51='' P52''
// EVALUATE P35=''
// EVALUATE P58='?2?'
// EVALUATE P59='?1?'
// IF ?CD?=2003 IF ?61?=1 GOTO SYS310 ?1F'?L'294,6'?'? +
?2F'?L'300,5'?'? ?3F'?L'305,6'?'? ?4F'?L'311,1'?'?
// IF ?CD?=2003 IF ?61?=2 GOTO SYS320 ?1F'?L'312,6'?'? +
?2F'?L'318,2'?'? ?3F'?L'320,6'?'? ?4F'?L'326,6'?'?
// IF ?CD?=2003 IF ?61?=3 GOTO SYS300 ?2F''?
// IF ?CD?=2007 CANCEL
// IF '?1?'/ GOTO SYS330 ?3F'3332'? ?51F'C'?
// IF '?2?'/ GOTO SYS330 ?3F'3333'? ?52F'C'?
*
* If the files that are to be built still exist on the system, then delete
* them.
*
// IF DATAF1-$MYGRPN DELETE $MYGRPN,F1
// IF DATAF1-$MYMEMA DELETE $MYMEMA,F1
// IF DATAF1-$MYMEMI DELETE $MYMEMI,F1
// IF DATAF1-$MYMEMN DELETE $MYMEMN,F1
// IF DATAF1-$MYGRPT DELETE $MYGRPT,F1
// IF DATAF1-$MYDRUF DELETE $MYDRUF,F1
// IF DATAF1-$MYSYSID DELETE $MYSYSID,F1
// IFF DATAF1-$OUDRFL GOTO PSDR
// IFF DATAF1-$OUGRFL GOTO PSDR
*
* Run the group resolve module (PSX1) to prepare group data for use in the
* Duplicate Resolution module (PSDR).
*
// LOCAL OFFSET-1,DATA-' ',BLANK-*ALL
// LOCAL OFFSET-9,DATA-'0000'
// LOCAL OFFSET-13,DATA-' '
// BLDFILE $MYGRPN,I,RECORDS,100,10,,T,1,8,DFILE,NODUPKEY,50
// BLDFILE $MYMEMN,I,RECORDS,100,28,,T,1,16,DFILE,NODUPKEY,50
// LOAD PSX1,#MYLIB
*@A0C** ADDED DISP-SHARE
// FILE NAME-$OUGRFL,UNIT-F1,DISP-SHR
// FILE NAME-$MYGRPN,UNIT-F1,DISP-OLD
// FILE NAME-$MYMEMN,UNIT-F1,DISP-OLD
// RUN
// IFF ?L'9,4'?='0000' GOTO ERREND
*
* NOTE: DLS WILL NOT BE MIGRATED IN THE FIRST RELEASE **********
*
* Run the Duplicate Resolution module (PSDR), and be sure to check for
* existence of Document Library Services (verifying existence of DLS file
* $OULINFO will serve this purpose).
*
// TAG PSDR
// LOCAL OFFSET-1,DATA-' ',BLANK-*ALL
// LOCAL OFFSET-9,DATA-'0000'
// LOCAL OFFSET-13,DATA-' '
// LOCAL OFFSET-15,DATA-'?2?'
// LOCAL OFFSET-23,DATA-'?1?'
// IF DATAF1-$OULINFO LOCAL OFFSET-31,DATA-'1'
// IFF DATAF1-$OUDRFL GOTO SECHK
// LOCAL OFFSET-32,DATA-'1'
// IFF DATAF1-$OUGRFL GOTO SECHK
// BLDFILE $MYGRPT,I,R,100,80,A1,T,1,8,DFILE,NODUPKEY,50
// BLDINDEX $MYMEMI,9,8,$MYMEMN,,DUPKEY,A1
// TAG SECHK
// IF SECURITY-ACTIVE GOTO NONPS
// LOCAL OFFSET-33,DATA-'?USER?'
// TAG NONPS
// IFF DATAF1-$OUDRFL GOTO BLD
// IF DATAF1-$OUGRFL LOCAL OFFSET-41,DATA-'1'
// IF DATAF1-$OUCLIX LOCAL OFFSET-42,DATA-'1'
// TAG BLD
// BLDFILE $MYDRUF,I,R,100,102,A1,T,1,34,DFILE,NODUPKEY,50
// BLDFILE $MYSYSID,I,R,1,16,A1,T,1,8,DFILE,NODUPKEY,0
// LOAD PSDR,#MYLIB
// IFF DATAF1-$OUDRFL GOTO LDF
*@A0C** ADDED DISP-SHR
// FILE NAME-$OUDRFL,UNIT-F1,DISP-SHR
// IFF DATAF1-$OUGRFL GOTO CLCHK
*@A0C** ADDED DISP-SHR
// FILE NAME-$OUGRFL,UNIT-F1,DISP-SHR
// FILE NAME-$MYGRPT,UNIT-F1,DISP-OLD
// FILE NAME-$MYMEMI,UNIT-F1,DISP-OLD
// TAG CLCHK
// IFF DATAF1-$OUCLIX GOTO LDF
*@A0C** ADDED DISP-SHR
// FILE NAME-$OUCLIX,UNIT-F1,DISP-SHR
// TAG LDF
// IF DATAF1-$OULINFO FILE NAME-$OULINFO,UNIT-F1,DISP-SHR
*@A0C** ADDED DISP-SHR
// FILE NAME-$MYSYSID,UNIT-F1,DISP-OLD
// FILE NAME-$MYDRUF,UNIT-F1,DISP-OLD
// FILE NAME-$MYLIST,LABEL-?60?,UNIT-F1,DISP-OLD
// RUN
// IFF ?L'9,4'?='0000' GOTO ERREND
// IF ?61?=1 SAVE $MYDRUF,999,,?21?,?22?,?23?
// IF ?61?=2 SAVE $MYDRUF,999,,?21?,?22?,?23?,,,,,,?24?
// GOTO ENDIT
*
* Error processing section
*
// TAG ERREND
* Issue an error message if an error occurred.
// #ERR ?L'9,4'?,3,MIGR,?L'13,2'??L'1,8'?
*
* End of PSDRU procedure
*
// TAG ENDIT
// IF DATAF1-$MYGRPN DELETE $MYGRPN,F1
// IF DATAF1-$MYMEMA DELETE $MYMEMA,F1
// IF DATAF1-$MYMEMI DELETE $MYMEMI,F1
// IF DATAF1-$MYMEMN DELETE $MYMEMN,F1
// IF DATAF1-$MYGRPT DELETE $MYGRPT,F1
// IF DATAF1-?60? DELETE ?60?,F1