DataMuseum.dk Presents historical artifacts from the history of: Rational R1000/400

This is an automatic "excavation" of a thematic subset of artifacts from Datamuseum.dk's BitArchive. See our Wiki for more about Rational R1000/400 Excavated with: AutoArchaeologist - Free & Open Source Software.

top - download

⟦19dbdf2f3⟧ Ada Source

    Length: 9216 (0x2400)
    Types: Ada Source
    Notes: 03_class, FILE, R1k_Segment, e3_tag, package body Find_Variable_References, seg_00441b

Derivation

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦5a81ac88f⟧ »Space Info Vol 1« 
        └─⟦this⟧ 

with Log;
with Profile;
with Common;
with Id_Referencers;
with Add_Hyper_Table;
with Create_Null_Document;
with Lrm_Renames;
use Lrm_Renames;
with Directory_Renames;
use Directory_Renames;
with Errors;
with Simple_Status;
with Lrm_Utilities;
package body Find_Variable_References is

    function Unit_Name (Elem : Ada.Element) return String is
    begin
        return Decls.Name (Comp_Units.Unit_Declaration
                              (Comp_Units.Parent_Compilation_Unit (Elem)));
    end Unit_Name;

    function Unit_Id (Elem : Ada.Element) return Ada.Element is
    begin
        return Ada.Value (Decls.Identifiers
                             (Comp_Units.Unit_Declaration
                                 (Comp_Units.Parent_Compilation_Unit (Elem))));
    end Unit_Id;

    procedure Add (Units       :        String := "";
                   To_Document : in out Abstract_Document.Handle;
                   Response    :        String := "<PROFILE>") is

        Units_Iter : Object.Iterator := Naming.Resolution (Units);

        type Columns is (Unit, Reference, Referenced_Parent, Set_Used);

        function Is_Integer_Column (C : Columns) return Boolean is
        begin
            return False;
        end Is_Integer_Column;

        function Is_Included (Elem : Ada.Element) return Boolean is
            Def : Ada.Element;
        begin
            case Exprs.Kind (Elem) is
                when Exprs.A_Simple_Name |
                     Exprs.An_Indexed_Component | Exprs.A_Slice =>
                    Def := Ada.Definition (Elem);

                    case Decls.Kind (Def) is
                        when Decls.A_Variable_Declaration =>
                            if Lrm_Utilities.Is_Actual_Variable_Declaration
                                  (Def) then  
                                return True;
                            else
                                return False;
                            end if;  
                        when others =>
                            return False;
                    end case;
                when others =>
                    return False;
            end case;
        end Is_Included;

        function Explanation (C    : Columns;  
                              Elem : Ada.Element) return String is
        begin
            case C is
                when Referenced_Parent =>
                    return "Unit containing the referenced object";
                when Unit =>
                    return "Unit containing the reference";
                when Reference =>
                    return "An object reference";
                when Set_Used =>
                    return "Kind of reference";
            end case;
        end Explanation;

        function Column_Image (C    : Columns;  
                               Elem : Ada.Element) return String is
        begin
            case C is
                when Referenced_Parent =>
                    return Unit_Name (Ada.Definition (Elem));
                when Unit =>
                    return Unit_Name (Elem);
                when Reference =>
                    return Ada.Image (Lrm_Utilities.Get_Full_Name (Elem));
                when Set_Used =>
                    case Id_Referencers.Kind (Elem) is
                        when Id_Referencers.Set =>
                            return "SET";
                        when Id_Referencers.Used =>
                            return "USED";
                        when Id_Referencers.Set_And_Used =>
                            return "SET/USED";
                    end case;

            end case;
        end Column_Image;

        procedure Linkage (C                :     Columns;
                           Elem             :     Ada.Element;
                           Linkage_Element  : out Ada.Element;
                           Linkage_Elements : out Ada.Element_List) is
        begin
            -- default values changed within the case statement as necessary
            Linkage_Element  := Ada.Nil_Element;
            Linkage_Elements := Ada.Nil_List;

            case C is
                when Referenced_Parent =>
                    Linkage_Element := Unit_Id (Ada.Definition (Elem));
                when Unit =>
                    Linkage_Element := Unit_Id (Elem);
                when Reference =>
                    Linkage_Element := Lrm_Utilities.Get_Full_Name (Elem);
                when Set_Used =>
                    Linkage_Element := Ada.Nil_Element;
            end case;
        end Linkage;

        procedure Add_Hyper_Table_To_Doc is
           new Add_Hyper_Table
                  (Is_Included,  
                   Columns,  
                   Is_Integer_Column, Column_Image, Explanation, Linkage,  
                   Table_Title => "VARIABLE REFERENCES");
    egin
        if Object.Is_Bad (Units_Iter) then
            Log.Put_Line (Units & " is not a valid pathname",
                          Profile.Error_Msg);
        else
            Add_Hyper_Table_To_Doc (Units_Iter, To_Document);
        end if;
    end Add;

    procedure Display (Units             : String := "";
                       To_Preview_Object : String := "Variable_Reference_Info";
                       Response          : String := "<PROFILE>") is
        Document  : Abstract_Document.Handle;
        Condition : Errors.Condition;
    begin

        Create_Null_Document (Named           => To_Preview_Object,
                              Error_Info      => Condition,
                              Document_Handle => Document);

        case Errors.Severity (Condition) is
            when Simple_Status.Problem | Simple_Status.Fatal =>
                Log.Put_Line ("Problem creating object " & To_Preview_Object &
                              ".  " & Errors.Info (Condition),
                              Profile.Error_Msg);
            when others =>

                Add (Units, Document, Response);

                Abstract_Document.Close (Document);
                Common.Definition (To_Preview_Object);

        end case;
    end Display;
end Find_Variable_References;

    nblk1=8
    nid=0
    hdr6=10
        [0x00] rec0=20 rec1=00 rec2=01 rec3=06c
        [0x01] rec0=1a rec1=00 rec2=02 rec3=00e
        [0x02] rec0=1b rec1=00 rec2=03 rec3=01c
        [0x03] rec0=17 rec1=00 rec2=04 rec3=038
        [0x04] rec0=18 rec1=00 rec2=05 rec3=008
        [0x05] rec0=00 rec1=00 rec2=08 rec3=002
        [0x06] rec0=17 rec1=00 rec2=06 rec3=042
        [0x07] rec0=0c rec1=00 rec2=07 rec3=001
    tail 0x215003552815c63bbe0f3 0x42a00088462061e03