DataMuseum.dk

top - download

    Length: 5629 (0x15fd)
    Types: TextFile
    Names: »DEMO_TINY_TALK«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

-- This file was created by Tiny_Talk Unparse
-- Copyright G.BRENET / S.FLON

POUR Spirale PRENDRE {
    AVEC Coordx:X Coordy:Y Pas:N Angle:Theta .
    Tortue Levetaplume .
    Tortue Vaenx:X Y:Y .
    Tortue Baissetaplume .
    1 A:N Repeter:{
        AVEC L .
        Tortue Avance:L .
        Tortue Agauche:Theta .
        } .
    } .
POUR Tube PRENDRE {
    AVEC X:X Y:Y Taille:T Profondeur:P .
    P <= 0 Sifaux:{
        Tortue Tonx:X Tony:Y .
        Polygone Cotes:8 Longueur:T .
        Tube X:X - 1 Y:Y - 2 Taille:T - 1 Profondeur:P - 1 .
        } .
    } .
POUR Polygone PRENDRE {
    AVEC Cotes:N Longueur:L .
    POUR Angle PRENDRE 360 / N .
    Tortue Baissetaplume .
    N Fois:{
        Tortue Avance:L .
        Tortue Agauche:Angle .
        } .
    } .
POUR Etoile PRENDRE {
    AVEC Arete:Longueur .
    Tortue Adroite:90 .
    8 Fois:{
        Tortue Agauche:135 .
        Tortue Avance:Longueur .
        Tortue Adroite:90 .
        Tortue Avance:Longueur .
        } .
    } .
POUR Europe PRENDRE {
    AVEC Coordx:X Coordy:Y .
    Tortue Levetaplume .
    Tortue Tonangle:0 .
    Tortue Vaenx:X Y:Y .
    1 A:12 Repeter:{
        AVEC I .
        Tortue Levetaplume .
        Tortue Avance:40 .
        Tortue Baissetaplume .
        Etoile Arete:8 .
        Tortue Tonangle:I * 30 .
        } .
    } .
POUR Factorielle PRENDRE {
    AVEC De:N .
    N < 1 Sifaux:{
        RENVOYER N * ( Factorielle De:N - 1 ) } Sivrai:{
        RENVOYER 1 } .
    } .
POUR Nuit_Etoilee PRENDRE {
    AVEC Nb_Etoiles:N Coord_X:X Limit_X:Lx Coord_Y:Y Limit_Y:Ly Taille_Plume:P Taille_Arete:A .
    1 A:N Repeter:{
        AVEC I .
        Tortue Tataille:( P Auhasard ) + 1 .
        Tortue Levetaplume .
        Tortue Vaenx:X + Lx Auhasard Y:Y + Ly Auhasard .
        Tortue Baissetaplume .
        Etoile Arete:A Auhasard + 1 .
        } .
    Tortue Tataille:1 .
    } .
POUR Axes PRENDRE {
    AVEC Origine_X:X Origine_Y:Y Pas:P Nb_Pas_X:Nbx Nb_Pas_Y:Nby .
    POUR Premiere_Tortue PRENDRE Tortue Copietoi .
    POUR Seconde_Tortue PRENDRE Tortue Copietoi .
    Premiere_Tortue Vaenx:X Y:Y .
    Seconde_Tortue Vaenx:X Y:Y .
    Premiere_Tortue Tataille:2 .
    Seconde_Tortue Tataille:2 .
    Seconde_Tortue Tonangle:90 .
    POUR Nb PRENDRE ( Nbx > Nby ) Sivrai:{
        RENVOYER Nbx } Sifaux:{
        RENVOYER Nby } .
    1 A:Nb * 2 Repeter:{
        AVEC I .
        ( I / 2 * 2 = I ) Sivrai:{
            ( I / 2 <= Nbx ) Sivrai:{
                Premiere_Tortue Levetaplume .
                Premiere_Tortue Vaenx:Premiere_Tortue Tonx Y:Premiere_Tortue Tony .
                Premiere_Tortue Baissetaplume .
                Premiere_Tortue Avance:P .
                } .
            } Sifaux:{
            ( I / 2 <= Nby ) Sivrai:{
                Seconde_Tortue Levetaplume .
                Seconde_Tortue Vaenx:Seconde_Tortue Tonx Y:Seconde_Tortue Tony .
                Seconde_Tortue Baissetaplume .
                Seconde_Tortue Avance:P .
                } .
            } .
        } .
    Premiere_Tortue Tataille:1 .
    Seconde_Tortue Tataille:1 .
    } .
