DataMuseum.dk Presents historical artifacts from the history of: Rational R1000/400

This is an automatic "excavation" of a thematic subset of artifacts from Datamuseum.dk's BitArchive. See our Wiki for more about Rational R1000/400 Excavated with: AutoArchaeologist - Free & Open Source Software.

top - download

⟦7dcd22ff5⟧ Ada Source

    Length: 5120 (0x1400)
    Types: Ada Source
    Notes: 03_class, FILE, R1k_Segment, e3_tag, seg_0217d2

Derivation

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦5a81ac88f⟧ »Space Info Vol 1« 
        └─⟦this⟧ 

PROCEDURE Transport_Server_Proc (Service      : IN OUT Service_Type;
                                 Connection   : IN OUT Transport.Connection_Id;
                                 Network      : Transport_Defs.Network_Name;
                                 Local_Socket : Transport_Defs.Socket_Id) IS


   Status      : Transport_Defs.Status_Code;  
   Fatal_Error : EXCEPTION;

   Min_Backoff : CONSTANT Duration := 0.1;
   Max_Backoff : CONSTANT Duration := 5 * 60.0;
   Backoff     : Duration          := Min_Backoff;

   PROCEDURE Do_Backoff (Backoff : IN OUT Duration) IS
   BEGIN
      DELAY Backoff;
      Backoff := 2 * Backoff;
      IF Backoff > Max_Backoff THEN
         Backoff := Max_Backoff;
      END IF;
   END Do_Backoff;

   FUNCTION Status_Ok RETURN Boolean IS
   BEGIN
      CASE Status IS
         WHEN Transport_Defs.Ok =>
            RETURN True;
         WHEN Transport_Defs.Too_Many_Clients |
              Transport_Defs.No_Hardware | Transport_Defs.No_Such_Network |
              Transport_Defs.Socket_In_Use | Transport_Defs.Access_Denied =>
            RAISE Fatal_Error;
         WHEN OTHERS =>
            Do_Backoff (Backoff);
            RETURN False;
      END CASE;
   END Status_Ok;

BEGIN
   LOOP
      Transport.Open (Connection, Status, Network, Local_Socket);

      IF Status_Ok THEN
         Transport.Connect (Connection, Status);
         IF Status_Ok THEN
            Serve (Service, Connection);
            Backoff := Min_Backoff;
         END IF;
         Transport.Disconnect (Connection);
      END IF;
      Transport.Close (Connection);
   END LOOP;
EXCEPTION
   WHEN Fatal_Error =>
      Transport.Close (Connection);
   WHEN OTHERS =>
      Transport.Close (Connection);
      RAISE;
END Transport_Server_Proc;

    nblk1=4
    nid=2
    hdr6=4
        [0x00] rec0=1e rec1=00 rec2=01 rec3=04c
        [0x01] rec0=1e rec1=00 rec2=04 rec3=000
        [0x02] rec0=13 rec1=00 rec2=02 rec3=000
        [0x03] rec0=0f rec1=00 rec2=03 rec3=001
    tail 0x2151ce1da838e77ea8a0c 0x489e0066482863c01
Free Block Chain:
  0x2: 0000  00 03 00 7c 80 10 73 65 20 28 43 6f 6e 6e 65 63  ┆   |  se (Connec┆
  0x3: 0000  00 00 01 b7 80 0c 6f 6e 2c 20 53 74 61 74 75 73  ┆      on, Status┆