DataMuseum.dk Presents historical artifacts from the history of: Rational R1000/400

This is an automatic "excavation" of a thematic subset of artifacts from Datamuseum.dk's BitArchive. See our Wiki for more about Rational R1000/400 Excavated with: AutoArchaeologist - Free & Open Source Software.

top - download

⟦5de4e4689⟧ Ada Source

    Length: 7168 (0x1c00)
    Types: Ada Source
    Notes: 03_class, FILE, R1k_Segment, e3_tag, package body Find_Overhead_Functions, seg_00440b

Derivation

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦cfc2e13cd⟧ »Space Info Vol 2« 
        └─⟦this⟧ 

with Log;
with Profile;
with Common;
with Add_Hyper_Table;
with Create_Null_Document;
with Lrm_Renames;
use Lrm_Renames;
with Directory_Renames;
use Directory_Renames;
with Errors;
with Simple_Status;
with Lrm_Utilities;
package body Find_Overhead_Functions is

    procedure Add (Units       :        String := "";
                   To_Document : in out Abstract_Document.Handle;
                   Response    :        String := "<PROFILE>") is

        Return_Exp : Ada.Element;

        Units_Iter : Object.Iterator := Naming.Resolution (Units);

        type Columns is (Function_Name, Returned_Object);

        function Is_Integer_Column (C : Columns) return Boolean is
        begin
            return False;
        end Is_Integer_Column;

        function Is_Included (Elem : Ada.Element) return Boolean is
            Stmt : Ada.Element;
        begin
            case Decls.Kind (Elem) is
                when Decls.A_Function_Body_Declaration =>
                    Stmt := Ada.Value (Stmts.Block_Body_Statements
                                          (Decls.Subprogram_Block (Elem)));
                    if Lrm_Utilities.Is_Actual_Declaration (Elem) and then
                       Stmts.Kind (Stmt) = Stmts.A_Return_Statement then

                        Return_Exp := Stmts.Return_Expression (Stmt);

                        case Exprs.Kind (Return_Exp) is
                            when Exprs.A_Simple_Name |
                                 Exprs.A_Selected_Component | Exprs.A_Slice |
                                 Exprs.An_Indexed_Component =>
                                return True;

                            when others =>
                                return False;
                        end case;
                    else
                        return False;
                    end if;
                when others =>
                    return False;
            end case;
        end Is_Included;

        function Explanation (C : Columns; Elem : Ada.Element) return String is
        begin
            case C is
                when Function_Name =>
                    return "Name of the function";
                when Returned_Object =>
                    return "Name of the returned type";
            end case;
        end Explanation;

        function Column_Image (C : Columns; Elem : Ada.Element) return String is
        begin
            case C is
                when Function_Name =>
                    return Decls.Name (Elem);
                when Returned_Object =>
                    return Decls.Name (Ada.Definition (Return_Exp));
            end case;
        end Column_Image;

        procedure Linkage (C                :     Columns;
                           Elem             :     Ada.Element;
                           Linkage_Element  : out Ada.Element;
                           Linkage_Elements : out Ada.Element_List) is
        begin
            -- default values changed within the case statement as necessary
            Linkage_Elements := Ada.Nil_List;

            case C is
                when Function_Name =>
                    Linkage_Element := Elem;
                when Returned_Object =>
                    Linkage_Element := Ada.Definition (Return_Exp);
            end case;
        end Linkage;

        procedure Add_Hyper_Table_To_Doc is
           new Add_Hyper_Table
                  (Is_Included,  
                   Columns,  
                   Is_Integer_Column, Column_Image, Explanation, Linkage,  
                   Table_Title =>
                      "OVERHEAD FUNCTIONS RETURNING VARIABLE REFERENCES");
    begin
        if Object.Is_Bad (Units_Iter) then
            Log.Put_Line (Units & " is not a valid pathname",
                          Profile.Error_Msg);
        else
            Add_Hyper_Table_To_Doc (Units_Iter, To_Document);
        end if;
    end Add;

    procedure Display (Units             : String := "";
                       To_Preview_Object : String := "Overhead_Info";
                       Response          : String := "<PROFILE>") is
        Document  : Abstract_Document.Handle;
        Condition : Errors.Condition;
    begin

        Create_Null_Document (Named           => To_Preview_Object,
                              Error_Info      => Condition,
                              Document_Handle => Document);

        case Errors.Severity (Condition) is
            when Simple_Status.Problem | Simple_Status.Fatal =>
                Log.Put_Line ("Problem creating object " & To_Preview_Object &
                              ".  " & Errors.Info (Condition),
                              Profile.Error_Msg);
            when others =>

                Add (Units, Document, Response);

                Abstract_Document.Close (Document);
                Common.Definition (To_Preview_Object);

        end case;
    end Display;
end Find_Overhead_Functions;

    nblk1=6
    nid=0
    hdr6=c
        [0x00] rec0=23 rec1=00 rec2=01 rec3=05c
        [0x01] rec0=16 rec1=00 rec2=02 rec3=02a
        [0x02] rec0=1a rec1=00 rec2=03 rec3=060
        [0x03] rec0=19 rec1=00 rec2=04 rec3=066
        [0x04] rec0=19 rec1=00 rec2=05 rec3=020
        [0x05] rec0=05 rec1=00 rec2=06 rec3=000
    tail 0x2170016d4815c639575c8 0x42a00088462061e03