DataMuseum.dk

top - metrics - download

    Length: 18795 (0x496b)
    Types: TextFile
    Notes: R1k Text-file segment

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─⟦cfc2e13cd⟧ »Space Info Vol 2« 
        └─⟦aa937f0f9⟧ 
            └─⟦this⟧ 

TextFile

JEU Bart_s_quest

ACTION

    Aller
    Ouvrir
    Prendre
    Donner
    Regarder
    Utiliser
    Parler
    Inventaire

DEFINITION

    STRUCTURE       PJ  (CHAINE Description, ENTIER Pt_Vie)
    STRUCTURE       PnJ (CHAINE Description)

    STRUCTURE       Divers (CHAINE Description)
    STRUCTURE       Piece (CHAINE Description)

PRESENTATION

    Bart                OBJET PJ AVEC ("Hi Man !!",10)

    Homere              OBJET PnJ AVEC ("C'est mon papa... (j'ai surement du etre adopte).")
    Marge               OBJET PnJ AVEC ("C'est ma maman... (elle a vraiment une coupe de cheveux bizarre).")
    Chien               OBJET PnJ AVEC ("C'est notre chien... (c'est drole, il me fait penser a Milouse).")
     Lisa                OBJET PnJ AVEC ("C'est  Lisa...")   

    Tele                OBJET Divers AVEC ("L'objet le plus precieux de la maison!")
    Biere               OBJET Divers AVEC ("Une bonne Budweiser.")
    Cle       OBJET Divers AVEC ("C'est la CLE_DU_GARAGE.")
    Savon               OBJET Divers AVEC ("Un savon qui sent le Donuts, c'est Homere qui l'a trouve.")
    WC                  OBJET Divers AVEC ("T'as jamais utilise des WC chez toi ?")
    Voiture             OBJET Divers AVEC ("C'est la Hommer mobile (meme pas une Clio ... peuh...).")
    Lavabo              OBJET Divers AVEC ("Tres utile lorsque l'on a les mains ou les dents a se laver.")
    Chaise_de_Maggie    OBJET Divers AVEC ("La chaise de ma petite soeur Maggie.")
    Bouillie_de_Maggie  OBJET Divers AVEC ("L'appetissante bouillie de ma soeur. ")
    Frigo               OBJET Divers AVEC ("La caverne aux mille et une boites de BIERE.")
    Porte_du_Garage     OBJET Divers AVEC ("Solide et imposante, sauf quand MARGE fait des manoeuvres.")
    Commode             OBJET Divers AVEC ("Une grosse commode Normande")
    Revues              OBJET   Divers AVEC ("Toute la collection de revues masculines de mon pere")
    Livre               OBJET Divers  AVEC ("Le grand livre du parfait programmeur en ADA.")
    Batte               OBJET Divers AVEC ("Ma batte de Base Ball ( elle n'a jamais touche une balle )")
    Placard             OBJET Divers AVEC ("Un vieux placard envahie par les mittes")
    Lit                 OBJET Divers AVEC ("Mon lit, un vrai champ de bataille")

    Garage              OBJET Piece AVEC ("Le garage. Un cafarnaum monstre, la VOITURE est la. Ouest : Salon")
    Salon               OBJET Piece AVEC ("Le salon.HOMERE et MARGE regardent la TELE.Nord:Salle de bain.Sud:Escalier")
    Cuisine             OBJET Piece AVEC ("La cuisine : une table, un FRIGO, des placards et la CHAISE_DE_MAGGIE.")
    Salle_de_Bain       OBJET Piece AVEC ("La salle de bain : un LAVABO, un R1000 (bizarre...). Ouest : Cuisine")
    Escalier            OBJET Piece AVEC ("C'est l'unique acces au premier etage. Attention il est casse gueule!!!")
    Couloir             OBJET Piece AVEC ("Le couloir.Nord:CHAMBRE_DES_PARENTS.Sud:CHAMBRE_LISA.Ouest:CHAMBRE_BART")
    Chambre_des_Parents OBJET Piece AVEC ("C'est la chambre de mes parents. A part le PLACARD, rien d'interessant")
    Chambre_Lisa        OBJET Piece AVEC ("Ma soeur Lisa est dans sa chambre")
    Chambre_Bart        OBJET Piece AVEC ("Quel fouilli dans ma chambre, le LIT n'est pas fait, la COMMODE va exploser.")
    Cabanne             OBJET Piece AVEC ("Ma tanniere")

    Position_Bart       OBJET Piece INIT Garage

    Position_Chien      OBJET   PnJ INIT Cuisine

