DataMuseum.dk

top - download

    Length: 18368 (0x47c0)
    Types: TextFile
    Notes: R1k Text-file segment

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦cfc2e13cd⟧ »Space Info Vol 2« 
        └─⟦29d252288⟧ 
            └─⟦this⟧ 

TextFile

JEU La_Belle   { ou comment echapper a 2 Orc }

ACTION

   Attaquer    
   Prendre
   Decrire     SYNONYME ( Regarder )
   Mettre
   Enlever
   Aider       SYNONYME ( Help )
   Inventaire
   Aller
   Utiliser
   Boire

DEFINITION

   ENUMERE   Etat_Pj    ( Norms, Super )
   STRUCTURE Pj     ( Etat_Pj Etat, ENTIER Vie )

   ENUMERE   Etat_Pnj   ( En_Vie, Mort, Endormi )
   STRUCTURE Pnj    ( Etat_Pnj Etat, CHAINE Descrip_Lg1, CHAINE Descrip_Lg2 )

   STRUCTURE Piece  ( CHAINE Descrip_Lg1, CHAINE Descrip_Lg2 )

   ENUMERE   Etat_Protection ( Ok, Detruit, Porte )
   STRUCTURE Protection ( Etat_Protection Etat, CHAINE Descrip_Lg1, CHAINE Descrip_Lg2 )

   STRUCTURE Divers     ( CHAINE Descrip_Lg1, CHAINE Descrip_Lg2 )

PRESENTATION

   Memrik OBJET Pj  AVEC ( Norms, 20 )

   Glouba OBJET Pnj AVEC ( Endormi,
                           "Un gros Troll plein de puces... Il a une enorme hache et",
                           "visiblement il n'a pas l'air commode !"                    )

   Gloubi OBJET Pnj AVEC ( En_Vie,
                           "Une autre de ces bestiole, je commence a hair c'est gros tas",
                           "de gelatine de troll (a vrai dire je ne les ai jamais aime) !!!" )

   Troll  OBJET Pnj INIT Glouba

   Garde_Manger OBJET Piece AVEC ( "Une grande salle taille dans le roc, un enorme tas de cadavres est juste",
                                   "deriere moi, A part ca au nord il a un couloir qui se perd dans la penombre..." )
   Chambre      OBJET Piece AVEC ( "Une petite salle, au centre il y a un gros tas de paille, et quelques rochers.",
                                   "qui doivent servir de nourriture. Au nord il y a un couloir ainsi qu'au sud." )
   Sortie       OBJET Piece AVEC ( "La sortie... On peut voir la lisiere de la foret d'ici !...",
                                   "Au sud il y a couloir et au nord la sortie." )
   Secret       OBJET Piece AVEC ( "Une piece minuscule ou se trouve tout plein de chose.",
                                   "A l'est il y a un passage etroit." )

   Tas           OBJET Divers AVEC ( "Breerk, un amas de cadavre... Cet endroit doit etre une sorte de garde manger",
                                     "pour les trolls qui m'ont captures." )

   Casque        OBJET Protection AVEC ( Ok,
                                         "Un casque de bronze, il est d'une facture remarquable et dans un tres tres",
                                         "bon etat." )

   Bouclier      OBJET Protection AVEC ( Ok,
                                         "Un bouclier de bois, il pourra surement me servir dans mon evasion...",
                                         "au cas ou je tomberai sur mes ravisseurs." )

   Armure        OBJET Protection AVEC ( Ok,
                                         "Une veille armure de plate complete, elle pourra surement me servir dans",
                                         "mon evasion... au cas ou je tomberai sur mes ravisseurs." )

   Rocher        OBJET Divers AVEC ( "Un gros caillou tout gris... Il doit servir de digestif aux trolls",
                                     "du coin." )

   Tas_de_Paille OBJET Divers AVEC ( "Um amas de paille qui sert visiblement de lit pour les habitants de",
                                     "cet endroit si charmant..." )

   Couteau       OBJET Divers AVEC ( "Whoua... Un vrai couteau Suisse avec la totale (couteau, ciseaux,",
                                     "trombole, fusil a pompe, etc) " )

   Potion_Verte  OBJET Divers AVEC ( "Bizzard une potion toute verte, elle a une drole d'odeur de",
                                     "MORT. Breerk c'est pas cool." )

   Potion_Rouge  OBJET Divers AVEC ( "Une potion rouge feu, elle bouillonne dans sa fiole et degage",
                                     "une souffre." )

   Position       OBJET Piece INIT Garde_Manger

