DataMuseum.dk

top - metrics - download

    Length: 5915 (0x171b)
    Types: TextFile
    Names: »B«

└─⟦85b835f43⟧ Bits:30000549 8mm tape, Rational 1000, Xlib rev 6.00
    └─⟦0c20f784e⟧ »DATA« 
        └─⟦1abbe589f⟧ 
            └─⟦059497ac5⟧ 
                └─⟦this⟧ 

TextFile

with Xlbt_Arithmetic;  
use Xlbt_Arithmetic;  
with Xlbt_Basic;  
use Xlbt_Basic;  
with Xlbt_Reply;  
use Xlbt_Reply;  
with Xlbt_Request;  
use Xlbt_Request;  
with Xlbt_Screen_Saver;  
use Xlbt_Screen_Saver;

with Xlbip_Get_Reply;  
use Xlbip_Get_Reply;  
with Xlbip_Internal;  
use Xlbip_Internal;  
with Xlbip_Put_Request;  
use Xlbip_Put_Request;

package body Xlbp_Screen_Saver is
------------------------------------------------------------------------------
-- X Library Screen Saver
--
-- Xlbp_Screen_Saver - Control of the server Screen-Saver facility
------------------------------------------------------------------------------
-- Copyright 1989 - 1991 by Rational, Santa Clara, California.
-- Copyright 1985 - 1989 by the Massachusetts Institute of Technology
--
--                  All Rights Reserved.
--
-- Permission to use, copy, modify, and distribute this software and its
-- documentation for any purpose and without fee is hereby granted,
-- provided that the above copyright notice(s) appear in all copies and that
-- both that copyright notice(s) and this permission notice appear in
-- supporting documentation, and that the names of MIT or Rational not be
-- used in advertising or publicity pertaining to distribution of the software
-- without specific, written prior permission.
--
-- MIT and Rational disclaim all warranties with regard to this software,
-- including all implied warranties of merchantability and fitness, in no
-- event shall MIT or Rational be liable for any special, indirect or
-- consequential damages or any damages whatsoever resulting from loss of use,
-- data or profits, whether in an action of contract, negligence or other
-- tortious action, arising out of or in connection with the use or performance
-- of this software.
------------------------------------------------------------------------------

--\f

    procedure X_Activate_Screen_Saver (Display : X_Display) is  
    begin  
        X_Force_Screen_Saver (Display, Screen_Saver_Active);  
    end X_Activate_Screen_Saver;

--\f

    procedure X_Reset_Screen_Saver (Display : X_Display) is  
    begin  
        X_Force_Screen_Saver (Display, Screen_Saver_Reset);  
    end X_Reset_Screen_Saver;

--\f

    procedure X_Force_Screen_Saver (Display : X_Display;  
                                    Mode    : X_Screen_Saver_Mode) is  
    begin

        Lock_Display (Display);  
        begin  
            Put_X_Force_Screen_Saver_Request  
               (Display, (Kind   => Force_Screen_Saver,  
                          Length => X_Force_Screen_Saver_Request'Size / 32,  
                          Mode   => Mode));  
        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;  
        Unlock_Display (Display);  
        Sync_Handle (Display);

    end X_Force_Screen_Saver;

--\f

    procedure X_Get_Screen_Saver  
                 (Display         :     X_Display;  
                  Timeout         : out U_Short;  
                  Interval        : out U_Short;  
                  Prefer_Blanking : out X_Screen_Saver_Blanking;  
                  Allow_Exposures : out X_Screen_Saver_Exposures) is  
        Rep  : X_Reply_Contents;  
        Succ : X_Status;  
    begin

----Lock the display.

        Lock_Display (Display);  
        begin

----Send the request.

            Put_X_Get_Screen_Saver_Request  
               (Display, (Kind   => Get_Screen_Saver,  
                          Length => X_Get_Screen_Saver_Request'Size / 32,  
                          Pad    => 0));

----Read the reply.

            Get_Reply (Display => Display,  
                       Code    => Get_Screen_Saver,  
                       Reply   => Rep,  
                       Extra   => 0,  
                       Discard => True,  
                       Status  => Succ);  
            if Succ /= Failed then  
                Timeout         := Rep.Get_Screen_Saver.Timeout;  
                Interval        := Rep.Get_Screen_Saver.Interval;  
                Prefer_Blanking := Rep.Get_Screen_Saver.Prefer_Blanking;  
                Allow_Exposures := Rep.Get_Screen_Saver.Allow_Exposures;  
            else  
                Timeout         := 0;  
                Interval        := 0;  
                Prefer_Blanking := None_X_Screen_Saver_Blanking;  
                Allow_Exposures := None_X_Screen_Saver_Exposures;  
            end if;

----Catch exceptions.

        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;

----Unlock; sync; return.

        Unlock_Display (Display);  
        Sync_Handle (Display);

    end X_Get_Screen_Saver;

--\f

    procedure X_Set_Screen_Saver (Display         : X_Display;  
                                  Timeout         : U_Short;  
                                  Interval        : U_Short;  
                                  Prefer_Blanking : X_Screen_Saver_Blanking;  
                                  Allow_Exposures : X_Screen_Saver_Exposures) is  
    begin

        Lock_Display (Display);  
        begin  
            Put_X_Set_Screen_Saver_Request  
               (Display, (Kind         => Set_Screen_Saver,  
                          Length       => X_Set_Screen_Saver_Request'Size / 32,  
                          Pad          => 0,  
                          Pad2         => 0,  
                          Timeout      => Timeout,  
                          Interval     => Interval,  
                          Prefer_Blank => Prefer_Blanking,  
                          Allow_Expose => Allow_Exposures));  
        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;  
        Unlock_Display (Display);  
        Sync_Handle (Display);

    end X_Set_Screen_Saver;

--\f

end Xlbp_Screen_Saver;