⟦a68ad08b8⟧

E3 Source Code



package Activity is

    pragma Subsystem (Commands);
    pragma Module_Name (4, 3940);

    subtype Activity_Name is String;

    -- An Activity is a managed object that maintains a map between
    -- subsystems and pairs of views. The pair consists of a spec view and
    -- a load (non-spec) view of the subsystem. An activity name is a
    -- string name for the managed object. The view pair can be specified
    -- indirectly by associating a subsystem in one activity with another
    -- activity, which then maps the subsystem to a pair of views.

    -- In these Activity commands, the default Activity is the object
    -- selected in the accompanying window, the object associated with the
    -- accompanying window, or, as a last resort, The_Current_Activity.


    type Creation_Mode is (Differential, Exact_Copy, Value_Copy);

    -- When a subsystem is copied from one Activity to another, the entry
    -- in the destination activity can be created in three ways:

    -- Differential : In the destination activity, the subsystem is mapped
    --                to the source Activity.

    --  Exact_Copy   : In the destination activity, the subsystem is mapped
    --                 to the same object it mapped to in the source
    --                 activity;  this may be either a view or an activity.

    --  Value_Copy   : In the destination activity, the subsystem is mapped
    --                 to the view currently associated with the subsystem
    --                 in the source activity.


    subtype Subsystem_Name is String;
    -- String name of a World directory.

    subtype View_Simple_Name is String;
    subtype View_Name        is String;
    -- View_Name = Subsystem_Name & '.' & View_Simple_Name

    -- A View is a world whose enclosing world is a Subsystem world.
    -- Any number of directories may come between a view and its subsystem.
    -- Hence, the view's subsystem is implicit in the full name of the
    -- view. The simple name of the view is used where the name of the
    -- subsystem is easily derived from other parameters.

    subtype View_Or_Activity_Name is String;
    -- An activity can be used to indirectly specify a view.

    subtype Unit_Name is String;
    -- The string name for an Ada library unit nested within a view of a
    -- subsystem.


    function Nil return Activity_Name;

    -- The name of the canonical activity with no subsystems;
    -- the empty activity.


    procedure Current (Response : String := "<PROFILE>");

    -- Prints the name of the activity currently associated with the
    -- running job; if no Activity has been associated with the job, it
    -- then returns the Activity currently associated with the running
    -- sesssion.


    function The_Current_Activity return Activity_Name;

    -- returns the name of the current activity; as defined above.


    procedure Set (The_Activity : Activity_Name := "<ACTIVITY>";
                   Response     : String        := "<PROFILE>");

    -- Makes The_Activity the current activity for the running job only.


    procedure Set_Default (The_Activity : Activity_Name := "<ACTIVITY>";
                           Response     : String        := "<PROFILE>");

    -- Makes Activity the current activity for the session.  If the job's
    -- activity is nil, set that as well.


    procedure Enclosing_View (Unit     : Unit_Name := "<IMAGE>";
                              Response : String    := "<PROFILE>");

    -- Prints the name of the enclosing view (either a load or spec view);

    function The_Enclosing_View
                (Unit : Unit_Name := "<IMAGE>") return View_Name;

    -- The name of the enclosing view (either a load or spec view);


    procedure Enclosing_Subsystem (View     : View_Name := "<IMAGE>";
                                   Response : String    := "<PROFILE>");

    -- Prints the name of the subsystem that encloses the View, which may
    -- be either a Spec or Load view.

    function The_Enclosing_Subsystem
                (View : View_Name := "<IMAGE>") return Subsystem_Name;

    -- The name of the subsystem that encloses the View, which may
    -- be either a Spec or Load view.


    procedure Create (The_Activity : Activity_Name := ">>ACTIVITY NAME<<";
                      Source       : Activity_Name := Activity.Nil;
                      Mode         : Creation_Mode := Activity.Exact_Copy;
                      Response     : String        := "<PROFILE>");

    -- Create a new Activity object.  If the Source activity is not Nil,
    -- its contents are copied to the new activity according to the
    -- specified Mode.


    procedure Add (Subsystem    : Subsystem_Name        := "<CURSOR>";
                   Load_Value   : View_Or_Activity_Name := Activity.Nil;
                   Spec_Value   : View_Or_Activity_Name := Activity.Nil;
                   The_Activity : Activity_Name         :=
                      Activity.The_Current_Activity;
                   Mode         : Creation_Mode         := Activity.Exact_Copy;
                   Response     : String                := "<PROFILE>");

    -- Add a subsystem to an existing Activity. If the load or spec values
    -- are activities, the mapping is created according to the specified
    -- mode.  The Load_Value and Spec_Value names are resolved in the
    -- context of the given Subsystem, so that View_Simple_Names may be
    -- used.


    procedure Remove (Subsystem    : Subsystem_Name := "<SELECTION>";
                      The_Activity : Activity_Name  :=
                         Activity.The_Current_Activity;
                      Response     : String         := "<PROFILE>");

    -- Remove a subsystem from an Activity.


    procedure Set_Spec_View (Spec_View : View_Or_Activity_Name := "<CURSOR>";                            Subsystem : Subsystem_Name := "";
                             Mode : Creation_Mode := Activity.Differential;
                             The_Activity : Activity_Name :=
                                Activity.The_Current_Activity;
                             Response : String := "<PROFILE>");

    -- If Spec_View designates a view, associates the given view as the spec
    -- view for the subsystem that contains the view.

    -- If Spec_View designates an activity, associates the spec view defined
    -- in the given source activity as the new spec view of the given
    -- subsytem in the destination Activity. The mapping is created
    -- according the given Mode.

    -- The Spec_View parameter is resolved in the context established by the
    -- Subsystem parameter.  The subsystem is derived from the Spec_View
    -- parameter if it denotes a view, otherwise the Subsystem parameter
    -- must be given.

    procedure Set_Load_View (Load_View : View_Or_Activity_Name := "<CURSOR>";
                             Subsystem : Subsystem_Name := "";
                             Mode : Creation_Mode := Activity.Differential;
                             The_Activity : Activity_Name :=
                                Activity.The_Current_Activity;
                             Response : String := "<PROFILE>");

    -- If Load_View designates an activity, associates the given View as the
    -- load view for the subsystem that contains the view.

    -- If Load_View designates an activity, associates the load view defined
    -- in the given Source activity as the new load view of the given
    -- subsystem in the named Activity. The mapping is created according the
    -- given Mode.

    -- The Load_View parameter is resolved in the context established by the
    -- Subsystem parameter.  The subsystem is derived from the Load_View
    -- parameter if it denotes a view, otherwise the Subsystem parameter
    -- must be given.

    procedure Display (Subsystem    : Subsystem_Name := "?";
                       Spec_View    : View_Name      := "?";
                       Load_View    : View_Name      := "?";
                       Mode         : Creation_Mode  := Activity.Value_Copy;
                       The_Activity : Activity_Name  :=
                          Activity.The_Current_Activity;
                       Response     : String         := "<PROFILE>");

    -- Display the mappings between subsystems and views defined by the
    -- given activity.  Only the mappings that match the patterns given in
    -- the Subsystem, Spec_View, and Load_View parameters are listed. (The
    -- default is to list all mappings in the activity.)  In the Value_Copy
    -- mode, all indirect references are resolved and only the resolution
    -- is displayed.  In the Exact_Copy mode, Indirect mappings are not
    -- resolved and the name of the source activity is displayed. In the
    -- Differential mode, the indirect mappings are resolved and both the
    -- resolution and the original indirect activity are displayed.


    procedure Edit (The_Activity : Activity_Name := "<ACTIVITY>");

    -- Invoke the Activity object editor on the given Activity.

    procedure Insert (Subsystem : Subsystem_Name        := ">>SUBSYSTEM NAME<<";
                      Spec_View : View_Or_Activity_Name := "";
                      Load_View : View_Or_Activity_Name := "");

    -- Inserts the specified subsystem mapping into the activity associated
    -- with the command window. (The current activity is brought up in an
    -- Activity window and modified if the command is not associated with
    -- an Activity window). The given names may specify a view or another
    -- activity. If the subsystem name is omitted, it is inferred from the
    -- view names.

    procedure Change (Spec_View : View_Or_Activity_Name := "";
                      Load_View : View_Or_Activity_Name := "");

    -- The selected subsystem mapping is changed to the new values given in
    -- the Views specification.  Valid only in an Activity window.

    procedure Write (File : Activity_Name := ">>ACTIVITY NAME<<");

    -- Copies the current content of the Activity window to the designated
    -- File. Valid only in an Activity window.

    procedure Visit (The_Activity : Activity_Name := "<ACTIVITY>");

    -- Same as Edit, except that if the command is given on an activity
    -- window, the new activity is displayed in that window rather than in
    -- a new one.


    procedure Merge (Source    : Activity_Name  := ">>ACTIVITY NAME<<";
                     Subsystem : Subsystem_Name := "?";
                     Spec_View : View_Name      := "?";
                     Load_View : View_Name      := "?";
                     Mode      : Creation_Mode  := Activity.Exact_Copy;
                     Target    : Activity_Name  := "<ACTIVITY>";
                     Response  : String         := "<PROFILE>");

    -- The subsystem mappings defined in the Source Activity that match the
    -- given subsystem and view patterns are copied to the Target activity
    -- according to the specified Creation mode. New subsystems are added
    -- to the Target activity if necessary; Existing subsystem mappings are
    -- replaced. The default Target activity is the current selection/image.

end Activity;
DataMuseum.dk

Rational R1000/400

⟦a68ad08b8⟧ Ada Source

Derivation

E3 Source Code

E3 Meta Data
