DataMuseum.dk

top - metrics - download

    Length: 1794 (0x702)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Object;
with Errors;
with Scanner;
with Statements;  
with Trace;
with Unparser;

package body More_Statements is

    type Node_Structure is
        record
            Line : Natural;
            Rule : Natural range 0 .. 1 := 0;
            Stat : Statements.Node := Statements.Empty_Node;
        end record;

    procedure Parse (N : in out Node) is
    begin
        Trace.Display ("parsing More_Statements");
        N := new Node_Structure;
        N.Line := Scanner.Get_Line_Number;
        case Scanner.Get_Token is
            when Scanner.L_Dot =>
                N.Rule := 1;
                Scanner.Next_Token;
                Statements.Parse (N.Stat);
            when Scanner.L_Eof | Scanner.L_Cbra =>
                null;
            when others =>
                raise Errors.Expecting_Dot;
        end case;
    end Parse;

    procedure Unparse (N : Node) is
    begin
        case N.Rule is
            when 0 =>
                null;
            when 1 =>
                Unparser.Put (".");
                Unparser.New_Line;
                Statements.Unparse (N.Stat);
        end case;
        Trace.Display ("fin unparse more_statements");
    end Unparse;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin
        Errors.Save_Interpret_Line (N.Line);
        case N.Rule is
            when 0 =>
                Result := Inherited;
            when 1 =>
                Result := Statements.Interpret (N.Stat, Inherited);
        end case;
        Trace.Display ("fin interpretation More_Statements");
        Trace.Display (Result);
        return Result;
    end Interpret;

end More_Statements;