DataMuseum.dk

top - download

    Length: 3968 (0xf80)
    Notes: Mikados TextFile, Mikados_K
    Names: »FCOPY«

└─⟦57a827f90⟧ Bits:30005247 COMAL A verson 2.24 (MIKADOS)
    └─ ⟦this⟧ »FCOPY« 
└─⟦85259e8f7⟧ Bits:30005248 COMAL B verson 1.19 (MIKADOS)
    └─ ⟦this⟧ »FCOPY« 

Text

0100 REM 05.09.1980 PNM
0110 DIM DREVFRA$(2),DREVTIL$(2),TYPE$(1),NAVNFRA$(9),NAVNTIL$(9)
0120 DIM NAVN$(18),SIDSTECHAR$(1)
0130 PRINT "FCOPY - KOPIER FIL."
0140 PRINT 
0150 REPEAT 
0160 INPUT "DREVNR (P1, P2, .. ), DER KOPIERES FRA: ",DREVFRA$
0170 UNTIL DREVFRA$>"P0" AND DREVFRA$<="P9"
0180 PRINT 
0190 REPEAT 
0200 INPUT "DREVNR (P1, P2, .. ), DER KOPIERES TIL: ",DREVTIL$
0210 UNTIL DREVTIL$>"P0" AND DREVTIL$<="P9"
0220 REPEAT 
0230 PRINT 
0240 REPEAT 
0250 NAVNFRA$="";NAVN$="";FLAG,FOREVER=0
0260 INPUT "INDTAST FILNAVN: ",NAVN$
0270 EXEC KONVERTOGMOVE(NAVN$,1,NAVNFRA$,SIDSTECHAR$,FLAG)
0280 IF LEN(NAVNFRA$)>8 OR LEN(NAVNFRA$)<1 OR NAVN$(9)<>"" THEN FLAG=1
0290 IF SIDSTECHAR$=":" THEN FLAG=1
0300 UNTIL FLAG=0
0310 LET TYPE$="K"
0320 EDIT "B FOR BINÆR FIL: ",TYPE$
0330 REPEAT 
0340 NAVN$="";NAVNTIL$="";FLAG=0
0350 INPUT "EVT NYT FILNAVN: ",NAVN$
0360 IF LEN(NAVN$)=0 THEN 
0370 NAVNTIL$=NAVNFRA$
0380 ELSE 
0390 EXEC KONVERTOGMOVE(NAVN$,1,NAVNTIL$,SIDSTECHAR$,FLAG)
0400 IF LEN(NAVNTIL$)>8 OR LEN(NAVNTIL$)<1 OR NAVN$(9)<>"" THEN FLAG=1
0410 ENDIF 
0420 UNTIL FLAG=0
0430 EXEC COPY
0440 UNTIL FOREVER
0450 PROC COPY
0460 CALL "SYSPROG:CFCOPY"
0470 IF FLAG THEN 
0480 PRINT "FCOPY MISLYKKEDES. FEJLKODE";FLAG
0490 STOP 
0500 ELSE 
0510 PRINT NAVNFRA$;" ER KOPIERET FRA ";DREVFRA$;" TIL ";DREVTIL$;
0520 PRINT " UNDER NAVNET ";NAVNTIL$
0530 ENDIF 
0540 ENDPROC 
0550 PROC KONVERTOGMOVE(NFRA,I,NTIL,CH,F)
0560 Y=1
0570 REPEAT 
0580 CH$=NFRA$(I)
0590 IF CH$=>"a" AND CH$<="å" THEN CH$=CHR(ORD(CH$)-32)
0600 IF CH$<>":" THEN 
0610 IF (CH$=>"0" AND CH$<="9") OR (CH$=>"A" AND CH$<="Å") OR CH$="_" THEN 
0620 NTIL$(Y)=CH$;Y=Y+1;I=I+1
0630 ELSE 
0640 IF CH$<>"" THEN 
0650 F=1
0660 EXIT ;ULOVLIGT TEGN
0670 ENDIF 
0680 ENDIF 
0690 ENDIF 
0700 UNTIL Y=LEN(NFRA$)+1 OR CH$=":" OR CH$="" OR LEN(NTIL$)=>9 OR I=>18
0710 ENDPROC