LIAISON

    CONNEXION ( Nord, Sud, Est, Ouest )


    CREER_CONNEXION ( Garage, Salon, Ouest, DELIE )

    CREER_CONNEXION ( Salon, Garage, Est, LIE )

    CREER_CONNEXION ( Salon, Salle_de_Bain, Nord, LIE )

    CREER_CONNEXION ( Salle_de_Bain, Salon, Sud, LIE )

    CREER_CONNEXION ( Cuisine, Salle_de_Bain, Est, LIE )

    CREER_CONNEXION ( Salle_de_Bain, Cuisine, Ouest, DELIE )

    CREER_CONNEXION ( Couloir, Chambre_des_Parents, Nord, DELIE )

    CREER_CONNEXION ( Chambre_des_Parents, Couloir, Sud, LIE )
    
    CREER_CONNEXION ( Couloir, Chambre_Lisa, Sud, LIE )
    
    CREER_CONNEXION ( Chambre_Lisa, Couloir, Nord, LIE )

    CREER_CONNEXION ( Couloir, Chambre_Bart, Ouest, LIE )

    CREER_CONNEXION ( Chambre_Bart, Couloir, Est, LIE )
    
    CREER_CONNEXION ( Salon, Couloir, Sud, DELIE )

    CREER_CONNEXION ( Chambre_Bart, Cabanne, Ouest, DELIE )


    CREER_LIEN ( Cuisine, Bouillie_de_Maggie, DELIE )

    CREER_LIEN ( Cuisine, Biere, DELIE )

    CREER_LIEN ( Garage, Cle, DELIE )

    CREER_LIEN ( Salle_de_Bain, Savon, LIE )

    CREER_LIEN ( Homere, Biere, DELIE )

    CREER_LIEN ( Chien, Bouillie_de_Maggie, DELIE )

    CREER_LIEN ( Bart, Biere, DELIE )

    CREER_LIEN ( Bart, Savon, DELIE )

    CREER_LIEN ( Bart, Cle, DELIE )

    CREER_LIEN ( Bart, Bouillie_de_Maggie, DELIE )

    CREER_LIEN ( Lisa, Livre, DELIE )

    CREER_LIEN ( Bart, Livre, DELIE )

    CREER_LIEN ( Bart, Revues, DELIE )

    CREER_LIEN ( Chambre_Bart, Batte, DELIE )

    CREER_LIEN ( Bart, Batte, DELIE )

    CREER_LIEN ( Chambre_des_Parents, Revues, DELIE )


