DataMuseum.dk

top - download

    Length: 5393 (0x1511)
    Types: TextFile
    Notes: R1k Text-file segment

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦5a81ac88f⟧ »Space Info Vol 1« 
        └─⟦774ae535a⟧ 
            └─⟦this⟧ 

TextFile

! exemple simple de scenario
! no 1

! le point d'exclamation "!" debute une ligne de commentaire

   

!declaration des verbes et des complements
  VERBES SONT
      prendre    lire    abandonner   editer .
   
  COMPLEMENTS SONT
      message    traducteur    jeu   vocabulaire .
      
    

!declaration des familles
  FAMILLES SONT
      identification AVEC nom(CHAINE) ET Prenom(CHAINE) .
      personne       AVEC HERITAGE DE identite(identification) 
                          ET ENSEMBLE DE attributs 
                          ET Nbr_vie(ENTIER).    

!declaration des variables 
  VARIABLES SONT       
      super_heros      COMME personne (("Paulla" "Roide") []   3 ).
      nbr_de_commandes COMME entier .

      
!definition des initialisations simples
INITIALISATIONS SONT
  nbr_de_commandes DEVIENT 0.
  ECRIRE "                Debut d'un petit jeu, pas vraiment d'aventure : 'A LA RECHERCHE DU SCHMILBLICK PERDU ...'".
  ECRIRE "                D'ailleurs la solution est si simple, que l'on vous laisse trouver la question ??? ".
  ECRIRE "".
  ECRIRE "".
  ECRIRE "".
  ECRIRE "Je vous souhaite bonne chance ... ".  
  ECRIRE "".
  ECRIRE "".
  ECRIRE "".
  ECRIRE "Pour quitter le jeu, taper                          : Abandonner jeu ". 
  ECRIRE "".                                           
  ECRIRE "Pour connaitre la liste des mots utilisables, taper : Editer vocabulaire".
  ECRIRE "". 
  ECRIRE "".
  ECRIRE "".
  ECRIRE "Attention, vous devez gagner avec un nombre restreint de commande".
  ECRIRE "(Pour simple information : apres 7 commandes vous serez officiellement declare PERDANT)".
  
!definition de la vie
VIE EST

     SI 'abandonner' COMPLEMENT1
     ALORS 
           SI COMPLEMENT1 = 'jeu'
           ALORS ECRIRE "Espece de lache, vous abandonnez ....".
                 QUITTER.
           SINON ECRIRE "Le verbe 'abandonner' doit etre suivit du mot 'jeu' pour quitter le jeu ".
           FSI.
     FSI.               
     SI ('abandonner') ou ('abandonner' COMPLEMENT1 COMPLEMENT2) 
     ALORS ECRIRE "Le verbe 'abandonner' doit etre uniquement suivit du mot 'jeu' pour quitter le jeu ".
     FSI.
     
     SI 'editer' COMPLEMENT1
     ALORS SI COMPLEMENT1 = 'vocabulaire' 
           ALORS ECRIRE "La liste des mots est la suivante :".
                 ECRIRE "       VERBES = ".
                 ECRIRE "                prendre, lire, abandonner, editer.".
                 ECRIRE "       COMPLEMENTS =".
                 ECRIRE "                message, traducteur, jeu, vocabulaire. ".
                 ECRIRE"".
            SINON ECRIRE "Vous ne pouvez que 'editer' 'vocabulaire', pour connaitre la liste des mots".
                  ECRIRE "du vocabulaire ".
                  ECRIRE"".
            FSI.
     FSI.
     SI ('editer') ou ('editer' COMPLEMENT1 COMPLEMENT2)
     ALORS ECRIRE "Le verbe 'editer' doit etre uniquement suivit du mot 'vocabulaire' pour connaitre la ".
           ECRIRE "liste des mots du vocabulaire".
     FSI.
     

     SI 'prendre' COMPLEMENT1
     ALORS
         SI COMPLEMENT1 = 'traducteur'
         ALORS SI NON ('traducteur' DANS attributs de super_heros)
               ALORS AJOUTER 'traducteur' A attributs DE super_heros.
                     ECRIRE "Vous possedez " attributs DE super_heros.
               SINON ECRIRE "vous possedez deja cet objet".
               FSI.
         SINON ECRIRE "Vous ne pouvez pas prendre cet objet".
         FSI.
     FSI. 
     SI 'prendre' 
     ALORS ECRIRE "Prendre quoi ? : mon pied peut etre ??? ".
           ECRIRE "Ca vous fatiguerait de preciser l'objet a prendre ? ".
     FSI.
     SI 'prendre' COMPLEMENT1 COMPLEMENT2
     ALORS ECRIRE "Vous n'etes pas assez fort pour prendre deux objets a la fois !".
     FSI.
     

     SI 'lire' COMPLEMENT1
     ALORS
          SI COMPLEMENT1 = 'message'
          ALORS SI ('traducteur' DANS attributs DE super_heros)
                ALORS ECRIRE "Le message est :".
                      ECRIRE "Bravo vous avez gagne le droit d'offrir un pot aux concepteurs de ce jeu".
                      QUITTER.  
                SINON ECRIRE " _._  _..  _.... _ _..___ __..__ ... __. _ ___..._  __ .._ _.._ ".
                      ECRIRE "Il s'agit d'un message en morse !".
                      ECRIRE "ce serait bien si vous le dechiffreriez". 
                FSI.
          SINON ECRIRE "Piniouff, vous ne pouvez pas lire ca !!!! ".
          FSI.
      FSI.
      SI 'lire'
      ALORS ECRIRE "Lire quoi???, vous etes devin ou quoi???".
      FSI.
      SI 'lire' COMPLEMENT1 COMPLEMENT2 
      ALORS ECRIRE "Je sais que vous avez deux yeux, mais ce n'est pas une raison pour essayer de lire".
            ECRIRE "deux trucs a la fois ".
      FSI.
       

      nbr_de_commandes DEVIENT nbr_de_commandes + 1.                      

      SI nbr_de_commandes = (nbr_vie DE super_heros*2)   !attention la ligne ci-dessus ne sera evaluee qu'apres
                                                         !l'evaluation de toutes les conditions
      ALORS   !attention syntaxe pour atteindre un champs herite
             ECRIRE nom DE identite DE super_heros " "   prenom de identite de super_heros  ",vous n'avez pas trouve apres".
             ECRIRE "7 commandes ... c'est PERDU !".
             QUITTER.
      FSI.
      
      ECRIRE "".

!fin du fichier