DataMuseum.dk

top - metrics - download

    Length: 1222 (0x4c6)
    Types: TextFile
    Names: »checkfonts«

└─⟦6ac9a67ca⟧ Bits:30000548 8mm tape, Rational 1000, access 1_0_1
    └─⟦78f173837⟧ »DATA« 
        └─⟦687a7d38f⟧ 
└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─⟦fc9b38f02⟧ »DATA« 
        └─⟦687a7d38f⟧ 
            └─⟦76eb391d8⟧ 
                └─⟦56d8da70c⟧ 
                    └─⟦this⟧ »bin/checkfonts« 

TextFile

#! /bin/csh -f 

set path=( /bin /usr/ucb $path )

#
getpath:
if (`xlsfonts -display xxxxx |& awk '$1 == "xlsfonts:" {print $2}'` == "Command") then
    echo "Unable to find xlsfonts, please provide the path for xlsfonts."
    echo -n "xlsfonts path:"
    set ANSWER=$<
    set path=( $ANSWER $path )
    goto getpath
endif

set flag = "f"
set Display = ""
foreach f ($argv[*])
    if ($flag == "t") then
       set Display = $f
       break
    endif
    if ("$f" == "-display") set flag = "t"
end

if ($Display != "") setenv DISPLAY $Display

set fonts = `(xlsfonts |& egrep '(xlsfonts:|fixed-screen-|cairo-|icon-|parker-|plunk)')`

if (`echo $fonts | grep 'fixed-screen' | wc -l` == "0" || \
    `echo $fonts | grep 'cairo' | wc -l` == "0" || \
    `echo $fonts | grep 'icon' | wc -l` == "0" || \
    `echo $fonts | grep 'parker' | wc -l` == "0" || \
    `echo $fonts | grep 'plunk' | wc -l` == "0") then
   if (`echo $fonts | grep 'xlsfonts:' | wc -l` == "0") then 
      echo "You do not have visibility to all Rational Access fonts for $DISPLAY"
   else
      echo "checkfonts: Unable to open display $DISPLAY"
      exit 1
   endif
else
    echo "You do have visibility to Rational Access fonts for $DISPLAY"
endif