DataMuseum.dk

top - download

    Length: 6596 (0x19c4)
    Types: TextFile
    Names: »V«

└─⟦5829e5ed5⟧ Bits:30000534 8mm tape, Rational 1000, RCI 2_0_5
    └─ ⟦c9a165082⟧ »DATA« 
        └─⟦c3895f76e⟧ 
            └─⟦this⟧ 

TextFile

with Directory;
with Ftp_Profile;
with Profile;
with Simple_Status;

package Library_Interface is

    package Naming renames Directory.Naming;

    type String_Result (Size : Natural) is
        record
            Condition : Simple_Status.Condition;
            Result : String (1 .. Size);
        end record;
    Unimplemented : exception;


    --| LIBRARY OPERATIONS |--

    procedure Initialize (View : String := "<CURSOR>";
                          Remote_Machine : String := Ftp_Profile.Remote_Machine;
                          Remote_Directory : String :=
                             Ftp_Profile.Remote_Directory;
                          Remote_Account : String;
                          Remote_Library : String;
                          Condition : in out Simple_Status.Condition;
                          Compiler_Command : String := "<DEFAULT>";
                          Linker_Command : String := "<DEFAULT>";
                          Loader_Command : String := "<DEFAULT>";
                          Compiler_Options : String := "<DEFAULT>";
                          Linker_Options : String := "<DEFAULT>";
                          Echo_Commands : Boolean := True;
                          Response : Profile.Response_Profile := Profile.Get);

    -- Build a State_File in the specified World_Or_View, and in the process,
    -- register all existing units.
    --
    -- If Remote_Machine and Remote_Directory are defaulted, their values will
    -- be taken from the FTP switches.  Subsequent changes to the
    -- Remote_Machine, Remote_Directory or Remote_Library will cause all coded
    -- units in the host view to be demoted to installed.
    --
    -- The Remote_Directory usually refers to the directory to which units are
    -- transferred and the context in which compilation commands are executed.
    -- It is also, normally, the home directory of the remote Program Library
    -- (file or directory), options/configuration files, and compiler and
    -- linker output (errors, listings etc...).
    --
    -- If the @_Commands and @_Options parameters are defaulted, the compiler
    -- defaults will be used.  Command names may be changed in the future by
    -- calls to Set_Command_Names.  Changes to Options, on a library basis, can
    -- be made by updating the options file that is maintained in the state
    -- file directory.  Changes to Options, on a unit basis, can be made by
    -- calls to Change_X_Option.


    procedure Set_Remote_Machine
                 (View : String := "<CURSOR>";
                  Value : String;
                  Condition : in out Simple_Status.Condition;
                  Response : Profile.Response_Profile := Profile.Get);

    -- Change the remote machine associated with the World_Or_View.
    -- This will result in all coded units being installed.


    procedure Set_Remote_Directory
                 (View : String := "<CURSOR>";
                  Value : String;
                  Condition : in out Simple_Status.Condition;
                  Response : Profile.Response_Profile := Profile.Get);

    -- Change the remote directory associated with the World_Or_View.
    -- This will result in all coded units being installed.


    procedure Set_Remote_Library
                 (View : String := "<CURSOR>";
                  Value : String;
                  Condition : in out Simple_Status.Condition;
                  Response : Profile.Response_Profile := Profile.Get);

    -- Change the remote library associated with the World_Or_View.
    -- This will result in all coded units being installed.


    function Remote_Machine (View : String := "<CURSOR>";
                             Response : Profile.Response_Profile := Profile.Get)
                            return String_Result;

    function Remote_Directory
                (View : String := "<CURSOR>";
                 Response : Profile.Response_Profile := Profile.Get)
                return String_Result;

    function Remote_Library (View : String := "<CURSOR>";
                             Response : Profile.Response_Profile := Profile.Get)
                            return String_Result;

    -- Return the Remote_Machine, Remote_Directory or Remote_Library for the
    -- specified World_Or_View.


    procedure Information (View : Directory.Object;
                           Units : Naming.Iterator;  
                           Condition : in out Simple_Status.Condition;
                           Response : Profile.Response_Profile := Profile.Get);

    -- Display remote information about Units in the remote Library.

    function Default_Remote_Machine
                (Potential_View : String;
                 Target_Key : String;
                 Response : Profile.Response_Profile := Profile.Get)
                return String_Result;

    -- Return remote machine name of a view that would be created with
    -- the specified target key.

    function Default_Remote_Directory
                (Potential_View : String;
                 Target_Key : String;
                 Response : Profile.Response_Profile := Profile.Get)
                return String_Result;

    -- Return remote directory name of a view that would be created with
    -- the specified target key.

    procedure Set_Default_Machine
                 (Machine_Name : String;
                  Target_Key : String;
                  Location : String := "<CURSOR>";
                  Use_Enclosing_Source : Boolean := False;
                  Condition : in out Simple_Status.Condition;
                  Response : Profile.Response_Profile := Profile.Get);

    -- Set Rci.<target_key>_default_machine in the switch file associated
    -- with Location.  If Use_Enclosing_Source is true,
    -- then actually set the switch in the nearest enclosing library of
    -- Location that contains a non-empty switch value.
    --

    procedure Set_Default_Roof
                 (Remote_Roof : String;
                  Target_Key : String;
                  Location : String := "<CURSOR>";
                  Use_Enclosing_Source : Boolean := False;
                  Condition : in out Simple_Status.Condition;
                  Response : Profile.Response_Profile := Profile.Get);

    -- Set Rci.<target_key>_Default_Roof in the switch file associated
    -- with Location.  If Use_Enclosing_Source is true,
    -- then actually set the switch in the nearest enclosing library of
    -- Location that contains a non-empty switch value.
    --

    pragma Module_Name (4, 4140);
    pragma Bias_Key (32);
end Library_Interface;