|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/3 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/3 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 2032 (0x7f0)
Types: s3xseg
Names: »SSTIME«
└─⟦811594a0b⟧ Bits:30009185 5702-sc1.V16.pgm
└─⟦8223a6838⟧
└─⟦this⟧ »SSTIME«
└─⟦990ba7470⟧ Bits:30009182 5702-PP1
└─⟦efad88270⟧
└─⟦this⟧ »SSTIME«
MACRO
&NAME STIME &UNITS-
GBLB &ONCE
TEXT
*A MACRO TO LINK TO THE RESIDENT CODE TO HALT THE PROGRAM FOR A TIME
*DATE LAST CHANGED 02/13/74
AIF (T'&NAME EQ 'O').NNM
&NAME EQU * GENERATE USER LABEL.
.NNM ANOP
AIF (T'&UNITS EQ 'O').REG
LA &UNITS,2 POINT TO 3 BYTE HALT TIME.
.REG ANOP
ST $TSV2,2 SAVE REG.
AIF (&ONCE).FOUND
$TF01 EQU *
JC $TFEND,X'80' A FIRST TIME SWITCH,SET NOT TO JUMP
MVI $TF01+1,X'87' SET SWITCH TO SKIP
L X'11',1 POINT TO SCA.
L 1(,1),1 POINT TO PLCA.
L X'16'(,1),1 POINT TO START OF PL1.
A $TNG1,1 POINT TO ENTRY ADDRESS.
ST $TICOM,1 SAVE ADDR OF PTR TO COMMON
ST $TIADD,1 SET SEARCH ADDRESS
$TFLUP EQU *
CLC $TIADD(2),$TIEND CHECK IF DONE
BE $TNSUP IF EQ,TIMER NOT SUPPORTED
ALC $TIADD(2),$TNG1 NOT EQ,TRY NEXT
CLC $TSUP,0 COMMON CONSTANT FOUND
$TIADD EQU *-1
BNE $TFLUP NO,KEEP TRYING
MVC 0(2,1),$TIADD POINT TO BEGINING OF COMMON
SLC 0(2,1),$TFCL SET POINTER
$TFEND EQU *
.FOUND ANOP
L $TICOM,2 POINT TO POINTER TO COMMON
L 0(,2),2 POINT TO COMMON
ST $TG&SYSNDX+3,2 SET ENTRY POINT
ALC $TG&SYSNDX+3,$TNG4(2) POINT TO ENTRY
L $TSV2,2 RESTORE REGISTER
$TG&SYSNDX B 0 GOTO RESIDENT CODE
AIF (&ONCE).XIT
J $TXIT *
$TNSUP HPL X'3C',X'3C' HALT FF
HPL X'7D',X'6F' HALT 06
LA $THALT,2 POINT TO PARM LIST
B 4 GO HALT
DC XL1'85' HALT/SYSLOG
$THALT EQU *
DC XL1'DA' HALT FROM ASSM
DC CL3'Q05' SUBCOMPONENT,HALT CODE
DC XL1'01' CANCEL ONLY
DC CL2'NS' SUBMESSAGE
$TNG1 DC IL2'-1'
$TICOM DS XL2
$TSV2 DS XL2
$TNG4 DC XL2'006F'
$TSUP DC CL6'O$TIME'
$TFCL DC IL2'104'
$TIEND DC XL2'0400'
$TXIT EQU *
.XIT ANOP
&ONCE SETB 1
MEND