DataMuseum.dk

top - download

    Length: 4863 (0x12ff)
    Types: TextFile
    Names: »V«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 
└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦e24fb53b7⟧ 
            └─⟦this⟧ 

TextFile

with Constant_String;  
with Fact_Reference;
with Output_Stream;
package Slot is

    type Types is (Integer, Boolean, Float, Character, Duration,
                   String, Enumeration, Reference, Undefined);

    type Object (Kind : Types := Integer) is private;

    Null_Object : constant Object;
    False, True : constant Object;

    function Value (I : Standard.Integer)   return Object;
    function Value (B : Standard.Boolean)   return Object;
    function Value (F : Standard.Float)     return Object;
    function Value (C : Standard.Character) return Object;
    function Value (D : Standard.Duration)  return Object;
    function Value (S : Standard.String)    return Object;

    function Get (The_Object : Object) return Standard.Integer;
    function Get (The_Object : Object) return Standard.Boolean;
    function Get (The_Object : Object) return Standard.Float;
    function Get (The_Object : Object) return Standard.Character;
    function Get (The_Object : Object) return Standard.Duration;
    function Get (The_Object : Object) return Standard.String;

    procedure Set (The_Object : in out Object; To : Standard.Integer);
    procedure Set (The_Object : in out Object; To : Standard.Boolean);
    procedure Set (The_Object : in out Object; To : Standard.Float);
    procedure Set (The_Object : in out Object; To : Standard.Character);
    procedure Set (The_Object : in out Object; To : Standard.Duration);
    procedure Set (The_Object : in out Object; To : Standard.String);

    function  Undefined_Value                      return Object;
    function  Is_Undefined   (The_Object : Object) return Standard.Boolean;
    procedure Make_Undefined (The_Object : in out Object);

    function Is_A_Reference (The_Object : Object) return Standard.Boolean;
    function Reference_Value
                (The_Reference : Fact_Reference.Object) return Object;
    function Get_Reference  (From_Object : Object) return Fact_Reference.Object;

    function Have_Same_Type (Left, Right : Object) return Standard.Boolean;

    procedure Put (The_Object : Object; Where : Output_Stream.Object);

    package Operators is

        function "="  (Left, Right : Object) return Standard.Boolean
            renames Slot."=";
        function "<"  (Left, Right : Object) return Standard.Boolean;
        function "<=" (Left, Right : Object) return Standard.Boolean;
        function ">"  (Left, Right : Object) return Standard.Boolean;
        function ">=" (Left, Right : Object) return Standard.Boolean;

        function "+" (Left, Right : Object) return Object;
        function "-" (Left, Right : Object) return Object;
        function "*" (Left, Right : Object) return Object;
        function "/" (Left, Right : Object) return Object;

        function "&" (Left, Right : Object) return Object;

        function "-"   (Right : Object) return Object;
        function "abs" (Right : Object) return Object;
    end Operators;

    generic
        type Enumeration_Values is (<>);
    package Enumeration_Facilities is

        function Value (Enumeration_Value : Enumeration_Values) return Object;
        function Get   (The_Object : Object) return Enumeration_Values;

        procedure Set (The_Object : in out Object; To : Enumeration_Values);
        procedure Put (The_Object : Object; Where : Output_Stream.Object);

    end Enumeration_Facilities;

    Illegal_Operation : exception;
    Typing_Error      : exception;

private
    type Object (Kind : Types := Integer) is
        record
            case Kind is
                when Integer =>
                    The_Integer : Standard.Integer := 0;
                when Float =>
                    The_Float : Standard.Float := 0.0;
                when Boolean =>
                    The_Boolean : Standard.Boolean := Standard.False;
                when Character =>
                    The_Character : Standard.Character := Ascii.Nul;
                when Duration =>
                    The_Duration : Standard.Duration := 0.0;
                when String =>
                    The_String : Constant_String.Object :=
                       Constant_String.Null_Object;
                when Enumeration =>
                    The_Enumeration : Standard.Integer := 0;  
                when Reference =>
                    The_Reference : Fact_Reference.Object :=
                       Fact_Reference.Null_Object;
                when Undefined =>
                    null;
            end case;
        end record;

    Null_Object : constant Slot.Object := (Kind => Undefined);
    False       : constant Slot.Object := (Kind        => Boolean,  
                                           The_Boolean => Standard.False);
    True        : constant Slot.Object := (Kind        => Boolean,  
                                           The_Boolean => Standard.True);
end Slot;