DataMuseum.dk

top - download

    Length: 3507 (0xdb3)
    Types: TextFile
    Names: »V«

└─⟦5f3412b64⟧ Bits:30000745 8mm tape, Rational 1000, ENVIRONMENT 12_6_5 TOOLS 
    └─ ⟦91c658230⟧ »DATA« 
        └─⟦458657fb6⟧ 
            └─⟦a5bbbb819⟧ 
                └─⟦this⟧ 
└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─ ⟦fc9b38f02⟧ »DATA« 
        └─⟦9b46a407a⟧ 
            └─⟦eec0a994f⟧ 
                └─⟦this⟧ 

TextFile

with Rpc;  
with Transport_Defs;  
with Transport_Stream;

package Rpc_Client is

    generic  
        Default_Network : Transport_Defs.Network_Name;  
        Default_Host : Transport_Defs.Host_Id;  
        Default_Socket : Transport_Defs.Socket_Id;  
        Default_Program : Rpc.Program_Number;  
        Default_Version : Rpc.Version_Number;

    procedure Start_Request_Generic  
                 (Stream : out Transport_Stream.Stream_Id;  
                  Proc : Rpc.Procedure_Number;  
                  Network : Transport_Defs.Network_Name := Default_Network;  
                  Host : Transport_Defs.Host_Id := Default_Host;  
                  Socket : Transport_Defs.Socket_Id := Default_Socket;  
                  Program : Rpc.Program_Number := Default_Program;  
                  Version : Rpc.Version_Number := Default_Version);

    -- Allocate a stream from the pool.  Transmit a call message
    -- header with the given program, version, and proc values.


    -- The following procedure is defunct: it is here for
    -- backward-compatibility.  Use the previous procedure.

    generic  
        Pool : in out Transport_Stream.Pool_Id;  
        Program : Rpc.Program_Number;  
        Version : Rpc.Version_Number;

    procedure Begin_Request_Generic (Stream : out Transport_Stream.Stream_Id;  
                                     Proc : Rpc.Procedure_Number);

    -- Allocate a stream from the pool.  Transmit a call message
    -- header with the given program, version, and proc values.


    procedure End_Request (Stream : Transport_Stream.Stream_Id);

    -- Flush the transmit buffer.  Get the response header.
    -- If it is not OK, deallocate the stream.


    procedure End_Response (Stream : Transport_Stream.Stream_Id);

    -- Deallocate the stream.


    generic  
        with procedure Raise_Exception (Excep : Rpc.Exception_Number);

    procedure End_Request_With_Exception  
                 (Stream : Transport_Stream.Stream_Id);

    -- Like End_Request (above), except that it also checks
    -- for a server-defined exception, and, if there is one,
    -- raises it (using the Raise_Exception procedure).


    generic  
        Default_Network : Transport_Defs.Network_Name;  
        Default_Host : Transport_Defs.Host_Id;  
        Default_Socket : Transport_Defs.Socket_Id;  
        Default_Program : Rpc.Program_Number;  
        Default_Version : Rpc.Version_Number;  
        Default_Username : String := "";  
        Default_Password : String := "";

    procedure Start_Request_With_Username  
                 (Stream : out Transport_Stream.Stream_Id;  
                  Proc : Rpc.Procedure_Number;  
                  Network : Transport_Defs.Network_Name := Default_Network;  
                  Host : Transport_Defs.Host_Id := Default_Host;  
                  Socket : Transport_Defs.Socket_Id := Default_Socket;  
                  Program : Rpc.Program_Number := Default_Program;  
                  Version : Rpc.Version_Number := Default_Version;  
                  Username : String := Default_Username;  
                  Password : String := Default_Password);

    -- Like Start_Request_Generic, above, with the addition of
    -- support for passing a username and password to the server.
    -- This is useful when the server must assume an identity in
    -- the access control system of the serving machine.
    -- This feature is supported only in versions 5 and higher
    -- of the RPC protocol.

end Rpc_Client;