LIAISON

   CONNEXION ( Nord, Sud, Est, Ouest, Bas, Haut, Gauche, Droite )

   CREER_CONNEXION ( Garde_Manger, Chambre, Nord, LIE )
   CREER_CONNEXION ( Chambre, Garde_Manger, Sud, LIE )
   CREER_CONNEXION ( Chambre, Secret , Ouest, DELIE )
   CREER_CONNEXION ( Secret , Chambre, Est, LIE )
   CREER_CONNEXION ( Chambre, Sortie, Nord, LIE )
   CREER_CONNEXION ( Sortie, Chambre, Sud, LIE )

   CREER_LIEN ( Memrik, Casque, DELIE )
   CREER_LIEN ( Memrik, Rocher, DELIE )
   CREER_LIEN ( Memrik, Potion_Verte, DELIE )
   CREER_LIEN ( Memrik, Potion_Rouge, DELIE )

   CREER_LIEN ( Glouba, Chambre, LIE )
   CREER_LIEN ( GloubI, Chambre, LIE )

   CREER_LIEN ( Garde_Manger, Tas, LIE )
   CREER_LIEN ( Garde_Manger, Bouclier, DELIE )
   CREER_LIEN ( Garde_Manger, Armure, DELIE )
   CREER_LIEN ( Garde_Manger, Casque, DELIE )

   CREER_LIEN ( Chambre, Rocher, LIE )
   CREER_LIEN ( Chambre, Tas_de_Paille, LIE )
   
   CREER_LIEN ( Secret, Couteau, LIE )
   CREER_LIEN ( Secret, Potion_Verte, LIE )
   CREER_LIEN ( Secret, Potion_Rouge, LIE )


INTRODUCTION

   AFFICHER ( "  Vous vous reveillez couche dans une grotte... Vos souvenirs" )
   AFFICHER ( "reviennent... alors que vous chassiez le lievre, vous avez ete" )
   AFFICHER ( "sauvagement attaque par deux trolls, le seul souvenir tangible" )
   AFFICHER ( "de cet attaque sont une grosse bosse et une plaie a la jambe." )
   AFFICHER ( "  Il faut donc sortir au plus vite avant que les Trolls ne reviennent" )
   AFFICHER ( "pour vous manger, et avant que votre blessure ne vous affaiblisse de" )
   AFFICHER ( "de trop." )
   AFFICHER ( " " )

ANIMATION_GENERALE

   POUR 2 ENTREE FAIRE
      SI Memrik.Etat = Norms ALORS
         Memrik.Vie:=Memrik.Vie-1
      SINON
         Memrik.Vie:=Memrik.Vie-3
      FINSI
   FINPOUR

   POUR 5 ENTREE FAIRE
      SI Memrik.Vie >= 10 ALORS
         AFFICHER ( "Il faut se depecher !" )
      SINON
         SI Memrik.Vie >= 5 ALORS
            AFFICHER ( "Ma blessure me fait de plus en plus souffrir ! Vite..." )
         SINON
            SI Memrik.Vie >= 2 ALORS
               AFFICHER ( "De grace ! Vite..." )
            SINON
               SI Memrik.Vie >= 1 ALORS
                  AFFICHER ( "Je vais bientot m'ecrouler et les Trolls vont me manger !!!" )
               FINSI
            FINSI
         FINSI
      FINSI
      AFFICHER ( " " )
   FINPOUR

   SI Memrik.Vie <= 0 ALORS
      AFFICHER ( "Vous vous ecrouler sur le sol glacial de la grotte, alors que vos dernieres" )
      AFFICHER ( "vous quitte vous sentez une douleur au nivaeu de votre jambe. Trop faible" )
      AFFICHER ( "pour criez, et pour reagir, vous restez la a regarder les trolls vous devorer !" )
      FIN
   FINSI