INTRODUCTION

    AFFICHER ( "Springfield, an de grace 1995." )

    AFFICHER ( "" )
    
    AFFICHER ( "Apres avoir fini d'ecrire votre punition : " )

    AFFICHER ( "   je ne dois pas voler des barettes de RAM a mon ecole" )

    AFFICHER ( "vous arrivez chez vous ( grace a votre skate board de combat ). " )

    AFFICHER ( "" )
    
    AFFICHER ( "Votre mission, si vous l'accepter ( en fait vous avez pas le choix ) " )

    AFFICHER ( "est de voler les revues de votre pere et de rejoindre vos amis dans la cabanne." )

    AFFICHER ( "" )
    
    AFFICHER ( "Bien sur, si vous ou un membre de votre equipe ( donc vous ) est capture" )

    AFFICHER ( "ou tue ( ou requisitionne pour couler du beton ), le directeur des etudes niera" )

    AFFICHER ( "toutes  responsabilites ( vous n'aviez qu'a faire LSI en troisieme annee ). " )

    AFFICHER ( "" )
    
    AFFICHER ( "Bonne chance Monsieur Simpson. Rational plantera dans 10 secondes ( et" )

    AFFICHER ( "vous savez ce que cela veut dire en temps de rebootage ) . " )

    AFFICHER ( "" )
    
    AFFICHER ( "Ordres : Aller, Parler, Ouvrir, Prendre, Utiliser, Inventaire, Donner, Regarder" )
    
    AFFICHER ( "" )
    
    AFFICHER ( Garage.Description )
    
    AFFICHER ( "" )

ANIMATION_GENERALE

    POUR 20 ENTREE FAIRE
        
        Bart.Pt_Vie := Bart.Pt_Vie - 1

    FINPOUR
    
    
    
    SI Bart.Pt_Vie = 3 ALORS

        AFFICHER ( "Fini le tourisme, il faut que je me depeche" )

    FINSI

    
    
    SI Bart.Pt_Vie = 2 ALORS

        AFFICHER ( "Bon, c'est decide, je vais faire quelque chose de constructif" )

    FINSI

    
    
    SI Bart.Pt_Vie = 1 ALORS

        AFFICHER ( "Ok, Ok. Je me met au travail" )

    FINSI

    
    
    SI Bart.Pt_Vie = 0 ALORS

        AFFICHER ( "Bon je vais aller me coucher. Je reprendrai ma quete une autre fois" )

        AFFICHER ( "FIN DU JEU" )

        FIN

    FINSI

ANIMATION_GLOBALE

    SI [ Aller COMP ] OU [ COMP ] ALORS

        SI EXISTE_CONNEXION ( Position_Bart, COMP ) = VRAI ALORS

            SI ETAT_CONNEXION ( Position_Bart, COMP ) = LIE ALORS

                Position_Bart := DESTINATION_CONNEXION ( Position_Bart, COMP )
                
                AFFICHER ( Position_Bart.Description )
                
                AFFICHER ( "Je vois aussi :" )
                
                LISTE_LIEN ( Position_Bart, LIE )

            SINON

                AFFICHER ( "Le passage est bloque" )

            FINSI

        SINON

            AFFICHER ( "Il n'y a pas d'issue par la" )

        FINSI

    FINSI


    
    
    SI [ Regarder ] ALORS

        AFFICHER ( Position_Bart.Description )
        
        AFFICHER ( "Je vois aussi :" )
        
        LISTE_LIEN ( Position_Bart, LIE )       

    FINSI


    
    
    SI [ Regarder COMP ] ALORS

        SI ETAT_LIEN ( COMP, Position_Bart ) = LIE OU ETAT_LIEN ( COMP, Bart ) = LIE ALORS

            AFFICHER ( COMP.Description )   

        SINON

            AFFICHER ( "?????" )
        FINSI
    FINSI


    
    
    SI [ Inventaire ] ALORS

        AFFICHER ( "Je me ballade avec :" )

        LISTE_LIEN ( Bart, LIE )

    FINSI

    
    
    SI [ Prendre COMP ] ALORS

        SI ETAT_LIEN ( Position_Bart, COMP ) = LIE ALORS

            ECHANGER_LIEN (COMP, Position_Bart, Bart )

        SINON

            AFFICHER ( "Impossible" )

        FINSI

    FINSI


