DataMuseum.dk

top - download

    Length: 3968 (0xf80)
    Notes: Mikados TextFile, Mikados_K
    Names: »INITLIZE«

└─⟦57a827f90⟧ Bits:30005247 COMAL A verson 2.24 (MIKADOS)
    └─ ⟦this⟧ »INITLIZE« 
└─⟦85259e8f7⟧ Bits:30005248 COMAL B verson 1.19 (MIKADOS)
    └─ ⟦this⟧ »INITLIZE« 

Text

0100 REM INITLIZE -    EGS 791106, PNM 050980, DI 050182, DI 210182
0110 DIM SVAR$(4),SVARK$(4),ETIKETTE$(9),DREVN$(2),NAVN$(18),SIDSTECHAR$(1)
0120 PRINT 
0130 PRINT "INITLIZE - Initialisering af disketter"
0140 PRINT "         - og indsætning af etiketter"
0150 REPEAT 
0160 PRINT 
0170 REPEAT 
0180 ETIKETTE$="";NAVN$="";FOREVER,FLAG=0
0190 INPUT "Indtast etikette: ",NAVN$
0200 EXEC KONVERTOGMOVE(NAVN$,1,ETIKETTE$,SIDSTECHAR$,FLAG)
0210 IF LEN(ETIKETTE$)>8 OR LEN(ETIKETTE$)<1 OR LEN(NAVN$)>8 THEN FLAG=1
0220 IF SIDSTECHAR$=":" THEN FLAG=1
0230 UNTIL FLAG=0
0240 REPEAT 
0250 INPUT "Indtast drevbetegnelse (P1, P2, .. ): ",DREVN$
0260 UNTIL DREVN$>"P0" AND DREVN$<="P9"
0270 REPEAT 
0280 PRINT 
0290 PRINT "Indsæt diskette i drev nr. ";DREVN$(2)
0300 PRINT 
0310 PRINT "Tast derefter   I for Initialisering"
0320 PRINT "                E for indsætning af Etikette"
0330 INPUT "              ESC for at stoppe programmet : ",SVAR$
0340 UNTIL SVAR$="E" OR SVAR$="I"
0350 IF SVAR$="I" THEN 
0360 REPEAT 
0370 INPUT "                J for indlæsningskontrol   : ",SVARK$
0380 UNTIL LEN(SVARK$)<2 AND (SVARK$="J" OR SVARK$="N")
0390 ENDIF 
0400 EXEC INIT
0410 UNTIL FOREVER
0420 PROC INIT
0430 IF SVAR$="I" THEN 
0440 PRINT " "
0450 PRINT "Aktuelt spor                   Sidste spor"
0460 PRINT " "
0470 ENDIF 
0480 CALL "SYSPROG:PLINC"
0490 PRINT " "
0500 IF FLAG=250 THEN 
0510 PRINT "Etiketten ";ETIKETTE$;" er nu indsat."
0520 ELSE 
0530 IF FLAG THEN 
0540 PRINT "Initlize mislykkedes. Fejlkode";FLAG
0550 ELSE 
0560 PRINT "Diskette ";ETIKETTE$;" er nu initialiseret."
0570 ENDIF 
0580 ENDIF 
0590 ENDPROC 
0600 PROC KONVERTOGMOVE(NFRA,I,NTIL,CH,F)
0610 Y=1
0620 REPEAT 
0630 CH$=NFRA$(I)
0640 IF CH$=>"a" AND CH$<="å" THEN CH$=CHR(ORD(CH$)-32)
0650 IF CH$<>":" THEN 
0660 IF (CH$=>"0" AND CH$<="9") OR (CH$=>"A" AND CH$<="Å") OR CH$="_" THEN 
0670 NTIL$(Y)=CH$;Y=Y+1;I=I+1
0680 ELSE 
0690 IF CH$<>"" THEN 
0700 F=1
0710 EXIT ;ULOVLIGT TEGN
0720 ENDIF 
0730 ENDIF 
0740 ENDIF 
0750 UNTIL Y=LEN(NFRA$)+1 OR CH$=":" OR CH$="" OR LEN(NTIL$)=>9 OR I=>18
0760 ENDPROC