DataMuseum.dk

top - download

    Length: 2374 (0x946)
    Types: TextFile
    Notes: R1k Text-file segment

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦5a81ac88f⟧ »Space Info Vol 1« 
        └─⟦abecc96c0⟧ 
            └─⟦this⟧ 

TextFile

--
-- This script returns an output file describing the hierarchy of the
-- specified model.  The syntax of this file is as follows:
--
--    A   -- model identifier
--    M   -- A's node number
--    ... -- A's comments
--    ... -- requirements 1 to 9 for A 
--    2   -- number of sons of A
--    B   -- identifier of A's first son
--    M1  -- B's node number    
--    ... -- B's comments
--    ... -- requirements 1 to 9 for B 
--    0   -- number of sons of B
--    C   -- identifier of A's second son
--    M2  -- C's node number
--    ... -- C's comments
--    ... -- requirements 1 to 9 for C 
--    1   -- number of sons of C
--    D   -- identifier of C's unique son
--    M21 -- D's node number
--    ... -- D's comments
--    ... -- requirements 1 to 9 for D 
--    0   -- number of sons of D
--           
-- This syntax has been chosen to make sure that we can parse the module
-- identifiers even if they contain funny characters.  This information
-- will be used to create the following gateway structure:
--
--    A
--      .B
--      .C
--         .D
--    
outfile : output;
root : Tmodule;
--
feature (Tmodule) annotation (s : string) is
local
do  
   if current.is_valued (s) then
      outfile.fprint_f ("%s\n", current.stgann (s));
   else
      outfile.fprint_f ("\n");
   end;
end;
--
feature (Tmodule) hierarchy () is
local
   sons : set [Tmodule];
   son  : Tmodule;
do                               
   outfile.fprint_f ("%s\n", current.ident);
   outfile.fprint_f ("%s\n", current.node);
   outfile.fprint_f ("%s\n", current.comment);
   current.annotation ("requirement_1");
   current.annotation ("requirement_2");
   current.annotation ("requirement_3");
   current.annotation ("requirement_4");
   current.annotation ("requirement_5");
   current.annotation ("requirement_6");
   current.annotation ("requirement_7");
   current.annotation ("requirement_8");
   current.annotation ("requirement_9");
   sons := current.sons;
   outfile.fprint_f ("%d\n", sons.card);
   for son in sons do
      son.hierarchy;
   end;
end;                                          
--             
outfile.create ("**OUTPUT**");
outfile.open_write;
root := modelc_load ("**MODEL**",
                     "**ANNOTATIONS**",
                     "**ANNOTATION_TYPES**",
                     "M",
                     false);
root.hierarchy;
outfile.close;