DataMuseum.dk

top - metrics - download

    Length: 1232 (0x4d0)
    Types: TextFile
    Names: »B«

└─⟦5f3412b64⟧ Bits:30000745 8mm tape, Rational 1000, ENVIRONMENT 12_6_5 TOOLS 
    └─⟦91c658230⟧ »DATA« 
        └─⟦458657fb6⟧ 
            └─⟦1472c4407⟧ 
                └─⟦this⟧ 
└─⟦d10a02448⟧ Bits:30000409 8mm tape, Rational 1000, ENVIRONMENT, D_12_7_3
    └─⟦fc9b38f02⟧ »DATA« 
        └─⟦9b46a407a⟧ 
            └─⟦2e03b931c⟧ 
                └─⟦this⟧ 

TextFile

separate (Generic_Elementary_Functions)

function Kf_Asncy (X, Cycle : Float_Type) return Float_Type is

   Y, Sign_X, U, V, One_M_Y, Z1, Z2, Result, Cy : Common_Float;

   Zero : constant := 0.0;
   One  : constant := 1.0;
   Two  : constant := 2.0;
   Four : constant := 4.0;
   Half : constant := 0.5;

   Two_Pi_Inv : constant := 0.15915_49430_91895_33576_88837_63372_51436_2034;

begin

-- Filter out exceptional cases.
   Cy := Common_Float (Cycle);
   if Cy <= 0.0 then
      raise Argument_Error;
   end if;

   Y      := Common_Float (X);
   Sign_X := Copy_Sign (One, Y);
   Y      := abs (Y);

   if Y > One then
      raise Argument_Error;
   end if;

   if Y = One then
      Result := Cy / Four;
      return (Float_Type (Copy_Sign (Result, Sign_X)));
   end if;

   V := Y;
   if Y < Half then
      U := One - Y * Y;
   else
      One_M_Y := Half + (Half - Y);
      U       := Two * One_M_Y - One_M_Y * One_M_Y;
   end if;

   U := Kf_Sqrt (U);

   if U >= V then
      Kp_Atn (V, U, Z1, Z2);
      Result := ((Z1 + Z2) * Two_Pi_Inv) * Cy;
   else
      Kp_Atn (U, V, Z1, Z2);
      Result := Cy * 0.25 - ((Z1 + Z2) * Two_Pi_Inv) * Cy;
   end if;

   return (Float_Type (Copy_Sign (Result, Sign_X)));

end Kf_Asncy;