DataMuseum.dk

top - download

    Length: 2283 (0x8eb)
    Types: TextFile
    Names: »B«

└─⟦25882cbde⟧ Bits:30000536 8mm tape, Rational 1000, RCI_RS6000_AIX_IBM 2_0_2
    └─ ⟦b8efda8ac⟧ »DATA« 
        └─⟦7061b4ee8⟧ 
            └─⟦this⟧ 

TextFile

separate (Batch_Extensions_Support)
procedure Generate_Link_Commands (Compilation_Script_File : Io.File_Type;
                                  Host_Units : Dt.Object.Iterator;
                                  Target_Key : String;
                                  Status : in out Simple_Status.Condition) is
    Host_Units_Iter : Dt.Object.Iterator := Host_Units;
    Current_Object : Directory.Object;
    Has_Secondary : Boolean := False;
    Error_Status : Directory.Error_Status;
begin  
    Dt.Object.Reset (Host_Units_Iter);
    -- Reset the iterator

    while not Dt.Object.Done (Host_Units_Iter) loop
        -- First generate all secondary commands for the host units

        Dt.Object.Low_Level.Get_Object
           (Dt.Object.Value (Host_Units_Iter), Current_Object, Error_Status);
        -- Convert current handle to a directorty object

        if Directory."/=" (Error_Status, Directory.Successful) then
            Log.Put_Line ("Error in getting object from its handle",
                          Profile.Error_Msg);
            return;
        end if;


        if Is_Main_Program (Current_Object) then
            -- Generate link commands only for main units

            Log.Put_Line ("Generating link commands for " &
                          Naming.Unique_Full_Name (Current_Object),
                          Profile.Note_Msg);

            Generate_Context_Change_Command
               (Compilation_Script_File, Current_Object, Target_Key, Status);
            -- Set remote context to the unit's remote directory

            if Simple_Status.Error (Status) then
                return;
            end if;

            Bi.Generate_Link_Commands (Compilation_Script_File, Current_Object,
                                       Target_Key, Status, Profile.Get);

            if Simple_Status.Error (Status) then
                Log.Put_Line ("Error while generating link commands for " &
                              Naming.Unique_Full_Name (Current_Object),
                              Profile.Error_Msg);
                return;
            end if;  
        end if;
        Dt.Object.Next (Host_Units_Iter);
    end loop;
exception
    when others =>
        Unhandled_Exception (Status, "generate_link_commands");

end Generate_Link_Commands;