ANIMATION_GLOBALE

   SI [ Aider ] ALORS
      AFFICHER ( "Vous pouvez: Attaquer, Prendre, Decrire, Mettre," )
      AFFICHER ( "             Enlever, Inventaire, Aller, Utiliser" )
   FINSI

   SI [ Inventaire ] ALORS
      AFFICHER ( "Vous avez sur vous:" )
      AFFICHER ( " " )
      LISTE_LIEN (Memrik, LIE )
      AFFICHER ( " " )
   FINSI

   SI [ Aller COMP ] OU [ COMP ] ALORS
      SI EXISTE_CONNEXION (Position, COMP) = VRAI ALORS
         SI ETAT_CONNEXION (Position, COMP) = LIE ALORS
            Position := DESTINATION_CONNEXION (Position, COMP)
            AFFICHER ( " " )
            AFFICHER ( Position.Descrip_Lg1 )
            AFFICHER ( Position.Descrip_Lg2 )
            AFFICHER ( " " )
         SINON
            AFFICHER ( "Il n'y a pas d'issue par ici." )
         FINSI
      SINON
         AFFICHER ( "Il n'y a pas d'issue par ici." )
      FINSI
   FINSI

   SI [ Decrire COMP ] ALORS
      SI ETAT_LIEN ( Position, COMP ) = LIE OU ETAT_LIEN ( Memrik, COMP ) = LIE ALORS
         AFFICHER ( " " )
         AFFICHER ( COMP.Descrip_Lg1 )
         AFFICHER ( COMP.Descrip_Lg2 )
         AFFICHER ( " " )
      FINSI
   FINSI
   
   SI [ Decrire ] ALORS
      AFFICHER ( " " )
      AFFICHER ( Position.Descrip_Lg1 )
      AFFICHER ( Position.Descrip_Lg2 )
      AFFICHER ( " " )
   FINSI

   SI [ Prendre COMP ] ALORS
      SI EXISTE_LIEN ( Memrik, COMP ) = VRAI ALORS
         SI ETAT_LIEN ( Memrik, COMP ) = DELIE ALORS
            SI EXISTE_LIEN ( Position, COMP ) = VRAI ALORS
               SI ETAT_LIEN ( Position, COMP ) = LIE ALORS
                  ECHANGER_LIEN ( COMP, Position, Memrik )
               SINON
                  AFFICHER ( "Prendre quoi ???" )
               FINSI
            SINON
               AFFICHER ( "Prendre quoi ???" )
            FINSI
         SINON
            AFFICHER ( "Je l'ai deja !" )
         FINSI
      SINON
         AFFICHER ( "Et j'en fairait quoi ???" )
      FINSI
   FINSI

   SI [ Attaquer COMP ] ALORS
      AFFICHER ( "Tu petes les plombs ou quoi ???" )
   SINON
      AFFICHER ( "Un ange passe .........." )
   FINSI

