DataMuseum.dk

top - download

    Length: 1498 (0x5da)
    Types: TextFile
    Names: »B«

└─⟦5f3412b64⟧ Bits:30000745 8mm tape, Rational 1000, ENVIRONMENT 12_6_5 TOOLS 
    └─ ⟦91c658230⟧ »DATA« 
        └─⟦458657fb6⟧ 
            └─⟦1472c4407⟧ 
                └─⟦this⟧ 
└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─ ⟦fc9b38f02⟧ »DATA« 
        └─⟦9b46a407a⟧ 
            └─⟦2e03b931c⟧ 
                └─⟦this⟧ 

TextFile

separate (Generic_Elementary_Functions)

function Kf_Cotcy (X, Cycle : Float_Type) return Float_Type is

-- On input, X is a floating-point value in Float_Type; Cycle is a
-- user specificed period.
-- On output, the value of cot(X*2pi/Cycle) is returned.

   R, Y, Sign_Y, Z, User_Period, P_Lead, P_Trail, K : Common_Float;
   U, V : Common_Float;
   Zero : Common_Float := 0.0;
   I_Flag, Sc_Flag : Quadrant_Flag;
   Two_Pi : constant := 6.28318_53071_79586_47692_52867_66559_00576_8394;

begin

-- Argument reduction by  "rem"

   User_Period := Common_Float (Cycle);

   if User_Period <= 0.0 then
      raise Argument_Error;
   end if;

   if (X = 0.0) then
      raise Constraint_Error;
   end if;

   Y := Common_Float (X);
   if (Y > 0.0) then
      Sign_Y := 1.0;
   else
      Sign_Y := -1.0;
      Y      := abs (Y);
   end if;

   R := Y rem User_Period;

   K      := Round (4.0 * R / User_Period);
   I_Flag := Quadrant_Flag (Integer (K) mod 4);

   Sc_Flag := I_Flag mod 2;

   P_Lead  := Leading_Part (User_Period, 4);
   P_Trail := User_Period - P_Lead;

   K := K * 0.25;

   R := (R - K * P_Lead) - K * P_Trail;
   R := (R / User_Period) * Two_Pi;

   U := Kf_Sin (R, Zero);
   V := Kf_Cos (R, Zero);

   if (Sc_Flag = 1) then
      if (V = 0.0) then
         raise Constraint_Error;
      end if;
      Z := -U / V;
   else
      if (U = 0.0) then
         raise Constraint_Error;
      end if;
      Z := V / U;
   end if;

   return (Float_Type (Sign_Y * Z));

end Kf_Cotcy;