DataMuseum.dk

top - download

    Length: 3968 (0xf80)
    Notes: Mikados TextFile, Mikados_K
    Names: »RENAME«

└─⟦57a827f90⟧ Bits:30005247 COMAL A verson 2.24 (MIKADOS)
    └─ ⟦this⟧ »RENAME« 
└─⟦85259e8f7⟧ Bits:30005248 COMAL B verson 1.19 (MIKADOS)
    └─ ⟦this⟧ »RENAME« 

Text

0100 REM PNM 05.09.1980
0110 DIM NAVN$(18),DREVN$(9),FILNAVN$(9),FILTYPE$(1),FILNA$(9),SIDSTECHAR$(1)
0120 PRINT 
0130 PRINT "RENAME - AENDRING AF FILNAVN"
0140 PRINT "PROGRAMMET STOPPES VED AT TRYKKE PAA ESC"
0150 REPEAT 
0160 PRINT 
0170 REPEAT 
0180 NAVN$="";FILNAVN$="";DREVN$="";FLAG,FOREVER=0;INDEX=1
0190 INPUT "INDTAST DET NUVAERENDE FILNAVN (MED ETIKETTE): ",NAVN$
0200 EXEC KONVERTOGMOVE(NAVN$,INDEX,DREVN$,SIDSTECHAR$,FLAG)
0210 IF SIDSTECHAR$<>":" OR INDEX>9 OR INDEX=1 THEN FLAG=1
0220 EXEC KONVERTOGMOVE(NAVN$,1+INDEX,FILNAVN$,SIDSTECHAR$,FLAG)
0230 IF LEN(FILNAVN$)>8 OR LEN(FILNAVN$)<1 OR NAVN$(18)<>"" THEN FLAG=1
0240 IF SIDSTECHAR$=":" THEN FLAG=1
0250 UNTIL FLAG=0
0260 REPEAT 
0270 PRINT "INDTAST FILTYPE ";
0280 INPUT "(K FOR PROGRAM-/DATAFILER, B FOR BINAERFILER): ",FILTYPE$
0290 UNTIL FILTYPE$="K" OR FILTYPE$="B"
0300 REPEAT 
0310 FLAG=0;NAVN$="";FILNA$=""
0320 INPUT "INDTAST DET NYE FILNAVN (UDEN ETIKETTE): ",NAVN$
0330 EXEC KONVERTOGMOVE(NAVN$,1,FILNA$,SIDSTECHAR$,FLAG)
0340 IF LEN(FILNA$)>8 OR LEN(FILNA$)<1 THEN FLAG=1
0350 UNTIL FLAG=0
0360 EXEC RENAME
0370 UNTIL FOREVER
0380 PROC RENAME
0390 CALL "SYSPROG:OMDØB"
0400 IF FLAG<>0 THEN 
0410 PRINT "RENAME MISLYKKEDES. FEJLKODE:";FLAG
0420 STOP 
0430 ELSE 
0440 PRINT DREVN$;":";FILNAVN$;" ER OMDØBT TIL ";DREVN$;":";FILNA$
0450 ENDIF 
0460 ENDPROC 
0470 PROC KONVERTOGMOVE(NFRA,I,NTIL,CH,F)
0480 Y=1
0490 REPEAT 
0500 CH$=NFRA$(I)
0510 IF CH$=>"a" AND CH$<="å" THEN CH$=CHR(ORD(CH$)-32)
0520 IF CH$<>":" THEN 
0530 IF (CH$=>"0" AND CH$<="9") OR (CH$=>"A" AND CH$<="Å") OR CH$="_" THEN 
0540 NTIL$(Y)=CH$;Y=Y+1;I=I+1
0550 ELSE 
0560 IF CH$<>"" THEN 
0570 F=1
0580 EXIT ;ULOVLIGT TEGN
0590 ENDIF 
0600 ENDIF 
0610 ENDIF 
0620 UNTIL Y=LEN(NFRA$)+1 OR CH$=":" OR CH$="" OR LEN(NTIL$)=>9 OR I=>18
0630 ENDPROC