POUR Spectre PRENDRE {
    AVEC Origine_X:X Origine_Y:Y Hauteur:H Pas:P Largeur:L .
    Tortue Tonangle:270 .
    0 A:L Repeter:{
        AVEC I .
        Tortue Levetaplume .
        POUR Random PRENDRE H Auhasard .
        Tortue Vaenx:X + ( I * P ) Y:Y - ( H / 2 ) - ( Random / 2 ) .
        Tortue Baissetaplume .
        Tortue Avance:Random .
        } .
    } .
POUR Ligne_Brisee PRENDRE {
    AVEC Nb_Cassures:C Sens:S Taille_Cassure:T .
    1 A:5 Auhasard + C Repeter:{
        Tortue Agauche:5 Auhasard + 85 Avance:5 Auhasard + T Adroite:5 Auhasard + 175 .
        Tortue Tonangle:S .
        } .
    } .
POUR Montagnes_Russes PRENDRE {
    AVEC Coord_X:X Coord_Y:Y Nb_Pics:P Nb_Cassures:C Compression:Co .
    Tortue Levetaplume .
    Tortue Vaenx:X Y:Y .
    Tortue Baissetaplume .
    1 A:P Repeter:{
        Ligne_Brisee Nb_Cassures:C Sens:0 - Co Taille_Cassure:15 .
        Tortue Tonangle:0 .
        Ligne_Brisee Nb_Cassures:C Sens:180 + Co Taille_Cassure:15 .
        } .
    } .
Stylo Largeplume .
Stylo Tonx:225 Tony:30 Ecrire:"demonstration tiny talk" Enmajuscule .
Stylo Petiteplume .
Stylo Tonx:590 Tony:48 Ecrire:"copyright g.brenet s.flon" Capitalise .
Axes Origine_X:10 Origine_Y:280 Pas:10 Nb_Pas_X:25 Nb_Pas_Y:20 .
Spectre Origine_X:10 Origine_Y:280 Hauteur:200 Pas:2 Largeur:125 .
Stylo Tonx:100 Tony:320 Ecrire:"Spectre" Capitalise .
Spirale Coordx:400 Coordy:180 Pas:100 Angle:50 .
Stylo Tonx:300 Tony:320 Ecrire:"Spirale pas:100 angle:50" Capitalise .
Spirale Coordx:650 Coordy:180 Pas:160 Angle:88 .
Stylo Tonx:550 Tony:320 Ecrire:"Spirale pas:160 angle:88" Capitalise .
Spirale Coordx:150 Coordy:430 Pas:150 Angle:91 .
Stylo Tonx:50 Tony:550 Ecrire:"Spirale pas:150 angle:91" Capitalise .
Spirale Coordx:400 Coordy:415 Pas:150 Angle:89 .
Stylo Tonx:300 Tony:550 Ecrire:"Spirale pas:150 angle:89" Capitalise .
Montagnes_Russes Coord_X:550 Coord_Y:500 Nb_Pics:9 Nb_Cassures:8 Compression:4 .
Stylo Tonx:590 Tony:550 Ecrire:"affreuuuuuuuux" Capitalise .
Nuit_Etoilee Nb_Etoiles:25 Coord_X:90 Limit_X:130 Coord_Y:585 Limit_Y:130 Taille_Plume:2 Taille_Arete:10 .
Stylo Tonx:70 Tony:750 Ecrire:"nuit blanche !!!" Capitalise .
Tube X:460 Y:700 Taille:30 Profondeur:60 .
Stylo Tonx:400 Tony:750 Ecrire:"Bitube" Capitalise .
Europe Coordx:640 Coordy:730 .
Stylo Tonx:615 Tony:750 Ecrire:"europe valeur" Capitalise .
Stylo Largeplume .
1 A:8 Repeter:{
    AVEC N .
    Stylo Tonx:140 Tony:790 Ecrire:( "factorielle de:" + N Entexte + " donne " ) Capitalise .
    Stylo Ecrire:( Factorielle De:N ) Entexte .
    } .