DataMuseum.dk

top - download

    Length: 2562 (0xa02)
    Types: TextFile
    Names: »B«

└─⟦afbc8121e⟧ Bits:30000532 8mm tape, Rational 1000, MC68020_OS2000 7_2_2
    └─ ⟦77aa8350c⟧ »DATA« 
        └─⟦f794ecd1d⟧ 
            └─⟦this⟧ 

TextFile

with Log;
with Profile;
with Simple_Status;
with Os2000_Transfer;
with Os2000_Transfer_Utilities;

with Directory_Tools;

procedure Os2000_Put (From_Local_File : String := "<IMAGE>";
                      To_Remote_File : String := "";
                      Remote_Machine : String := "<DEFAULT>";
                      Remote_Directory : String := "<DEFAULT>";
                      Transliterate : Boolean := False;
                      Response : String := "<PROFILE>") is

    package Util renames Os2000_Transfer_Utilities;
    package Dir renames Directory_Tools;
    package Naming renames Dir.Naming;

    Handle : Dir.Object.Handle;

    Rspns : Profile.Response_Profile;
    Status : Simple_Status.Condition;

    Transfer_Type : Os2000_Transfer_Utilities.Transfer_Type;

    function Local_Path (File : String) return String is
    begin
        return Naming.Unique_Full_Name (Naming.Resolution (File));
    end Local_Path;

begin
    Profile.Convert (Response, Rspns, Status);
    if not Simple_Status.Error (Status) then
        Log.Put_Line
           ("[Os2000_Put (""" & From_Local_File & """, """ &
            To_Remote_File & """, """ & Remote_Machine & """, """ &
            Remote_Directory & """, " & Boolean'Image (Transliterate) & ", " &
            Profile.Error_Reaction'Image (Profile.Reaction (Rspns)) & ");]",
            Kind => Profile.Auxiliary_Msg,
            Response => Rspns);

        Handle := Naming.Resolution (From_Local_File);

        if Dir.Object.Is_Ok (Handle) then

            if Transliterate then
                Transfer_Type := Util.Put_File;
            else
                Transfer_Type := Util.Put_Exe;
            end if;

            Os2000_Transfer (Local_File => Local_Path (From_Local_File),
                             Remote_File => Util.Remote_Path
                                               (To_Remote_File,
                                                Remote_Directory, Rspns),
                             Transliterate => Transliterate,
                             Transfer_Type => Transfer_Type,
                             Remote_Machine => Remote_Machine,
                             Response => Rspns);
        else
            Log.Put_Line (Dir.Object.Message (Handle),
                          Kind => Profile.Error_Msg,
                          Response => Rspns);
            if Profile.Propagate (Rspns) then
                raise Profile.Error;
            end if;
        end if;
    else
        Log.Put_Condition (Status);
    end if;
end Os2000_Put;
pragma Main;