ANIMATION_LOCALE

    
    SI [ Parler Homere ] ALORS

        SI Position_Bart = Salon ALORS

            SI ETAT_LIEN ( Homere, Biere ) = DELIE ALORS

                AFFICHER ( "Va me chercher une biere Bart, et plus vite que ca" )

            SINON

                AFFICHER ( "Tais toi Bart, Je regarde la tele" )

            FINSI

        SINON

            AFFICHER( "Mais Homere n'est pas dans la piece. Je commence a etre dingo moi" )

        FINSI

    FINSI



    SI [ Parler Marge ] ALORS
    
        SI Position_Bart = Salon ALORS

            SI ETAT_CONNEXION ( Salle_de_Bain, Ouest ) = DELIE ALORS
        
                AFFICHER ( "Va te laver les mains Bart" )

            SINON

                AFFICHER ( "Ne me derange pas quand je regarde la tele avec ton pere" )

            FINSI

        SINON

            AFFICHER( "Mais Marge n'est pas dans la piece. Je commence a etre dingo moi" )

        FINSI

    FINSI


    
    SI [ Regarder Voiture ] ALORS

        SI ETAT_LIEN ( Garage, Cle ) = DELIE ALORS

            AFFICHER ( "Tiens, il y a une cle qui traine sur le siege" )

            LIE_LIEN ( Garage, Cle )

        SINON

            AFFICHER ( "Cette voiture est tellement defoncee qu'Homer doit surement ")

                      AFFICHER ( "participer au championnat de stock-car avec" )


        FINSI

    FINSI


    
    SI [ Utiliser Cle ] ALORS

        SI Position_Bart = Garage ALORS

            AFFICHER ( "C'est magique, c'est la bonne cle" )

            LIE_CONNEXION ( Garage, Ouest )

        SINON

            AFFICHER ( "C'est la cle du garage, je voie pas ce que j'en ferait ici" )

        FINSI

    FINSI


    
    SI [ Utiliser Lavabo ] ALORS

        SI Position_Bart = Salle_de_Bain ALORS

            SI ETAT_LIEN ( Savon, Bart ) = LIE ALORS

                AFFICHER ( "C'est maman qui va etre contente, j'ai les mains propres" )

                LIE_CONNEXION ( Salle_de_Bain, Ouest )

            SINON

                AFFICHER ( "Il me faudrait du savon" )

            FINSI

        SINON

            AFFICHER ( "Ou c'est qu'il y a un lavabo" )

        FINSI

    FINSI


    
    SI [ Ouvrir Frigo ] ALORS

        SI Position_Chien = Cuisine ALORS

            AFFICHER ( "Impossible, cet idiot de chien ne veut pas se pousser" )

        SINON

            SI ETAT_LIEN ( Bart, Biere ) = LIE OU ETAT_LIEN ( Homere, Biere ) = LIE ALORS

                AFFICHER ( "Il n'y a rien d'interessant dans le frigo" )

            SINON

                AFFICHER ( "Oh la belle BIERE dans le FRIGO" )

                LIE_LIEN ( Cuisine, Biere )

            FINSI

        FINSI

    FINSI



    
    SI [ Donner Biere Homere ] ALORS

        SI ETAT_LIEN ( Bart, Biere ) = LIE ALORS

            AFFICHER ( "C'est pas trop tot Bart. Va te coucher maintenant" )

            LIE_CONNEXION ( Salon, Sud )
            
            ECHANGER_LIEN ( Biere, Bart, Homere )

            AFFICHER ( "Et voila comme je suis recompense. Je n'ai plus qu'a prendre ")
            AFFICHER ( "l'esclalier au sud pour monter au premier ( c'est assez clair, non ? )" )
            
        SINON

            AFFICHER ( "Il faudrait peut etre avoir une biere" )

        FINSI

    FINSI


    
    SI [ Regarder Chaise_de_Maggie ] ALORS

        SI Position_Bart = Cuisine ALORS

            SI ETAT_LIEN ( Bart, Bouillie_de_Maggie ) = DELIE ET ETAT_LIEN ( Chien, Bouillie_de_Maggie ) = DELIE ALORS
            
                AFFICHER ( Chaise_de_Maggie.Description )

                AFFICHER ( Bouillie_de_Maggie.Description )

                LIE_LIEN ( Cuisine, Bouillie_de_Maggie )
                
            SINON
            
                AFFICHER ( Chaise_de_Maggie.Description )
                
            FINSI

        SINON

            AFFICHER ( "Il n'y a pas la chaise de ma soeur ici" )

        FINSI

    FINSI


    
    SI [ Donner Bouillie_de_Maggie Chien ] ALORS

        SI ETAT_LIEN ( Bart, Bouillie_de_Maggie ) = LIE ALORS

            SI Position_Bart = Cuisine ALORS

                SI Position_Chien = Cuisine ALORS

                    AFFICHER ( "Le radin, il est alle manger la bouillie ailleurs" )

                    ECHANGER_LIEN ( Bouillie_de_Maggie, Bart, Chien )

                    Position_Chien := Garage

                SINON

                    AFFICHER ( "Le chien n'est pas ici" )

                FINSI

            SINON

                AFFICHER ( "Le chien n'est pas ici" )   

            FINSI

        SINON

            AFFICHER ( "Je n'ai pas la bouillie de Maggie " )

        FINSI

    FINSI


    
    SI [ Parler Lisa ] ALORS

        SI Position_Bart = Chambre_Lisa ALORS

            SI ETAT_LIEN ( Lisa, Livre ) = DELIE ALORS

                AFFICHER ( "Je ne te parlerai que si tu me rend mon livre" )

            SINON

                AFFICHER ( "Je ne vais pas la deranger pendant qu'elle joue du saxo" )

            FINSI

        SINON

            AFFICHER( "Mais Lisa n'est pas dans la piece. Si je commence a parler aux")
            AFFICHER( "murs ca ne va plus aller" )

        FINSI

    FINSI


    
    SI [ Aller Nord ] OU [ Nord ] ALORS

        SI Position_Bart = Couloir ALORS

            SI Etat_Lien ( Lisa, Livre ) = DELIE ALORS

                AFFICHER ( "La porte de la chambre de mes parents grince de trop. Si")
                AFFICHER ( "j'essaie de rentrer ils vont m'entendre" )

            SINON

                Position_Bart := Chambre_des_Parents

                AFFICHER ( Chambre_des_Parents.Description )

            FINSI

        FINSI

    FINSI


    
    SI [ Donner Livre Lisa ] ALORS

        SI ETAT_LIEN ( Bart, Livre ) = LIE ALORS

            SI Position_Bart = Chambre_Lisa ALORS

                ECHANGER_LIEN ( Livre, Bart, Lisa )

                AFFICHER ( "Merci Bart. Mon livre de chevet. Pour te recompenser ")
                AFFICHER ( "je vais te jouer quelque chose avec mon saxo" )

            SINON

                AFFICHER ( "Lisa n'est pas ici" )

            FINSI

        SINON

            AFFICHER ( "Je n'ai pas de livre" )

        FINSI

    FINSI


    
    SI [ Regarder Lit ] ALORS

        SI Position_Bart = Chambre_Bart ALORS

            SI ETAT_LIEN ( Bart, Batte ) = DELIE ALORS

                AFFICHER ( Lit.Description )

                AFFICHER ( "Tiens, je vois ma BATTE de Base Ball sous le lit" )

                LIE_LIEN ( Chambre_Bart, Batte )

            SINON
                
                AFFICHER ( Lit.Description )

            FINSI

        SINON

            AFFICHER ( "Ou est ce qu'il y a un lit ici ?" )

        FINSI

    FINSI


    
    
    SI [ Regarder Commode ] ALORS

        SI Position_Bart = Chambre_Bart ALORS

            SI ETAT_LIEN ( Bart, Livre ) = DELIE ET ETAT_LIEN ( Lisa, Livre ) = DELIE ALORS

                AFFICHER ( Commode.Description )

                AFFICHER ( "Il y a un LIVRE qui depasse du dessus de la COMMODE" )

            SINON

                AFFICHER ( Commode.Description )

            FINSI

        SINON

            AFFICHER ( "Qu'elle commode ?" )

        FINSI

    FINSI


    
    
    SI [ Utiliser Batte Commode ] ALORS

        SI Position_Bart = Chambre_Bart ALORS

            SI ETAT_LIEN ( Bart, Livre ) = DELIE ET ETAT_LIEN ( Lisa, Livre ) = DELIE ALORS 

                SI ETAT_LIEN ( Bart, Batte ) = LIE ALORS

                    AFFICHER ( "Aie. Un livre vient de me tomber sur la tete. Mais c'est le livre de Lisa" )

                    LIE_LIEN ( Bart, Livre )

                SINON

                    AFFICHER ( "Je n'ai pas de batte" )

                FINSI

            SINON

                AFFICHER ( "Ah, ca defoule" )

            FINSI

        SINON
            
            AFFICHER ( "??? !!! " )

        FINSI

    FINSI


    
    
    SI [ Ouvrir Placard ] ALORS

        SI Position_Bart = Chambre_des_Parents ALORS

            SI ETAT_LIEN ( Bart, Revues ) = DELIE ALORS

                AFFICHER ( "Chouette, les REVUES de mon pere, c'est mes potes qui vont etre contents" )

                LIE_LIEN ( Chambre_des_Parents, Revues )

            SINON

                AFFICHER ( "Rien d'interessant" )

            FINSI

        SINON

            AFFICHER ( "Pas de placard ici" )

        FINSI

    FINSI


    
    
    SI [ Prendre Revues ] ALORS

        SI Position_Bart = Chambre_des_Parents ALORS

            SI ETAT_LIEN ( Chambre_des_Parents, Revues ) = LIE ALORS

                ECHANGER_LIEN ( Revues,Chambre_des_Parents, Bart )

                AFFICHER ( "Et voila, je vais maintenant vite rejoindre mes copains dans la cabanne" )

                AFFICHER ( " ( je n'ai plus qu'a sortir par la fenetre de ma chambre ( Ouest )" )
                
                LIE_CONNEXION ( Chambre_Bart, Ouest )

            SINON

                AFFICHER ( "Impossible" )

            FINSI

        SINON

            AFFICHER ( "Les revues ne sont pas ici" )

        FINSI

    FINSI

            
    
    
    SI [ Aller Ouest ] OU [ Ouest ] ALORS

        SI Position_Bart = Chambre_Bart ALORS

            SI ETAT_LIEN ( Bart, Revues ) = LIE ALORS

                AFFICHER ( "Ah, c'etait dur mais Bart a une nouvelle fois vaincu les ")
                AFFICHER ( "elements qui se dechainaient contre lui" )

                AFFICHER ( "Score : ", Bart.Pt_Vie, " / 10" )

                FIN

            SINON

                AFFICHER ( "Pas sans les revues sinon je vais passer pour un incapable" )

            FINSI

        FINSI

    FINSI
            
    SI [ Regarder Homere ] ALORS
    
        SI Position_Bart = Salon ALORS
        
            AFFICHER ( Homere.Description )
            
        SINON
            
            AFFICHER ( "Homere n'est pas ici" )
            
        FINSI
        
    FINSI
    
    SI [ Regarder Marge ] ALORS

        SI Position_Bart = Salon ALORS

            AFFICHER ( Marge.Description )

        SINON

            AFFICHER ( "Marge n'est pas ici" )

        FINSI

    FINSI
                            
    SI [ Regarder Lisa ] ALORS

        SI Position_Bart = Chambre_lisa ALORS

            AFFICHER ( Lisa.Description )

        SINON

            AFFICHER ( "Lisa n'est pas ici" )

        FINSI

    FINSI
FI