DataMuseum.dk

top - download

    Length: 2219 (0x8ab)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Errors;
with Expression;
with More_Statements;
with Object;
with Scanner;
with Trace;
with Unparser;

package body Statements is

    type Node_Structure is
        record
            Line : Natural;
            Rule : Natural range 0 .. 2 := 0;
            Expr : Expression.Node := Expression.Empty_Node;
            More : More_Statements.Node := More_Statements.Empty_Node;
        end record;

    procedure Parse (N : in out Node) is
    begin
        Trace.Display ("parsing Statements");
        N := new Node_Structure;
        N.Line := Scanner.Get_Line_Number;
        if Expression.Is_First (Scanner.Get_Token) then
            N.Rule := 1;
            Expression.Parse (N.Expr);
            More_Statements.Parse (N.More);
        else
            case Scanner.Get_Token is
                when Scanner.L_Renv =>
                    N.Rule := 2;
                    Scanner.Next_Token;
                    Expression.Parse (N.Expr);
                when others =>
                    null;
            end case;
        end if;
    end Parse;

    procedure Unparse (N : Node) is
    begin
        case N.Rule is
            when 0 =>
                null;
            when 1 =>
                Expression.Unparse (N.Expr);
                More_Statements.Unparse (N.More);
            when 2 =>
                Unparser.Put ("Renvoyer ");
                Expression.Unparse (N.Expr);
        end case;
        Trace.Display ("fin unparse statements");
    end Unparse;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin
        Errors.Save_Interpret_Line (N.Line);
        case N.Rule is
            when 0 =>
                Result := Inherited;
            when 1 =>
                Result := Expression.Interpret (N.Expr);
                Result := More_Statements.Interpret (N.More, Result);
            when 2 =>
                Result := Expression.Interpret (N.Expr);
        end case;
        Trace.Display ("fin interpretation Statements");
        Trace.Display (Result);
        return Result;
    end Interpret;

end Statements;