|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/3 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/3 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 4572 (0x11dc)
Types: s3xseg
Names: »S$NPL«
└─⟦d0bc1a931⟧ Bits:30009189 5704-sc1.V08.ccp
└─⟦64693a1c9⟧
└─⟦this⟧ »S$NPL«
└─⟦4498c64f7⟧ Bits:30009191 5704-sc2.V05.ccp
└─⟦95ee7795b⟧
└─⟦this⟧ »S$NPL«
└─⟦827b5bd03⟧ Bits:30009184 5702-sc1.V16.ccp
└─⟦f17e99db6⟧
└─⟦this⟧ »S$NPL«
MACRO 00010000
.********************************************************************** 00020000
.* * 00030000
.* TITLE: $NPL -- DEFINE CCP COMMUNICATIONS PARAMETER LIST * 00040000
.* * 00050000
.* FUNCTION: * 00060000
.* * 00070000
.* . GENERATE A 16-BYTE COMMUNICATIONS PARAMETER LIST * 00080000
.* * 00090000
.* . PERMIT THE USER TO SPECIFY INITIAL VALUES FOR CERTAIN FIELDS * 00100000
.* WITHIN THAT LIST * 00110000
.* * 00120000
.* INPUT: * 00130000
.* * 00140000
.* . USER MAY SPECIFY A LABEL FOR THE PARAMETER LIST * 00150000
.* * 00160000
.* . THE FOLLOWING OPERANDS, ALL OPTIONAL, PERMIT THE INITIALIZATION* 00170000
.* OF FIELDS WITHIN THE GENERATED PARAMETER LIST: * 00180000
.* * 00190000
.* OP-ABSOLUTE EXPRESSION * 00200000
.* * 00210000
.* OUTLEN-ABSOLUTE EXPRESSION * 00220000
.* * 00230000
.* ATTRID-ABSOLUTE EXPRESSION * 00240000
.* * 00250000
.* INLEN-ABSOLUTE EXPRESSION * 00260000
.* * 00270000
.* RECA-RELOCATABLE EXPRESSION * 00280000
.* * 00290000
.* . THE OPERANDS 'OUTLEN' AND 'ATTRID' ARE MUTUALLY EXCLUSIVE. * 00300000
.* * 00310000
.* . SEE SRL #GC21-7579 -- CCP PROGRAMMING REFERENCE MANUAL -- FOR * 00320000
.* FURTHER DESCRIPTION OF THIS MACRO. * 00330000
.* * 00340000
.* OUTPUT: * 00350000
.* * 00360000
.* . EIGHT 2-BYTE DEFINED CONSTANTS * 00370000
.* * 00380000
.* . A LABEL (IF SPECIFIED BY USER) EQUATED TO HI-ORDER BYTE OF THE * 00390000
.* GENERATED PARAMETER LIST * 00400000
.* * 00410000
.* EXTERNAL REFERENCES: * 00420000
.* * 00430000
.* . NO EXTRNS ARE GENERATED BY THIS MACRO * 00440000
.* * 00450000
.* . NO GLOBAL VARIABLES ARE USED BY THIS MACRO * 00460000
.* * 00470000
.* ERROR MESSAGES: * 00480000
.* * 00490000
.* . ERROR MNOTE (08) N2001 CONFLICTING OPERANDS--OUTLEN/ATTRID * 00500000
.* * 00510000
.* ISSUED IF THESE MUTUALLY EXCLUSIVE OPERANDS ARE BOTH PRESENT * 00520000
.* IN THE SAME MACRO-INSTRUCTION. * 00530000
.* * 00540000
.********************************************************************** 00550000
&LABEL $NPL &OP-0,&OUTLEN-,&ATTRID-,&INLEN-0,&RECA-'*+8' 00560000
TEXT 00570000
SPACE 00580000
* *** MACRO-$NPL RELEASE-8 *** 00590000
.* 00600000
.* IF LABEL SPECIFIED, GENERATE EQUATE TO HI-ORDER OF PARAMETER LIST 00610000
.* 00620000
AIF (T'&LABEL EQ 'O').PL10 . SKIP EQUATE IF NO LABEL SPEC'D 00630000
&LABEL EQU * HI-ORDER ADDR OF PARAMETER LIST 00640000
.PL10 ANOP . RESUME HERE 00650000
.* 00660000
.* GENERATE RETURN-CODE FIELD AS ZEROS 00670000
.* 00680000
DC AL2(0) RTC--RETURN CODE 00690000
.* 00700000
.* GENERATE OPERATION CODE/MODIFIERS FIELD FROM USER'S SPECIFICATION 00710000
.* 00720000
DC AL2(&OP) OPC--OPERATION CODE/MODIFIERS 00730000
.* 00740000
.* IF BOTH 'OUTLEN' AND 'ATTRID' SPECIFIED, ISSUE ERROR MNOTE 00750000
.* 00760000
AIF (T'&ATTRID EQ 'O').PL20 . SKIP IF *NO* 'ATTRID' 00770000
AIF (T'&OUTLEN EQ 'O').PL30 . SKIP IF ATTRID, *NO* 'OUTLEN' 00780000
SPACE 00790000
MNOTE 08,'N2001 CONFLICTING OPERANDS -- OUTLEN/ATTRID' 00800000
SPACE 00810000
AGO .PL40 . SKIP TO TREAT AS IF *NEITHER* 00820000
.* 00830000
.* NO ATTRIBUTES IDENTIFIER SPECIFIED -- IF OUTPUT LENGTH SPECIFIED, 00840000
.* GENERATE AS PER USER'S SPECIFICATIONS -- ELSE GENERATE ZEROS 00850000
.* 00860000
.PL20 ANOP 00870000
AIF (T'&OUTLEN EQ 'O').PL40 . SKIP IF *NO* 'OUTLEN' 00880000
DC AL2(&OUTLEN) OUL/EFL/ATI--LENGTHS OR ID 00890000
AGO .PL50 . SKIP TO JOIN COMMON GENERATION 00900000
.* 00910000
.* ATTRIBUTES IDENTIFIER SPECIFIED -- GENERATE AS PER USER SPECS 00920000
.* 00930000
.PL30 ANOP 00940000
DC AL2(&ATTRID) ATI/OUL/EFL--ID OR LENGTHS 00950000
AGO .PL50 . SKIP TO JOIN COMMON GENERATION 00960000
.* 00970000
.* NEITHER 'OUTLEN' NOR 'ATTRID' SPECIFIED -- GENERATE ZEROS 00980000
.* 00990000
.PL40 ANOP 01000000
DC AL2(0) OUL/EFL/ATI--LENGTHS OR ID 01010000
.* 01020000
.* GENERATE MAXIMUM INPUT LENGTH AS PER USER SPECIFICATION 01030000
.* 01040000
.PL50 ANOP . COMMON RESUME POINT 01050000
DC AL2(&INLEN) INL--MAXIMUM INPUT LENGTH 01060000
.* 01070000
.* GENERATE RECORD AREA ADDRESS AS PER USER SPECIFICATION 01080000
.* 01090000
DC AL2(&RECA) RAA--ADDRESS OF RECORD AREA 01100000
.* 01110000
.* GENERATE THREE INTERNAL WORK FIELDS AS ZEROS 01120000
.* 01130000
DC AL2(0) WKA--INTERNAL WORK FIELD 01140000
DC AL2(0) WKB--INTERNAL WORK FIELD 01150000
DC AL2(0) WKC--INTERNAL WORK FIELD 01160000
* *** END GENERATION -- $NPL *** 01170000
SPACE 01180000
MEND 01190000