DataMuseum.dk

top - download

    Length: 2836 (0xb14)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Message;
with Class_Printer;
with Unary;
with Bounded_String;

package body More_Binary is

    type Node_Structure is
        record
            Rule : Natural range 0 .. 1 := 0;
            Unar : Unary.Node := Unary.Empty_Node;
            More : More_Binary.Node := More_Binary.Empty_Node;
            Mess : Message.Binary;
            Line : Object.Index := Scanner.Get_Line_Number;
        end record;

    procedure Parse (N : in out Node) is
        use Scanner;
    begin  
        N := new Node_Structure;
        N.Rule := 0;
        Message.Put (Scanner.Get_Value, N.Mess);
        Scanner.Next;
        Unary.Parse (N.Unar);
        if Scanner.Get_Token = Scanner.Binary then
            N.Rule := 1;
            More_Binary.Parse (N.More);
        end if;
    end Parse;

    function Is_First (T : Scanner.Token) return Boolean is
        use Scanner;
    begin
        return T = Scanner.Binary;
    end Is_First;

    procedure Unparse (N : Node) is

        type E_Message is (Plus, Moins, Mul, Div, Egal, Diff, Sup,
                           Sup_Egal, Inf, Inf_Egal, Et, Ou, Eou);

        Token : E_Message;

    begin
        Token := E_Message'Value (Bounded_String.Image (Message.Get (N.Mess)));
        case Token is
            when Plus =>
                Class_Printer.Put (" + ");
            when Moins =>
                Class_Printer.Put (" - ");
            when Mul =>
                Class_Printer.Put (" * ");
            when Div =>
                Class_Printer.Put (" / ");
            when Egal =>
                Class_Printer.Put (" = ");
            when Diff =>
                Class_Printer.Put (" <> ");
            when Sup =>
                Class_Printer.Put (" > ");
            when Sup_Egal =>
                Class_Printer.Put (" >= ");
            when Inf =>
                Class_Printer.Put (" < ");
            when Inf_Egal =>
                Class_Printer.Put (" <= ");
            when Et =>
                Class_Printer.Put (" & ");
            when Ou =>
                Class_Printer.Put (" | ");
            when Eou =>
                Class_Printer.Put (" # ");
        end case;
        Unary.Unparse (N.Unar);
        if N.Rule = 1 then
            More_Binary.Unparse (N.More);
        end if;
    end Unparse;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin
        Scanner.Put_Line_Number (N.Line);
        Result := Unary.Interpret (N.Unar);
        Message.Put (Result, N.Mess);
        Result := Message.Send (N.Mess, Inherited);
        if N.Rule = 1 then
            Result := More_Binary.Interpret (N.More, Result);
        end if;
        return Result;
    end Interpret;

end More_Binary;