DataMuseum.dk Presents historical artifacts from the history of: Rational R1000/400

This is an automatic "excavation" of a thematic subset of artifacts from Datamuseum.dk's BitArchive. See our Wiki for more about Rational R1000/400 Excavated with: AutoArchaeologist - Free & Open Source Software.

top - download

⟦c7a8cd8ca⟧ Ada Source

    Length: 5120 (0x1400)
    Types: Ada Source
    Notes: 03_class, FILE, R1k_Segment, e3_tag, function Evaluator, seg_0046c2, separate Spreadsheet_Generic.Tool_Set

Derivation

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦cfc2e13cd⟧ »Space Info Vol 2« 
        └─⟦this⟧ 

separate (Spreadsheet_Generic.Tool_Set)
function Evaluator (S : String) return Number is

    X : constant String := S & ")))))))\";
    I : Integer         := X'First;

    function Expression return Number;

    procedure Skip is
    begin
        while X (I) = ' ' loop
            I := I + 1;
        end loop;
    end Skip;

    function Factor return Number is
        Temp : Number;
    begin
        Skip;
        case X (I) is
            when '(' =>
                I    := I + 1;
                Temp := Expression;
                Skip;
                if X (I) = ')' then
                    I := I + 1;
                end if;
                return Temp;
            when '0' .. '9' =>
                Get_Literal (X (I .. X'Last), Temp, I);
                I := I + 1;
                return Temp;
            when ')' =>
                return Zero;
            when others =>
                return Zero;
        end case;
    end Factor;

    function Term return Number is
        Result : Number;
    begin
        Result := Factor;
        loop
            Skip;
            case X (I) is
                when '*' =>
                    I      := I + 1;
                    Result := Result * Factor;
                when '/' =>
                    I      := I + 1;
                    Result := Result / Factor;
                when others =>
                    return Result;
            end case;
        end loop;
    end Term;

    function Expression return Number is
        Result : Number := Zero;
    begin
        Skip;
        case X (I) is
            when '+' =>
                I      := I + 1;
                Result := Term;
            when '-' =>
                I      := I + 1;
                Result := Zero - Term;
            when others =>
                Result := Term;
        end case;
        loop
            Skip;
            case X (I) is
                when '+' | ',' =>
                    I      := I + 1;
                    Result := Result + Term;
                when '-' =>
                    I      := I + 1;
                    Result := Result - Term;
                when '0' .. '9' =>
                    Result := Result + Term;
                when others =>
                    return Result;
            end case;
        end loop;
    end Expression;

begin
    return Expression;
end Evaluator;

    nblk1=4
    nid=0
    hdr6=8
        [0x00] rec0=26 rec1=00 rec2=01 rec3=022
        [0x01] rec0=01 rec1=00 rec2=04 rec3=014
        [0x02] rec0=25 rec1=00 rec2=02 rec3=032
        [0x03] rec0=12 rec1=00 rec2=03 rec3=001
    tail 0x217002a0c815c6701a902 0x42a00088462061e03