|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/3 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/3 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 2540 (0x9ec)
Types: s3xseg
Names: »S$BCSW«
└─⟦34f897e8c⟧ Bits:30009186 5702-sc1.V16.scp
└─⟦e1bdf435f⟧
└─⟦this⟧ »S$BCSW«
MACRO 00010000
&LABEL $BCSW &PARM- 00020000
TEXT 00190000
* CHANGE A SWITCHED ID LIST RELEASE-8 00200000
AIF (T'&LABEL EQ '').A 00210000
&LABEL EQU * 00220000
.A AIF (T'&PARM EQ '').A1 00230000
LA &PARM,$BPRM1 LOAD PARM ADDR IN XR1. 00240000
.A1 ST $RS&SYSNDX,$BPRS2 SAVE XR2. 00250000
L $BPDTF(,$BPRM1),$DTF LOAD ADDR OF DTF IN XR2. 00260000
L $BDRID(,$DTF),$BLST2 LOAD ADDR OF LIST IN XR2. 00270000
$GO&SYSNDX EQU * 00280000
MVI $LN&SYSNDX+2,$DT&SYSNDX INIT TO JMP ARND ENBL/OR DISABLE. 00290000
LA 1(,$BLST2),$BLST2 BUMP XR2 TO LGTH IN SW ID LIST. 00300000
MVC $DE&SYSNDX+2(1),0(,$BLST2) SAVE LGTH OF ID CHARS. 00310000
CLI $BPNUM(,$BPRM1),0 LENGTH=0 IN PARM LIST? 00320000
JNE $MR&SYSNDX NO, CONTINUE CHECKING 00330000
CLI 0(,$BLST2),0 LENGTH=0 IN SW ID LIST? 00340000
JE $CK&SYSNDX YES, NO FURTHER CHK NEEDED 00350000
J $DE&SYSNDX NO, NOT A MATCH 00360000
$MR&SYSNDX EQU * 00370000
MVI $EQ&SYSNDX+3,$BPNUM INITLZ DISP TO LENGTH 00380000
MVI $EQ&SYSNDX+1,$BFOX * INIT LGTH IN COMPARE INSTR 00390000
ALC $EQ&SYSNDX+1,$BPNUM(1,$BPRM1) * LGTH - 1. 00400000
MVC $EQ&SYSNDX+2,$BPNUM(1,$BPRM1) INIT XR1 DISP IN CLC INSTR 00410000
ALC $EQ&SYSNDX+3,$BPNUM(1,$BPRM1) INIT XR2 DISP IN CLC INSTR 00420000
$EQ&SYSNDX EQU * 00430000
CLC *-*(*-*,$BLIST),*-*(,$BPRM1) ARE CHARS EQUAL? 00440000
JNE $DE&SYSNDX NO-SKIP FOLLOWING. 00450000
CLC 3(1,$BPRM1),0(,$BLST2) *ARE LGTHS UNEQUAL 00460000
TBF $BPATR(,$BPRM1),$BPEXT *AND EXACTLY MATCH ON? 00470000
JC $DE&SYSNDX,$TRU+$EQ YES-THEN SKIP ENABLE/OR DISABLE. 00480000
$CK&SYSNDX EQU * 00490000
MVI $LN&SYSNDX+2,$BPNOP SET TO NO-OP JUMP INSTR. 00500000
$DE&SYSNDX EQU * 00510000
LA *-*(,$BLST2),$BLST2 BUMP XR2 TO END OF ID CHARS. 00520000
$LN&SYSNDX EQU * 00530000
J *-* 00540000
$AC&SYSNDX EQU * 00550000
SBF 1(,$BLST2),$BPENA SET ACTIVE. 00560000
TBF $BPATR(,$BPRM1),$BPACT ACTIVATE SPECIFIED? 00570000
JT $BP&SYSNDX YES-SKIP FOLLOWING INSTR. 00580000
SBN 1(,$BLST2),$BPENA SET INACTIVE. 00590000
$BP&SYSNDX EQU * 00600000
LA 2(,$BLST2),$BLST2 BUMP TO NEXT SWITCHED ID ENTRY. 00610000
CLI 0(,$BLST2),$BPEND Q IS THIS THE END OF THE LIST. 00620000
BL $GO&SYSNDX CHECK NEXT ENTRY IN LIST. 00630000
LA *-*,$BPRS2 RESTORE XR2. 00640000
$RS&SYSNDX EQU *-1 00650000
$DT&SYSNDX EQU $BP&SYSNDX-$AC&SYSNDX 00660000
MEND 00670000