|
DataMuseum.dkPresents historical artifacts from the history of: Rational R1000/400 Tapes |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about Rational R1000/400 Tapes Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - downloadIndex: ┃ T V ┃
Length: 26555 (0x67bb)
Types: TextFile
Names: »V«
└─⟦85b835f43⟧ Bits:30000549 8mm tape, Rational 1000, Xlib rev 6.00
└─ ⟦0c20f784e⟧ »DATA«
└─⟦1abbe589f⟧
└─⟦059497ac5⟧
└─⟦this⟧
with Xlbt_Arithmetic;
use Xlbt_Arithmetic;
with Xlbt_Basic;
use Xlbt_Basic;
with Xlbt_Window;
use Xlbt_Window;
with Xlbt_Visual;
use Xlbt_Visual;
package Xlbp_Window is
------------------------------------------------------------------------------
-- X Library Window Controls
--
-- Xlbp_Window - Control functions for windows.
------------------------------------------------------------------------------
-- Copyright 1989 - 1991 by Rational, Santa Clara, California.
-- Copyright 1985 - 1989 by the Massachusetts Institute of Technology
--
-- All Rights Reserved.
--
-- Permission to use, copy, modify, and distribute this software and its
-- documentation for any purpose and without fee is hereby granted,
-- provided that the above copyright notice(s) appear in all copies and that
-- both that copyright notice(s) and this permission notice appear in
-- supporting documentation, and that the names of MIT or Rational not be
-- used in advertising or publicity pertaining to distribution of the software
-- without specific, written prior permission.
--
-- MIT and Rational disclaim all warranties with regard to this software,
-- including all implied warranties of merchantability and fitness, in no
-- event shall MIT or Rational be liable for any special, indirect or
-- consequential damages or any damages whatsoever resulting from loss of use,
-- data or profits, whether in an action of contract, negligence or other
-- tortious action, arising out of or in connection with the use or performance
-- of this software.
------------------------------------------------------------------------------
--\f
procedure X_Change_Window_Attributes
(Display : X_Display;
Window : X_Window;
Values_Mask : X_New_Window_Attributes;
Values : X_Set_Window_Attributes);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to use.
-- Values_Mask - Specifies the fields within Attributes to be used in
-- making changes to the windows attributes.
-- Values - Specifies the attributes to be changed; only those fields
-- indicated as valid by the Values_Mask need be set.
--
-- Uses the Values as indicated by Values_Mask to make changes in the basic
-- attributes of the indicated window. The contents of the window are not
-- changed. X_Clear_Area can be used to force a redisplay of the window's
-- contents. See the Xlib manual for the extensive details.
------------------------------------------------------------------------------
procedure X_Circulate_Subwindows (Display : X_Display;
Window : X_Window;
Direction : X_Circulate_Place);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be circulated.
-- Direction - Specifies the direction.
--
-- Circulates the subwindow(s) of the specified window in the chosen direction.
-- Raise_Lowest raises the lowest mapped child (if any) that is occluded by
-- another child to the top of the stack.
-- Lower_Highest lowers the highest mapped child (if any) that occludes another
-- child to the bottom of the stack.
------------------------------------------------------------------------------
procedure X_Circulate_Subwindows_Down (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be circulated.
--
-- Just like X_Circulate_Subwindows with Raise_Lowest.
------------------------------------------------------------------------------
procedure X_Circulate_Subwindows_Up (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be circulated.
--
-- Just like X_Circulate_Subwindows with Lower_Highest.
------------------------------------------------------------------------------
procedure X_Configure_Window (Display : X_Display;
Window : X_Window;
Values_Mask : X_Window_Changes_Mask;
Values : X_Window_Changes);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to configure.
-- Values_Mask - Specifies which fields in Changes are to be used.
-- Values - Specifies the configuration changes to be made to the window.
--
-- Uses the values from Values as indicated by flags in Mask to reconfigure
-- a window's size, position, border, and/or stacking order.
------------------------------------------------------------------------------
function X_Create_Simple_Window
(Display : X_Display;
Parent : X_Window;
X : S_Short;
Y : S_Short;
Width : U_Short_Positive;
Height : U_Short_Positive;
Border_Width : U_Short;
Border : X_Pixel;
Background : X_Pixel) return X_Window;
------------------------------------------------------------------------------
-- Display - Specifies the display to use
-- Parent - Specifies the parent window ID.
-- X - Specify the X coordinate.
-- Y - Specify the Y coordinate. These coordinates are the top
-- left outside corner of the created window's borders and are
-- relative to the inside of the parent window's borders.
-- Width - Specify the width of the window.
-- Height - Specify the height of the window. These are the created
-- window's inside dimensions. These dimensions do not
-- include the created window's borders, which are entirely
-- outside of the window. The dimensions must be non-zero.
-- Border_Width - Specifies, in pixels, the width of the created window's
-- border. Must be non-zero for Input_Only windows.
-- Border - Specifies the border pixel value of the window.
-- Background - Specifies the background pixel value of the window.
--
-- Creates and returns an unmapped Input_Output window for the specified
-- parent window. Causes the X server to generate a Create_Notify event.
-- The new window is place on top of the stacking order.
------------------------------------------------------------------------------
function X_Create_Window (Display : X_Display;
Parent : X_Window;
X : S_Short;
Y : S_Short;
Width : U_Short_Positive;
Height : U_Short_Positive;
Border_Width : U_Short;
Depth : U_Char;
Class : X_Window_Class;
Visual : X_Visual;
Values_Mask : X_New_Window_Attributes;
Values : X_Set_Window_Attributes) return X_Window;
------------------------------------------------------------------------------
-- Display - Specifies the display to use
-- Parent - Specifies the parent window ID.
-- X - Specify the X coordinate.
-- Y - Specify the Y coordinate. These coordinates are the top
-- left outside corner of the created window's borders and are
-- relative to the inside of the parent window's borders.
-- Width - Specify the width of the window.
-- Height - Specify the height of the window. These are the created
-- window's inside dimensions. These dimensions do not
-- include the created window's borders, which are entirely
-- outside of the window. The dimensions must be non-zero.
-- Border_Width - Specifies, in pixels, the width of the created window's
-- border. Must be non-zero for Input_Only windows.
-- Depth - Specifies the depth of the new window. A depth of zero
-- for class Input_Output or Copy_From_Parent means the depth
-- is taken from the parent.
-- Class - Specifies the created window's class. A class of
-- Copy_From_Parent means the class is taken from the parent.
-- Visual - Specifies the visual type. A visual of
-- Copy_From_Parent_Class means the visual type is taken from
-- the parent.
-- Values_Mask - Specifies which window attributes are defined in the
-- Attributes argument.
-- Values - Specifies the attributes to be set at creation time. The
-- Values_Mask should have the appropriate bits set to indicate
-- which Attributes have been set in this structure.
--
-- Creates and returns a new unmapped window with the specified characteristics.
-- Causes the X server to generate a Create_Notify event. The new window is
-- place on top of the stacking order.
------------------------------------------------------------------------------
procedure X_Destroy_Subwindows (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be destroyed.
--
-- Destroys all inferior windows of the specified window, in bottom to top
-- stacking order. It causes the X server to generate a Destroy_Notify event
-- for each window. The subwindows should never again be referenced.
------------------------------------------------------------------------------
procedure X_Destroy_Window (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to destroy.
--
-- Destroys the specified window as well as all of its subwindows and causes
-- the X server to generate a Destroy_Notify event for each window. The window
-- should never again be referenced.
------------------------------------------------------------------------------
procedure X_Iconify_Window (Display : X_Display;
Window : X_Window;
Screen : X_Screen_Number;
Status : out X_Status);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to affect.
-- Screen - Specifies the screen
-- Status - Receives Successful if the request has been made; receives
-- Failed if the request could not be made
--
-- Sends an Xa_Wm_Change_State Client_Message event with a format of 32 and a
-- first data element of Iconic_State (as described in section 4.14 of the
-- ICCCM) to the root window of the specified screen. If the window is in
-- its normal state and if the window manager has elected to receive these
-- events then the window should change to the iconic state.
------------------------------------------------------------------------------
procedure X_Lower_Window (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to lower.
--
-- Lowers the specified window to the bottom of the stack so that it does not
-- obscure any sibling windows.
------------------------------------------------------------------------------
procedure X_Map_Raised (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to map and raise.
--
-- Just like X_Map_Window except that it also raises the window to the top of
-- the window stack.
------------------------------------------------------------------------------
procedure X_Map_Subwindows (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be mapped.
--
-- Maps all subwindows for a specified window in top-to-bottom stacking order.
-- The X server generates an Expose event on each newly displayed window.
------------------------------------------------------------------------------
procedure X_Map_Window (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to map.
--
-- Maps the window and all of its subwindows which have had previous map
-- requests. A subwindow will appear on the screen as long as all of its
-- ancestors are mapped and not obscured by a sibling or are not clipped by
-- and ancestor.
------------------------------------------------------------------------------
procedure X_Move_Resize_Window (Display : X_Display;
Window : X_Window;
X : S_Short;
Y : S_Short;
Width : U_Short_Positive;
Height : U_Short_Positive);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to resize.
-- X - Specifies the new X coordinate.
-- Y - Specifies the new Y coordinate. These coordinates define the new
-- location of the top left pixel of the window's border or of the
-- window itself if it has no border.
-- Width - Specifies the new width, in pixels.
-- Height - Specifies the new height, in pixels.
--
-- Changes the size and location of the specified window without raising it.
-- Moving and resizing a window may generate an Expose event on the window.
------------------------------------------------------------------------------
procedure X_Move_Window (Display : X_Display;
Window : X_Window;
X : S_Short;
Y : S_Short);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to move.
-- X - Specifies the new X coordinate.
-- Y - Specifies the new Y coordinate. These coordinates define the new
-- location of the top left pixel of the window's border or of the
-- window itself if it has no border.
--
-- Moves the specified window to the indicated X and Y coordinates. Does not
-- change the size, does not raise the window, and does not change the
-- mapping state of the window. Moving a window may or may not lose the
-- contents and cause Expose events.
------------------------------------------------------------------------------
procedure X_Raise_Window (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to raise.
--
-- Raises the specified window to the top of the stack so that no sibling
-- window obscures it. May generate Expose events on this window and its
-- mapped subwindows.
------------------------------------------------------------------------------
procedure X_Reconfigure_Wm_Window (Display : X_Display;
Window : X_Window;
Screen : X_Screen_Number;
Values_Mask : X_Window_Changes_Mask;
Values : X_Window_Changes;
Status : out X_Status);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to affect.
-- Screen - Specifies the screen of the window.
-- Values_Mask - Specifies the values within the Values record.
-- Values - Specifies the values to change for the window.
-- Status - Receives Successful if we made the request or Failed if we
-- could not make it for some reason.
--
-- Issues a Configure_Window request on the specified top-level window. If
-- the stacking mode is changed and the request fails with a Bad_Match error
-- then the error event is trapped and a synthetic Configure_Request_Event
-- containing the same configuration parameters is sent to the root of the
-- specified window. Window managers may elect to receive this event and treat
-- it as a request to reconfigure the window.
------------------------------------------------------------------------------
procedure X_Reparent_Window (Display : X_Display;
Window : X_Window;
Parent : X_Window;
X : S_Short;
Y : S_Short);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to reparent.
-- Parent - Specifies the new parent window.
-- X - Specifies the X coordinate relative to the parent for the window.
-- Y - Specifies the Y coordinate relative to the parent for the window.
--
-- Reparents the specified window by inserting it as the child of the
-- specified parent.
------------------------------------------------------------------------------
procedure X_Resize_Window (Display : X_Display;
Window : X_Window;
Width : U_Short_Positive;
Height : U_Short_Positive);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to resize.
-- Width - Specifies the new width, in pixels.
-- Height - Specifies the new height, in pixels.
--
-- Changes the inside dimensions of the specified window, not including its
-- borders. This function does not change the window's upper-left coordinate
-- or the origin and does not raise the window. Changing the size may lose
-- the contents of the window and may cause an Expose event.
------------------------------------------------------------------------------
procedure X_Restack_Windows (Display : X_Display;
Windows : X_Window_Array);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Windows - Specifies the windows to be restacked. All of these windows
-- must have the same parent.
--
-- Restacks the windows in the order specified, from top to bottom. The
-- stacking order of the first window in the windows array will be unaffected,
-- but the other windows in the array will be stacked underneath the first
-- window in the order of their appearance in the array. The stacking order
-- of windows not appearing in the array are unaffected.
------------------------------------------------------------------------------
procedure X_Set_Window_Background (Display : X_Display;
Window : X_Window;
Pixel : X_Pixel);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to use.
-- Pixel - Specifies the new background pixel value.
--
-- Sets the background pixel of the window. This does not change the contents
-- of the window; use X_Clear_Area to cause the window to be redrawn.
------------------------------------------------------------------------------
procedure X_Set_Window_Background_Pixmap (Display : X_Display;
Window : X_Window;
Pixmap : X_Pixmap);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to use.
-- Pixmap - Specifies the new background pixmap value.
--
-- Sets the background pixmap of the window. If no background pixmap is
-- specified then the background pixmap of the parent is used. On the root
-- window the default background will be restored. The pixmap can be
-- immediately freed if no further explicit references to it are to be made.
-- This can not be performed on an Input_Only window. This does not change
-- the contents of the window; use X_Clear_Area to cause the window to be
-- redrawn.
------------------------------------------------------------------------------
procedure X_Set_Window_Border (Display : X_Display;
Window : X_Window;
Pixel : X_Pixel);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to use.
-- Pixel - Specifies the new border pixel.
--
-- Sets the border pixel of the window. It uses this value as an entry in the
-- color map to determine which color is to be used to paint the border. This
-- change takes immediate effect and the border is redrawn (if necessary).
------------------------------------------------------------------------------
procedure X_Set_Window_Border_Pixmap (Display : X_Display;
Window : X_Window;
Pixmap : X_Pixmap);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to use.
-- Pixmap - Specifies the new border pixmap value.
--
-- Sets the border pixmap of the window. If no background pixmap is
-- specified then the background pixmap of the parent is used. On the root
-- window the default background will be restored. The pixmap can be
-- immediately freed if no further explicit references to it are to be made.
-- This can not be performed on an Input_Only window. This change takes
-- immediate effect and the border is redrawn (if necessary).
------------------------------------------------------------------------------
procedure X_Set_Window_Border_Width (Display : X_Display;
Window : X_Window;
Width : U_Short);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to set.
-- Width - Specifies the width of the window border, in pixels.
--
-- Sets the specified window's border width to the specified width.
------------------------------------------------------------------------------
procedure X_Unmap_Subwindows (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window whose subwindows are to be unmapped.
--
-- Unmaps all subwindows for the specified window in bottom to top stacking
-- order. Causes the X server to generate an Unmap_Notify event for each
-- window unmapped. Has no effect if there are no mapped subwindows.
------------------------------------------------------------------------------
procedure X_Unmap_Window (Display : X_Display;
Window : X_Window);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to unmap.
--
-- Unmaps the specified window and causes the X server to generate an
-- Unmap_Notify event. Has not effect if the window is already unmapped.
------------------------------------------------------------------------------
procedure X_Withdraw_Window (Display : X_Display;
Window : X_Window;
Screen : X_Screen_Number;
Status : out X_Status);
------------------------------------------------------------------------------
-- Display - Specifies the display to use.
-- Window - Specifies the window to affect.
-- Screen - Specifies the screen
-- Status - Receives Successful if the request has been made; receives
-- Failed if the request could not be made
--
-- Unmaps the specified window and sends a synthetic Unmap_Notify event to
-- the root window of the specified screen. If the window has elected to
-- receive these events then the window should change to the withdraw state
-- where neither the window nor its icon are visible.
------------------------------------------------------------------------------
--\f
end Xlbp_Window;