⟦79a8ddca4⟧

E3 Source Code



with Lexical, Bounded_String, Set_Of_Connections, Set_Of_Links;
with Models, Symbols, Comps_Dictionary;

use Lexical, Bounded_String;

package Abstract_Tree is

    Bad_Type : exception;

    type Node_Type is (Struct_Type, Enumeration_Type, Integer_Type,
                       Boolean_Type, State_Type, Entry_Type, Other_Type);

    type Object is private;

    -- Noeud d'operateur binaire (comparaison,mathematique et logique) ---------------------

    function Make_Node (Operation : Token; Left, Right : Object) return Object;


    -- Noeud d'operateur unaire ------------------------------------------------------------

    function Make_Node (Operation : Token; Down : Object) return Object;


    -- Noeud d'entier ----------------------------------------------------------------------

    function Make_Node (Value : Integer) return Object;


    -- Noeud de Booleen ou d'etat de lien/connexion ----------------------------------------
   function Make_Node (Value : Token) return Object;


    -- Noeud de variable ou enumere --------------------------------------------------------

    function Make_Node (Name, Extension : String;
                        Models_Table : Models.Object;
                        Symbols_Table : Symbols.Object) return Object;


    -- Noeud de fonction interne -----------------------------------------------------------

    function Make_Node (Name : Token; Param1, Param2 : String) return Object;


    -- Noeud d'entree utilisateur ----------------------------------------------------------

    function Make_Node (Entry1, Entry2, Entry3 : String) return Object;


    -- Destruction de l'arbre --------------------------------------------------------------

    procedure Destroy (Node : in out Object);


    -- Evaluation d'un arbre retournant un entier ou un enumere ----------------------------
    --
    -- Bad_Type (Exception) est levee si on appelle cette fonction avec un
    --                      noeud qui ne retourne pas un entier ou un enumere.

    function Evaluate_Node (Node : Object;
                            Models_Table : Models.Object;
                            Symbols_Table : Symbols.Object;
                            Connect : Set_Of_Connections.Object;
                            Links : Set_Of_Links.Object;
                            Comp_Dict : Comps_Dictionary.Object) return Integer;


    -- Evaluation d'un arbre retournant un booleen -----------------------------------------
    --
    -- Bad_Type (Exception) est levee si on appelle cette fonction avec un
    --                      noeud qui ne retourne pas un booleen.

    function Evaluate_Node (Node : Object;
                            Models_Table : Models.Object;
                            Symbols_Table : Symbols.Object;
                            Connect : Set_Of_Connections.Object;
                            Links : Set_Of_Links.Object;
                            Comp_Dict : Comps_Dictionary.Object) return Boolean;


    -- Evaluation d'un arbre retournant l'etat lien/connexion ou un nom de structure -------
    --
    -- Bad_Type (Exception) est levee si on appelle cette fonction avec un
    --                      noeud qui ne retourne pas un etat ou un nom de structure.

    function Evaluate_Node (Node : Object;
                            Models_Table : Models.Object;
                            Symbols_Table : Symbols.Object;
                            Connect : Set_Of_Connections.Object;
                            Links : Set_Of_Links.Object;
                            Comp_Dict : Comps_Dictionary.Object) return String;


    -- Renvoie le type d'un noeud ----------------------------------------------------------

    function What_Type (Node : Object) return Node_Type;


    -- Affichage d'un  arbre abstrait ------------------------------------------------------

    procedure Dump (Node : Object);
    procedure Dump_Struct (Nb : Integer; Node : Object);

private
    type Cell_Type is (Binary_Operator, Unary_Operator,
                       Integer_Data, Boolean_Data, State_Data,
                       Var_Data, Instruction, Player_Entry);

    type Cell (Kind : Cell_Type := Binary_Operator) is
        record
            Return_Type : Node_Type;
            case Kind is
                when Binary_Operator =>
                    Binary_Kind : Token;
                    Left_Node, Right_Node : Object;
                when Unary_Operator =>
                    Unary_Kind : Token;
                    Down_Node : Object;
                when Integer_Data =>
                    Integer_Value : Integer;
                when Boolean_Data =>
                    Boolean_Value : Boolean;
                when State_Data =>
                    State_Value : Token;
                when Var_Data =>
                    Var_Name, Var_Extension : Variable_String (32);
                when Instruction =>
                    Instruction_Name : Token;
                    Param1, Param2 : Variable_String (32);
                when Player_Entry =>
                    Nb_Param : Integer;
                    Entry1, Entry2, Entry3 : Variable_String (32);
            end case;
        end record;

    type Object is access Cell;
end Abstract_Tree;
DataMuseum.dk

Rational R1000/400

⟦79a8ddca4⟧ Ada Source

Derivation

E3 Source Code

E3 Meta Data
