|
DataMuseum.dkPresents historical artifacts from the history of: IBM System/3 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about IBM System/3 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 17526 (0x4476)
Types: s3xseg
Names: »S$EBSC«
└─⟦d0bc1a931⟧ Bits:30009189 5704-sc1.V08.ccp
└─⟦64693a1c9⟧
└─⟦this⟧ »S$EBSC«
MACRO 00010000
.********************************************************************** 00020000
.* * 00030000
.* NAME: $EBSC * 00040000
.* * 00050000
.* MODIFICATION LEVEL: VERSION 0, MODIFICATION LEVEL 0 * 00060000
.* * 00070000
.* FUNCTION: * 00080000
.* * 00090000
.* . CCP GENERATION FIRST PASS MACRO-INSTRUCTION -- DEFINE BSCA * 00100000
.* SUPPORT. * 00110000
.* * 00120000
.* INPUT OPERANDS: * 00130000
.* * 00140000
.* . BSCA-0/1/2 * 00150000
.* * 00160000
.* NUMBER OF BSC ADAPTERS. OPERAND REQUIRED IF THIS STATEMENT * 00170000
.* IS USED. * 00180000
.* * 00190000
.* . DIAL-YES/NO * 00200000
.* * 00210000
.* SPECIFIES WHETHER SWITCHED-LINE SUPPORT IS TO BE INCLUDED. * 00220000
.* DEFAULT IS NO. * 00230000
.* * 00240000
.* . PP-YES/NO * 00250000
.* * 00260000
.* SPECIFIES WHETHER POINT-TO-POINT SUPPORT IS TO BE INCLUDED. * 00270000
.* DEFAULT IS NO. * 00280000
.* * 00290000
.* . MP-YES/NO * 00300000
.* * 00310000
.* SPECIFIES WHETHER MULTIPOINT TRIBUTARY SUPPORT IS TO BE * 00320000
.* INCLUDED. DEFAULT IS NO. * 00330000
.* * 00340000
.* . CS-YES/NO * 00350000
.* * 00360000
.* SPECIFIES WHETHER MULTIPOINT CONTROL STATION SUPPORT IS TO BE * 00370000
.* INCLUDED. DEFAULT IS NO. * 00380000
.* * 00390000
.* . GETMSG-YES/NO * 00400000
.* * 00410000
.* SPECIFIES WHETHER 'GATHER READ' SUPPORT IS TO BE INCLUDED. * 00420000
.* DEFAULT IS NO. * 00430000
.* * 00440000
.* . ITB-YES/NO * 00450000
.* * 00460000
.* SPECIFIES WHETHER INTERMEDIATE-TEXT-BLOCK SUPPORT IS TO BE * 00470000
.* INCLUDED. DEFAULT IS NO. * 00480000
.* * 00490000
.* . RECSEP-XX * 00500000
.* * 00510000
.* SPECIFIES ALTERNATE RECORD-SEPARATOR BYTE. OPERAND IS * 00520000
.* OPTIONAL. DEFAULT IS "1E". 00530000
.* * 00540000
.* . ASCII-YES/NO * 00550000
.* * 00560000
.* SPECIFIES WHETHER SUPPORT FOR ASCII TRANSMISSION CODE IS TO * 00570000
.* BE INCLUDED. DEFAULT IS NO. * 00580000
.* * 00590000
.* . EBCDIC-YES/NO * 00600000
.* * 00610000
.* SPECIFIES WHETHER SUPPORT FOR EBCDIC TRANSMISSION CODE IS TO * 00620000
.* BE INCLUDED. DEFAULT IS *YES*. * 00630000
.* * 00640000
.* . RESPOL-YES/NO * 00650000
.* * 00660000
.* SPECIFIES WHETHER RESIDENT POLLING IS TO BE INCLUDED FOR * 00670000
.* CONTROL-STATION LINE SUPPORT. DEFAULT IS NO. * 00680000
.* * 00690000
.* . AUTORS-YES/NO * 00700000
.* * 00710000
.* SPECIFIES WHETHER AUTO-RESPONSE SUPPORT IS TO BE INCLUDED * 00720000
.* FOR MULTIPOINT TRIBUTARY LINES. DEFAULT IS NO. * 00730000
.* * 00740000
.* . XPRNCY-YES/NO * 00750000
.* * 00760000
.* SPECIFIES WHETHER TEXT TRANSPARENCY FEATURE IS TO BE SUPPORTED * 00770000
.* -- DEFAULT IS NO. * 00780000
.* * 00790000
.* . INTPOL-YES/NO * 00800000
.* * 00810000
.* SPECIFIES WHETHER INTERVAL POLLING FEATURE IS TO BE SUPPORTED * 00820000
.* -- DEFAULT IS NO. * 00830000
.* * 00840000
.* . DA-YES/NO * 00850000
.* * 00860000
.* SPECIFIES WHETHER IDA FEATURE IS TO BE SUPPORTED 00870000
.* -- DEFAULT IS NO. 00880000
.* 00890000
.********************************************************************** 00900000
$EBSC &BSCA-,&DIAL-NO,&PP-NO,&MP-NO,&CS-NO,&GETMSG-NO,&ITB-NO, X00910000
&RECSEP-,&ASCII-NO,&EBCDIC-YES,&RESPOL-NO,&AUTORS-NO, X00920000
&XPRNCY-NO,&INTPOL-NO,&DA-NO 00930000
.* 00940000
GBLA &SEQ . SEQUENCE CONTROL: 00950000
.* . MUST BE 5, 6, 7 UPON ENTRY 00960000
.* . IF 6 THEN &MLA MUST BE 0 00970000
.* . IS MADE 8 AFTER PROCESSING 00980000
GBLB &TERR . TERMINATION ERROR SWITCH 00990000
.* 01000000
GBLB &BIDA . IDA SUPPORT 01010000
GBLA &BSC . NUMBER BSC ADAPTERS 01020000
GBLC &BLT . BSC LINE TYPES SUPPORTED 01030000
GBLC &BFA . BSCA FEATURES SUPPORTED 01040000
GBLC &RSB . HEX RECORD SEPARATOR 01050000
GBLA &MLA . NUMBER MLTA LINES 01060000
GBLB &INPOL . INTERVAL POLLING SUPPORT. 01070000
.* 01080000
LCLA &N . NUMBER OF CHARACTERS 01090000
LCLC &C1,&C2 . FOR MANIPULATING CHAR VALUES 01100000
.* 01110000
TABLE &DIAL . SWITCHED LINE SUPPORT 01120000
YES TABDF 1 01130000
Y TABDF 1 01140000
NO TABDF 0 01150000
N TABDF 0 01160000
TABDF * . INVALID PARAMETER 01170000
.* 01180000
TABLE &PP . POINT-TO-POINT SUPPORT 01190000
YES TABDF 1 01200000
Y TABDF 1 01210000
NO TABDF 0 01220000
N TABDF 0 01230000
TABDF * . INVALID PARAMETER 01240000
.* 01250000
TABLE &MP . MULTIPOINT TRIBUTARY SUPPORT 01260000
YES TABDF 1 01270000
Y TABDF 1 01280000
NO TABDF 0 01290000
N TABDF 0 01300000
TABDF * . INVALID PARAMETER 01310000
.* 01320000
TABLE &CS . CONTROL STATION SUPPORT 01330000
YES TABDF 1 01340000
Y TABDF 1 01350000
NO TABDF 0 01360000
N TABDF 0 01370000
TABDF * . INVALID PARAMETER 01380000
.* 01390000
TABLE &GETMSG . GATHER-READ SUPPORT 01400000
YES TABDF 1 01410000
Y TABDF 1 01420000
NO TABDF 0 01430000
N TABDF 0 01440000
TABDF * . INVALID PARAMETER 01450000
.* 01460000
TABLE &ITB . INTERMEDIATE TEXT BLOCK SUPPRT 01470000
YES TABDF 1 01480000
Y TABDF 1 01490000
NO TABDF 0 01500000
N TABDF 0 01510000
TABDF * . INVALID PARAMETER 01520000
.* 01530000
TABLE &ASCII . ASCII TRANSMISSION CODE 01540000
YES TABDF 1 01550000
Y TABDF 1 01560000
NO TABDF 0 01570000
N TABDF 0 01580000
TABDF * . INVALID PARAMETER 01590000
.* 01600000
TABLE &EBCDIC . EBCDIC TRANSMISSION CODE 01610000
YES TABDF 1 01620000
Y TABDF 1 01630000
NO TABDF 0 01640000
N TABDF 0 01650000
TABDF * . INVALID PARAMETER 01660000
.* 01670000
TABLE &RESPOL . RESIDENT POLLING 01680000
YES TABDF 1 01690000
Y TABDF 1 01700000
NO TABDF 0 01710000
N TABDF 0 01720000
TABDF * . INVALID PARAMETER 01730000
.* 01740000
TABLE &AUTORS . AUTO RESPONSE 01750000
YES TABDF 1 01760000
Y TABDF 1 01770000
NO TABDF 0 01780000
N TABDF 0 01790000
TABDF * . INVALID PARAMETER 01800000
.* 01810000
TABLE &XPRNCY . TRANSPARENCY FEATURE 01820000
YES TABDF 1 01830000
Y TABDF 1 01840000
NO TABDF 0 01850000
N TABDF 0 01860000
TABDF * . INVALID PARAMETER 01870000
.* 01880000
TABLE &INTPOL . INTERVAL POLLING FEATURE 01890000
NO TABDF 0 01900000
N TABDF 0 01910000
YES TABDF 1 01920000
Y TABDF 1 01930000
TABDF * . INVALID PARAMETER 01940000
.* 01950000
TABLE &DA . DA FEATURE 01960000
YES TABDF 1 01970000
Y TABDF 1 01980000
NO TABDF 0 01990000
N TABDF 0 02000000
TABDF * . INVALID PARAMETER 02010000
.* 02020000
TEXT 02030000
.* 02040000
.*--------- CHECK STATEMENT SEQUENCE -------------------------------* 02050000
.* 02060000
AIF (&SEQ EQ '5').SEQOK . OK IF $EFIL PREVIOUS 02070000
AIF (&SEQ EQ '7').SEQOK . OK IF $EMLD PREVIOUS 02080000
AIF (&SEQ NE '6').SEQER . ERROR IF NOT $EMLA PREVIOUS 02090000
AIF (&MLA EQ '0').SEQOK . OK IF $EMLA AND LINES-0 02100000
.* 02110000
.SEQER ANOP 02120000
*!400E $EBSC STATEMENT OUT OF SEQUENCE -- OR PRECEDING STATEMENT ERROR 02130000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02140000
&BLT SETC '' . MAKE NULL PREVIOUS SPEC 02150000
&BFA SETC '' . MAKE NULL PREVIOUS SPEC 02160000
.* 02170000
.SEQOK ANOP . VALID SEQUENCE 02180000
.* 02190000
.*--------- BSCA-0/1/2 ---------------------------------------------* 02200000
.* 02210000
AIF (T'&BSCA NE 'O').BSCA . SKIP IF BSCA SPECIFIED 02220000
.* 02230000
*!405E MISSING 'BSCA' OPERAND -- MUST BE SPECIFIED IF STATEMENT USED 02240000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02250000
AGO .BSEND 02260000
.* 02270000
.BSCA ANOP . BSCA SPECIFIED 02280000
AIF (T'&BSCA NE 'N').BSERR . ERROR IF NOT NUMERIC 02290000
AIF (K'&BSCA GT '4').BSERR . SKIP IF LONGER THAN 4 DIGITS 02300000
&N SETA &BSCA 02310000
AIF (&N EQ '0').BS0 . SKIP IF BSCA-0 02320000
AIF (&N LE '2').BSOK . SKIP IF BSCA-1 OR BSCA-2 02330000
.* 02340000
.BSERR ANOP 02350000
*!410E INVALID 'BSCA' PARAMETER -- MUST BE NUMBER IN RANGE 0-2 02360000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02370000
AGO .BSEND 02380000
.* 02390000
.BS0 ANOP . BSCA-0 02400000
AIF ('&DIAL&PP&MP&CS&GETMSG&ITB' NE '000000').BS0ER 02410000
AIF ('&ASCII&EBCDIC&RESPOL&AUTORS' NE '0100').BS0ER 02420000
AIF (&RECSEP EQ 'NO').END 02430000
AIF (&RECSEP EQ 'N').END 02440000
.BS0ER ANOP 02450000
*!415E BSCA-0, BUT OTHER OPERAND SPECIFIED WITH NON-DEFAULT PARAMETER 02460000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02470000
.* 02480000
.BSOK ANOP . BSCA-1 OR BSCA-2 02490000
&BSC SETA &BSCA . NUMBER BSC ADAPTERS 02500000
.* 02510000
.BSEND ANOP . END OPERAND 'BSCA' 02520000
.* 02530000
.*----------- DA-YES/Y/NO/N (YES=1, NO=0) --------------------------* 02540000
.* 02550000
AIF (&DA NE '*').DAOK 02560000
*!417E INVALID 'DA' PARAMETER -- MUST BE YES/Y/NO/N 02570000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02580000
AGO .DAEND 02590000
.* 02600000
.DAOK ANOP 02610000
AIF (&DA NE '1').DAEND 02620000
AIF (&BSC GT '0').BIDK 02630000
*!419E IF DA-YES, MUST SPECIFY BSCA-1 OR BSCA-2 02640000
&TERR SETB 1 02650000
AGO .DAEND 02660000
.* 02670000
.BIDK ANOP . SET 'IDA' SUPPORT 02680000
&BIDA SETB 1 02690000
.* 02700000
.DAEND ANOP . END OPERAND 'DA' 02710000
.* 02720000
.*--------- PP-YES/Y/NO/N (YES=1, NO=0) ----------------------------* 02730000
.* 02740000
AIF (&PP NE '*').PPOK . SKIP IF VALID PARAMETER 02750000
.* 02760000
*!425E INVALID 'PP' PARAMETER -- MUST BE YES/Y/NO/N 02770000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02780000
AGO .PPEND 02790000
.* 02800000
.PPOK ANOP . VALID PARAMETER 02810000
&BLT SETC '&PP' . SET X 02820000
.* 02830000
.PPEND ANOP . END OPERAND 'PP' 02840000
.* 02850000
.*--------- MP-YES/Y/NO/N (YES=1, NO=0) ----------------------------* 02860000
.* 02870000
AIF (&MP NE '*').MPOK . SKIP IF VALID PARAMETER 02880000
.* 02890000
*!430E INVALID 'MP' PARAMETER -- MUST BE YES/Y/NO/N 02900000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 02910000
AGO .MPEND 02920000
.* 02930000
.MPOK ANOP . VALID PARAMETER 02940000
&BLT SETC '&BLT&MP' . SET .X 02950000
.* 02960000
.MPEND ANOP . END OPERAND 'MP' 02970000
.* 02980000
.*--------- CS-YES/Y/NO/N (YES=1, NO=0) ----------------------------* 02990000
.* 03000000
AIF (&CS NE '*').CSOK . SKIP IF VALID PARAMETER 03010000
.* 03020000
*!435E INVALID 'CS' PARAMETER -- MUST BE YES/Y/NO/N 03030000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03040000
AGO .CSEND 03050000
.* 03060000
.CSOK ANOP . VALID PARAMETER 03070000
&BLT SETC '&BLT&CS' . SET ..X 03080000
.* 03090000
.CSEND ANOP . END OPERAND 'CS' 03100000
.* 03110000
.*--------- DIAL-YES/Y/NO/N (YES=1, NO=0) --------------------------* 03120000
.* 03130000
AIF (&DIAL NE '*').DIOK . SKIP IF VALID PARAMETER 03140000
.* 03150000
*!420E INVALID 'DIAL' PARAMETER -- MUST BE YES/Y/NO/N 03160000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03170000
AGO .DIEND 03180000
.* 03190000
.DIOK ANOP 03200000
&BLT SETC '&BLT&DIAL' . SET ...X 03210000
.* 03220000
.DIEND ANOP . END OPERAND 'DIAL' 03230000
.* 03240000
.*--------- ASSURE AT LEAST ONE LINE TYPE SPECIFIED ----------------* 03250000
.* 03260000
AIF (&BLT NE '0000').LTEND . SKIP IF AT LEAST 1 TYPE 03270000
.* 03280000
*!440E BSCA PRESENT BUT NO LINE TYPES SPECIFIED 03290000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03300000
.* 03310000
.LTEND ANOP . END CHECK OF LINE TYPES 03320000
.* 03330000
.*--------- GETMSG-YES/Y/NO/N (YES=1, NO=0) -------------------------* 03340000
.* 03350000
AIF (&GETMSG NE '*').GMOK . SKIP IF VALID PARAMETER 03360000
.* 03370000
*!445E INVALID 'GETMSG' PARAMETER -- MUST BE YES/Y/NO/N 03380000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03390000
AGO .GMEND 03400000
.* 03410000
.GMOK ANOP . VALID PARAMETER 03420000
&BFA SETC '&GETMSG' . SET X 03430000
.* 03440000
.GMEND ANOP . END OPERAND 'GETMSG' 03450000
.* 03460000
.*--------- ITB-YES/Y/NO/N (YES=1, NO=0) ---------------------------* 03470000
.* 03480000
AIF (&ITB NE '*').ITOK . SKIP IF VALID PARAMETER 03490000
.* 03500000
*!450E INVALID 'ITB' PARAMETER -- MUST BE YES/Y/NO/N 03510000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03520000
.* 03530000
.ITOK ANOP . VALID PARAMETER 03540000
&BFA SETC '&BFA&ITB' . SET .X 03550000
.* 03560000
.ITEND ANOP . END OPERAND 'ITB' 03570000
.* 03580000
.*--------- RECSEP-XX ----------------------------------------------* 03590000
.* 03600000
AIF (T'&RECSEP EQ 'O').RSNO . SKIP IF RECSEP OMITTED 03610000
&N SETA K'&RECSEP . LENGTH OF PARAMETER 03620000
AIF (&N NE '2').RSERR . ERROR IF NOT 2 CHARS 03630000
.* 03640000
AIF ('&RECSEP'(1,1) GT '9').RSERR . ERR IF GT 9 03650000
AIF ('&RECSEP'(1,1) LT 'A').RSERR . ERR IF LT 'A' 03660000
AIF ('&RECSEP'(1,1) LE 'F').RS2 . OK IF IN RANGE A-F 03670000
AIF ('&RECSEP'(1,1) LT '0').RSERR . ERR IF NOT IN RANGE 0-9 03680000
.RS2 ANOP 03690000
AIF ('&RECSEP'(2,1) GT '9').RSERR . ERR IF GT 9 03700000
AIF ('&RECSEP'(2,1) LT 'A').RSERR . ERR IF LT 'A' 03710000
AIF ('&RECSEP'(2,1) LE 'F').RSYES . OK IF IN RANGE A-F 03720000
AIF ('&RECSEP'(2,1) GE '0').RSYES . OK IF IN RANGE 0-9 03730000
.* 03740000
.RSERR ANOP . INVALID PARAMETER 03750000
*!455E INVALID 'RECSEP' PARAMETER -- MUST BE 2 HEX DIGITS 03760000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03770000
AGO .RSEND 03780000
.* 03790000
.RSNO ANOP . RECSEP-NO 03800000
&BFA SETC '&BFA.0' . SET ..X 03810000
AGO .RSEND 03820000
.* 03830000
.RSYES ANOP . RECSEP-XX 03840000
&BFA SETC '&BFA.1' 03850000
&RSB SETC '1E' . SET DEFAULT RECORD-SEPARATOR 03860000
&RSB SETC '&RECSEP' . RECSEP CHARACTER 03870000
.* 03880000
.RSEND ANOP . END OPERAND 'RECSEP' 03890000
.* 03900000
.*---------- INTPOL-YES/Y/NO/N (YES=1, NO=0) ----------------------* 03910000
.* 03920000
AIF (&INTPOL NE '*').IPOK . SKIP IF VALID PARAMETER 03930000
.* 03940000
*!481E INVALID 'INTPOL' PARAMETER -- MUST BE YES/Y/NO/N 03950000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 03960000
AGO .IPEND 03970000
.* 03980000
.IPOK ANOP . VALID PARAMETER 03990000
AIF (&INTPOL EQ '0').IPEND . SKIP IF INTPOL-NO 04000000
&INPOL SETB 1 . SET INTERVAL POLLINE 04010000
.* 04020000
.IPEND ANOP . END OPERAND 'INTPOL' 04030000
.* 04040000
.*--------- RESPOL-YES/Y/NO/N (YES=1, NO=0) ------------------------* 04050000
.* 04060000
AIF (&RESPOL NE '*').RPOK . SKIP IF VALID PARAMETER 04070000
.* 04080000
*!480E INVALID 'RESPOL' PARAMETER -- MUST BE YES/Y/NO/N 04090000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04100000
AGO .RPEND 04110000
.* 04120000
.RPOK ANOP . VALID PARAMETER 04130000
&BFA SETC '&BFA&RESPOL' . SET ...X 04140000
AIF (&RESPOL NE '1').RPEND . SKIP UNLESS RESPOL-YES 04150000
AIF (&CS NE '0').RPEND . SKIP UNLESS RESPOL-YES/CS-NO 04160000
.* 04170000
*!482W RESPOL-YES SPECIFIED WITH CS-NO -- TREATED AS RESPOL-NO 04180000
.* 04190000
.RPEND ANOP . END OPERAND 'RESPOL' 04200000
.* 04210000
.*--------- AUTORS-YES/Y/NO/N (YES=1, NO=0) ------------------------* 04220000
.* 04230000
AIF (&AUTORS NE '*').AUOK . SKIP IF VALID PARAMETER 04240000
.* 04250000
*!485E INVALID 'AUTORS' PARAMETER -- MUST BE YES/Y/NO/N 04260000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04270000
AGO .AUEND 04280000
.* 04290000
.AUOK ANOP . VALID PARAMETER 04300000
&BFA SETC '&BFA&AUTORS' . SET ....X 04310000
AIF (&AUTORS NE '1').AUEND . SKIP UNLESS AUTORS-YES 04320000
AIF (&MP NE '0').AUEND . SKIP UNLESS AUTORS-YES/MP-NO 04330000
.* 04340000
*!487W AUTORS-YES SPECIFIED WITH CS-NO -- TREATED AS AUTORS-NO 04350000
.* 04360000
.AUEND ANOP . END OPERAND 'AUTORS' 04370000
.* 04380000
.*--------- EBCDIC-YES/Y/NO/N (YES/NULL=1, NO=0) -------------------* 04390000
.* 04400000
AIF (&EBCDIC NE '*').EBOK . SKIP IF VALID PARAMETER 04410000
.* 04420000
*!465E INVALID 'EBCDIC' PARAMETER -- MUST BE YES/Y/NO/N 04430000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04440000
AGO .EBEND 04450000
.* 04460000
.EBOK ANOP . VALID PARAMETER 04470000
&BFA SETC '&BFA&EBCDIC' . SET .....X 04480000
.* 04490000
.EBEND ANOP . END OPERAND 'EBCDIC' 04500000
.* 04510000
.*--------- ASCII-YES/Y/NO/N (YES=1, NO=0) -------------------------* 04520000
.* 04530000
AIF (&ASCII NE '*').ASOK . SKIP IF VALID PARAMETER 04540000
.* 04550000
*!460E INVALID 'ASCII' PARAMETER -- MUST BE YES/Y/NO/N 04560000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04570000
AGO .ASEND 04580000
.* 04590000
.ASOK ANOP . VALID PARAMETER 04600000
&BFA SETC '&BFA&ASCII' . SET ......X 04610000
.* 04620000
AIF ('&BFA'(6,2) NE '00').ASCK2 04630000
.* 04640000
*!470E BSCA PRESENT BUT NEITHER TRANSMISSION CODE IS USED 04650000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04660000
AGO .ASEND 04670000
.* 04680000
.ASCK2 ANOP 04690000
AIF ('&BFA'(6,2) NE '11').ASEND . SKIP UNLESS ASCII/EBCDIC-Y 04700000
AIF (&BSCA NE '1').ASEND . SKIP UNLESS BSCA-1 04710000
.* 04720000
*!472E EBCDIC-YES AND ASCII-YES SPECIFIED WITH BSCA-1 -- NOT POSSIBLE 04730000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04740000
.* 04750000
.ASEND ANOP . END OPERAND 'ASCII' 04760000
.* 04770000
.*--------- XPRNCY-YES/Y/NO/N (YES=1, NO=0) ------------------------* 04780000
.* 04790000
AIF (&XPRNCY NE '*').XPOK . SKIP IF VALID PARAMETER 04800000
.* 04810000
*!490E INVALID 'XPRNCY' PARAMETER -- MUST BE YES/Y/NO/N 04820000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04830000
AGO .XPEND 04840000
.* 04850000
.XPOK ANOP . VALID PARAMETER 04860000
&BFA SETC '&BFA&XPRNCY' . SET .......X 04870000
.* 04880000
AIF (&XPRNCY EQ '0').XPEND . SKIP IF XPRNCY-NO 04890000
.* 04900000
AIF (&EBCDIC NE '0').XPEND . SKIP UNLESS EBCDIC-NO 04910000
.* 04920000
*!492E XPRNCY-YES SPECIFIED WITH EBCDIC-NO -- NOT VALID 04930000
&TERR SETB 1 . SET TERMINATION ERROR SWITCH 04940000
.* 04950000
.XPEND ANOP . END OPERAND 'XPRNCY' 04960000
.* 04970000
.*--------- SET STATEMENT SEQUENCE ---------------------------------* 04980000
.* 04990000
.END ANOP 05000000
&SEQ SETA 8 . INDICATE $EBSC PROCESSED 05010000
.* 05020000
MEND 05030000