⟦a37650118⟧

E3 Source Code



package Debug_Tools is

    procedure Debug_On;
    procedure Debug_Off;

    -- Enable or disable debugging for the calling task's job.  When enabled,
    -- only tasks that are descendents of the caller can be debugged.
    -- When debugging is disabled, the task is released to execute, and all
    -- active debugger "hooks" are deactivated (eg, breakpoints, etc).

    function Debugging return Boolean;

    -- return true if calling task is being debugged.

    procedure Message (Info : String);

    -- Print the message string in the debugger window.  No operation if
    -- the debugger is not activated

    procedure User_Break (Info : String);

    -- "Break" in the debugger.  The calling task stops as though it
    -- encountered a breakpoint.  If the debugger is not active, no action
    -- is performed.  Otherwise, the task remains stopped until the
    -- debugger user explicitly continues its execution.

    procedure Set_Task_Name (Name : String);
    function  Get_Task_Name return String;

    -- Set or retrieve a string "synonym" for the calling task.  This name
    -- is used within the debugger to make identifying task easier.
    -- It is also useful for multiple instances of the same task type
    -- to distinguish themselves in the debugger.
    -- No operation if the debugger is not activate.


    function Ada_Location (Frame_Number  : Natural := 0;
                           Fully_Qualify : Boolean := True;
                           Machine_Info  : Boolean := False) return String;

    -- Return a string name for the Ada location of execution in the
    -- specified stack frame.  Frame_Number = 0 refers to the caller
    -- of Ada_Location.  Frame_Number = 1 refers to its caller, and so
    -- on.  The null string is returned if the frame is nonexistent or
    -- its location cannot be found for some other serious reason.

    -- This procedure works independent of whether there is a active
    -- debugger for the calling tasks, but it may return less information
    -- if there is not.

    function Get_Exception_Name (Fully_Qualify : Boolean := True;
                                 Machine_Info : Boolean := False) return String;

    -- return a string representation of the exception most recently
    -- executed by the calling task.  Get_Exception_Name must be called
    -- either directly or indirectly from an exception handler.  If
    -- no exception is found, the null string is returned.


    function Get_Raise_Location (Fully_Qualify : Boolean := True;
                                 Machine_Info : Boolean := False) return String;

    -- return a string representation of the location of the exception
    -- most recently executed by the calling task.  Get_Raise_Location
    -- must be called either directly or indirectly from an exception
    -- handler.  If  no exception is found or other problems encountered,
    -- the null string is returned.


    generic
        type T is limited private;
        -- Type that will be displayed using Image procedure as part
        -- of debugger's object display procedure.

        with function Image (Value           : T;
                             Level           : Natural;
                             Prefix          : String;
                             Expand_Pointers : Boolean) return String;

        -- Given the Value, return its image.  Level specifies the number
        -- of levels to detail to be displayed.  Expand_Pointers indicates
        -- that internal pointers should be expanded in the image.
        -- Level = 0 => entire object should be elided.

        -- If any ASCII.LF's are emitted, the following line should
        -- start with Prefix as an "indent" value.

    procedure Register;
    -- Make this special display procedure known to the debugger
    -- of the session making the call.


    generic
        type T is limited private;
    procedure Un_Register;
    -- Remove the display procedure from the calling session's
    -- database of special types for the type T given.

    pragma Subsystem (Native_Debugger);
    pragma Module_Name (4, 3802);

end Debug_Tools;
DataMuseum.dk

Rational R1000/400

⟦a37650118⟧ Ada Source

Derivation

E3 Source Code

E3 Meta Data