ANIMATION_LOCALE

   SI [ Decrire Tas ] ET Position = Garde_Manger ALORS
      AFFICHER ( Tas.Descrip_Lg1 )
      AFFICHER ( Tas.Descrip_Lg2 )
      SI ETAT_LIEN ( Garde_Manger, Bouclier ) = DELIE ALORS
         AFFICHER ( "   Oh il y a un bouclier dans le tas." )
         LIE_LIEN ( Garde_Manger, Bouclier )
      SINON
         SI ETAT_LIEN ( Garde_Manger, Casque ) = DELIE ALORS
            AFFICHER ( "   Oh il y a encore un casque dans le tas." )
            LIE_LIEN ( Garde_Manger, Casque )
         SINON
            SI ETAT_LIEN ( Garde_Manger, Casque ) = DELIE ALORS
               AFFICHER ( "   Oh il y a encore un casque dans le tas." )
               LIE_LIEN ( Garde_Manger, Casque )
            FINSI
         FINSI
      FINSI
   FINSI

   SI [ Prendre Bouclier ] ET Position = Garde_Manger ALORS
      SI ETAT_LIEN ( Garde_Manger, Bouclier ) = LIE ALORS
         SI Bouclier.Etat = Ok ALORS
            Bouclier.Etat := Detruit
            AFFICHER ( "  En tentant de prendre le bouclier vous le casse. Le bois etait" )
            AFFICHER ( "trop vieux." )
         SINON
            AFFICHER ( "  Ce n'est deja plus qu'un gros tas de debris." )
         FINSI
      SINON
         AFFICHER ( "Prendre quoi ???" )
      FINSI
   FINSI
   
   SI [ Prendre Armure ] ET Position = Garde_Manger ALORS
      SI ETAT_LIEN ( Garde_Manger, Armure ) = LIE ALORS
         SI Armure.Etat = Ok ALORS
            Armure.Etat := Detruit
            AFFICHER ( "  Alors que vous touchez a peine l'armure pour la prendre, elle tombe" )
            AFFICHER ( "poussiere" )
         SINON
            AFFICHER ( "  Ce n'est deja plus qu'un petit tas de poussiere." )
         FINSI
      SINON
         AFFICHER ( "Prendre quoi ???" )
      FINSI
   FINSI

   SI [ Decrire Bouclier ] ET Position = Garde_Manger ALORS
      SI ETAT_LIEN ( Garde_Manger, Bouclier ) = LIE ALORS
         SI Bouclier.Etat = Ok ALORS
            AFFICHER ( Bouclier.Descrip_Lg1 )
            AFFICHER ( Bouclier.Descrip_Lg2 )
         SINON
            AFFICHER ( "  C' est un gros tas de debris." )
         FINSI
      SINON
         AFFICHER ( "Quoi ???" )
      FINSI
   FINSI

   SI [ Decrire Armure ] ET Position = Garde_Manger ALORS
      SI ETAT_LIEN ( Garde_Manger, Armure ) = LIE ALORS
         SI Bouclier.Etat = Ok ALORS
            AFFICHER ( Armure.Descrip_Lg1 )
            AFFICHER ( Armure.Descrip_Lg2 )
         SINON
            AFFICHER ( "C'est un petit tas de poussiere.." )
         FINSI
      SINON
         AFFICHER ( "Quoi ???" )
      FINSI
   FINSI

   SI [ Mettre Casque ] ALORS
      SI ETAT_LIEN ( Casque, Memrik ) = LIE ALORS
         SI Casque.Etat = Porte ALORS
            AFFICHER ( "Je le porte deja!" )
         SINON
            Casque.Etat := Porte
            AFFICHER ( "Il me va parfaitement." )
            LIE_CONNEXION ( Chambre, Ouest )
         FINSI
      SINON
         SI ETAT_LIEN ( Garde_Manger, Casque ) = LIE ALORS
            Casque.Etat := Porte
            ECHANGER_LIEN ( Casque, Garde_Manger, Memrik )
            AFFICHER ( "Il me va parfaitement." )
            LIE_CONNEXION ( Chambre, Ouest )
         SINON
            AFFICHER ( " ?!? " )
         FINSI
      FINSI
   FINSI
   
   SI [ Enlever Casque ] ALORS
      SI ETAT_LIEN ( Casque, Memrik ) = LIE ALORS
         SI Casque.Etat = Porte ALORS
            Casque.Etat := Ok
            AFFICHER ( "Je l'enleve." )
            DELIE_CONNEXION ( Chambre, Ouest )
         SINON
            AFFICHER ( "Je ne le porte meme pas sur la tete." )
         FINSI
      SINON
         SI ETAT_LIEN ( Garde_Manger, Casque ) = LIE ALORS
            AFFICHER ( "Je ne le porte meme pas sur la tete." )
         SINON
            AFFICHER ( " ?!? " )
         FINSI
      FINSI
   FINSI

   SI ( [ Aller Ouest ] OU [ Ouest ] ) ET Position = Chambre ALORS
      SI ETAT_CONNEXION (Chambre, Ouest) = LIE ALORS
         Position := Secret
         AFFICHER  ( Secret.Descrip_Lg1 )
         AFFICHER  ( Secret.Descrip_Lg2 )
         SI ETAT_LIEN (Secret,Couteau) = LIE ALORS
            AFFICHER ("Il y a surtout un couteau." )
         FINSI
         SI ETAT_LIEN (Secret,Potion_Verte) = LIE ALORS
            AFFICHER ("Il y a aussi un potion_verte." )
         FINSI
         SI ETAT_LIEN (Secret,Potion_Rouge) = LIE ALORS
            AFFICHER ("Il y a encore un potion_rouge." )
         FINSI
      SINON
         AFFICHER ( "Il n'y a pas d'issue par ici." )
      FINSI
   FINSI

   SI [ Decrire ] ET Position = Secret ALORS
      AFFICHER  ( Secret.Descrip_Lg1 )
      AFFICHER  ( Secret.Descrip_Lg2 )
      SI ETAT_LIEN (Secret,Couteau) = LIE ALORS
         AFFICHER ("Il y a surtout un couteau." )
      FINSI
      SI ETAT_LIEN (Secret,Potion_Verte) = LIE ALORS
         AFFICHER ("Il y a aussi un potion_verte." )
      FINSI
      SI ETAT_LIEN (Secret,Potion_Rouge) = LIE ALORS
         AFFICHER ("Il y a encore un potion_rouge." )
      FINSI
   FINSI

   SI ( [ Aller Nord ] OU [ Nord ] ) ET Position = Sortie ALORS
      SI Gloubi.Etat = Mort ALORS
         AFFICHER ( "Vive la liberte......." )
         FIN
      SINON
         AFFICHER ( "Le Troll ne me laissera jamais passer." )
      FINSI
   FINSI

   SI ( [ Aller Nord ] OU [ Nord ] ) ET Position = Chambre ALORS
      Position := Sortie
      AFFICHER  ( Sortie.Descrip_Lg1 )
      AFFICHER  ( Sortie.Descrip_Lg2 )
      Troll := Gloubi
      SI Troll.Etat = En_Vie ALORS
         AFFICHER  ( "Il y a un gros Troll qui garde la sortie!" )
         AFFICHER  ( "Alors tout doux." )
      SINON
         SI Troll.Etat = Mort ALORS
            AFFICHER  ( "Il y a un cadavre de Troll a l'entree de la caverne." )
         FINSI
      FINSI
   FINSI

   SI (( [ Aller Nord ] OU [ Nord ] ) ET Position = Garde_Manger ) OU
      (( [ Aller Sud ] OU [ Sud ] ) ET Position = Sortie )        OU
      (( [ Aller Est ] OU [ Est ] ) ET Position = Secret )        ALORS
      Position := Chambre
      AFFICHER  ( Chambre.Descrip_Lg1 )
      AFFICHER  ( Chambre.Descrip_Lg2 )
      Troll := Glouba
      SI ETAT_CONNEXION (Chambre, Ouest ) = LIE ALORS
         AFFICHER ( "Il y a un etroit passage a l'ouest" )
      FINSI
      SI Troll.Etat = Endormi ALORS
         AFFICHER  ( "Il y a un gros Troll qui dort sur un tas de paille..." )
         AFFICHER  ( "Alors tout doux." )
      SINON
         SI Troll.Etat = Mort ALORS
            AFFICHER  ( "Il y a un cadavre de Troll sur le tas de paille!" )
         FINSI 
      FINSI
   FINSI
   
   SI [ Decrire ] ET Position = Chambre ALORS
      AFFICHER  ( Chambre.Descrip_Lg1 )
      AFFICHER  ( Chambre.Descrip_Lg2 )
      SI ETAT_CONNEXION (Chambre, Ouest ) = LIE ALORS
         AFFICHER ( "Il y a un etroit passage a l'ouest" )
      FINSI
      SI Troll.Etat = Endormi ALORS
         AFFICHER  ( "Il y a un gros Troll qui dort sur un tas de paille..." )
         AFFICHER  ( "Alors tout doux." )
      SINON
         SI Troll.Etat = Mort ALORS
            AFFICHER  ( "Il y a un cadavre de Troll sur le tas de paille!" )
         FINSI
      FINSI
   FINSI

   SI [ Decrire ] ET Position = Sortie ALORS
      AFFICHER  ( Sortie.Descrip_Lg1 )
      AFFICHER  ( Sortie.Descrip_Lg2 )
      SI Troll.Etat = En_Vie ALORS
         AFFICHER  ( "Il y a un gros Troll qui garde la sortie!" )
         AFFICHER  ( "Alors tout doux." )
      SINON
         SI Troll.Etat = Mort ALORS
            AFFICHER  ( "Il y a un cadavre de Troll a l'entree de la caverne." )
         FINSI
      FINSI
   FINSI

   SI [ Utiliser Rocher Troll ] ALORS
      SI Position = Chambre ALORS
         SI Troll.ETAT = Endormi ALORS
            AFFICHER ( "Vous fracassez le crane du troll. Il ne reste plus rien ou presque du Troll." )
            Troll.ETAT := Mort
         SINON
            AFFICHER ( "Il est deja mort." )
         FINSI
      SINON
         SI Position = Sortie ALORS
            SI Troll.Etat = Mort ALORS
               AFFICHER ( "Vous frappe le cadavre avec la pierre, il est bien mort." )
            SINON
               AFFICHER ( "NON ! Il risque de me repere, et je ne veux pas ca." )
            FINSI
         SINON
            AFFICHER ( " ?!? " )
         FINSI
      FINSI
   FINSI
   
   SI [ Prendre Couteau ] ET Position = Secret ALORS
      AFFICHER ("Non je veux pas prendre ce truc bizzard." )
   FINSI
   
   SI [ Boire Potion_Verte ] ALORS
      SI ETAT_LIEN (Potion_Verte, Memrik ) = LIE ou Position = Secret ALORS
         AFFICHER ( "Ca a un gout curieux ..................." )
         AFFICHER ( "On dirait .... du poison !!!!!!! " )
         AFFICHER ( " " )
         AFFICHER ( "Vous ne partirez jamais d'ici." )
         FIN
      FINSI
   FINSI
   
   SI [ Boire Potion_Rouge ] ALORS
      SI ETAT_LIEN (Potion_Rouge, Memrik ) = LIE ou Position = Secret ALORS
         AFFICHER ( "Vous vous sentez pret a detuire n'importe quel adversaire maintenant." )
         AFFICHER ( "Cette porion vous a revigore." )
         AFFICHER ( "Attention: Cette potion semble aussi avoir diminue votre resistane phisyque." )
         Memrik.Vie := Memrik.Vie - 3
         Memrik.Etat := Super
      FINSI
   FINSI
   
   SI [ Attaquer Troll ] ET ( Position = Sortie OU Position = Chambre ) ALORS
      SI Memrik.Etat = Norms ALORS
         SI Troll.Etat <> Mort ALORS
            AFFICHER ( "Je me sent trop faible." )
         SINON
            AFFICHER ( "Il est deja mort." )
         FINSI
      SINON
         SI Troll.Etat <> Mort ALORS
            AFFICHER ( "Vous etripez le troll ..... !!!!!  ( cool NON ? )" )
            Troll.Etat := Mort
         SINON
            AFFICHER ( "Il est deja mort." )
         FINSI
      FINSI
   FINSI         
   
FIN