DataMuseum.dk Presents historical artifacts from the history of: Rational R1000/400

This is an automatic "excavation" of a thematic subset of artifacts from Datamuseum.dk's BitArchive. See our Wiki for more about Rational R1000/400 Excavated with: AutoArchaeologist - Free & Open Source Software.

top - download

⟦e237f16bd⟧ Ada Source

    Length: 9216 (0x2400)
    Types: Ada Source
    Notes: 03_class, FILE, R1k_Segment, e3_tag, seg_00d44d

Derivation

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─ ⟦5a81ac88f⟧ »Space Info Vol 1« 
        └─⟦this⟧ 

WITH Transport_Complex;
WITH Text_Io;
WITH Complex_Service;
WITH Interchange;
WITH Transport_Interchange;
PACKAGE BODY Complex_Server IS

   PROCEDURE Process_Call (Stream  : Transport_Stream.Stream_Id;
                           Id      : Rpc.Transaction_Id;
                           Version : Rpc.Version_Number;
                           Proc    : Rpc.Procedure_Number) IS
   BEGIN
      CASE Proc IS
         WHEN Complex_Defs.Proc_Number.Make =>
            DECLARE
               Real, Imag : Float;
               Answer     : Complex_Defs.Number;
            BEGIN
               Transport_Interchange.Get (Stream, Interchange.Float (Real));
               Transport_Interchange.Get (Stream, Interchange.Float (Imag));
               Answer := Complex_Service.Make (Real, Imag);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Complex.Put (Stream, Answer);
            END;
         WHEN Complex_Defs.Proc_Number.Real_Part =>
            DECLARE
               X      : Complex_Defs.Number;
               Answer : Float;
            BEGIN
               Transport_Complex.Get (Stream, X);
               Answer := Complex_Service.Real_Part (X);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Interchange.Put (Stream, Interchange.Float (Answer));
            END;
         WHEN Complex_Defs.Proc_Number.Imaginary_Part =>
            DECLARE
               X      : Complex_Defs.Number;
               Answer : Float;
            BEGIN
               Transport_Complex.Get (Stream, X);
               Answer := Complex_Service.Imaginary_Part (X);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Interchange.Put (Stream, Interchange.Float (Answer));
            END;

         WHEN Complex_Defs.Proc_Number.Plus =>
            DECLARE
               Left, Right : Complex_Defs.Number;
               Answer      : Complex_Defs.Number;
            BEGIN
               Transport_Complex.Get (Stream, Left);
               Transport_Complex.Get (Stream, Right);
               Answer := Complex_Service.Plus (Left, Right);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Complex.Put (Stream, Answer);
            END;
         WHEN Complex_Defs.Proc_Number.Minus =>
            DECLARE
               Left, Right : Complex_Defs.Number;
               Answer      : Complex_Defs.Number;
            BEGIN
               Transport_Complex.Get (Stream, Left);
               Transport_Complex.Get (Stream, Right);
               Answer := Complex_Service.Minus (Left, Right);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Complex.Put (Stream, (Answer));
            END;

         WHEN Complex_Defs.Proc_Number.Image =>
            DECLARE
               X : Complex_Defs.Number;
            BEGIN
               Transport_Complex.Get (Stream, X);
               DECLARE
                  Answer : CONSTANT String := Complex_Service.Image (X);
               BEGIN
                  Rpc_Server.Begin_Response (Stream, Id);
                  Transport_Interchange.Put_String (Stream, Answer);
               END;
            END;
         WHEN Complex_Defs.Proc_Number.Value =>
            DECLARE
               X      : CONSTANT String :=
                  Transport_Interchange.Get_String (Stream);
               Answer : Complex_Defs.Number;
            BEGIN
               Answer := Complex_Service.Value (X);
               Rpc_Server.Begin_Response (Stream, Id);
               Transport_Complex.Put (Stream, Answer);
            END;
         WHEN OTHERS =>
            RAISE Rpc.No_Such_Procedure;
      END CASE;
   EXCEPTION
      WHEN Complex_Service.Overflow =>
         Rpc_Server.Return_Exception (Stream, Id,
                                      Complex_Defs.Exception_Number.Overflow);
      WHEN Complex_Service.Underflow =>
         Rpc_Server.Return_Exception (Stream, Id,
                                      Complex_Defs.Exception_Number.Underflow);
   END Process_Call;

   PROCEDURE Serve_Gets IS NEW Rpc_Server.Serve
                                  (Program => Complex_Defs.Program,
                                   Supported => (0, Rpc.Version_Number'Last),
                                   Process_Call => Process_Call);
   PROCEDURE Serve (Connection : Transport.Connection_Id) IS
   BEGIN
      Serve_Gets (Connection);
   END Serve;
END Complex_Server;

    nblk1=8
    nid=0
    hdr6=10
        [0x00] rec0=1a rec1=00 rec2=01 rec3=062
        [0x01] rec0=00 rec1=00 rec2=08 rec3=004
        [0x02] rec0=18 rec1=00 rec2=02 rec3=062
        [0x03] rec0=01 rec1=00 rec2=07 rec3=018
        [0x04] rec0=18 rec1=00 rec2=03 rec3=00e
        [0x05] rec0=00 rec1=00 rec2=06 rec3=00a
        [0x06] rec0=18 rec1=00 rec2=04 rec3=030
        [0x07] rec0=0e rec1=00 rec2=05 rec3=000
    tail 0x21509662a8216417cc8a3 0x489e0066482863c01