DataMuseum.dk

top - download

    Length: 5392 (0x1510)
    Types: TextFile
    Names: »B«

└─⟦85b835f43⟧ Bits:30000549 8mm tape, Rational 1000, Xlib rev 6.00
    └─ ⟦0c20f784e⟧ »DATA« 
        └─⟦1abbe589f⟧ 
            └─⟦059497ac5⟧ 
                └─⟦this⟧ 

TextFile

with Xlbt_Arithmetic;  
use Xlbt_Arithmetic;  
with Xlbt_Basic;  
use Xlbt_Basic;  
with Xlbt_Reply;  
use Xlbt_Reply;  
with Xlbt_Request;  
use Xlbt_Request;

with Xlbip_Get_Reply;  
use Xlbip_Get_Reply;  
with Xlbip_Internal;  
use Xlbip_Internal;  
with Xlbip_Put_Request;  
use Xlbip_Put_Request;

package body Xlbp_Selection is
------------------------------------------------------------------------------
-- X Library Selections
--
-- Xlbp_Selection - Control of user selections
------------------------------------------------------------------------------
-- Copyright 1989 - 1991 by Rational, Santa Clara, California.
-- Copyright 1985 - 1989 by the Massachusetts Institute of Technology
--
--                  All Rights Reserved.
--
-- Permission to use, copy, modify, and distribute this software and its
-- documentation for any purpose and without fee is hereby granted,
-- provided that the above copyright notice(s) appear in all copies and that
-- both that copyright notice(s) and this permission notice appear in
-- supporting documentation, and that the names of MIT or Rational not be
-- used in advertising or publicity pertaining to distribution of the software
-- without specific, written prior permission.
--
-- MIT and Rational disclaim all warranties with regard to this software,
-- including all implied warranties of merchantability and fitness, in no
-- event shall MIT or Rational be liable for any special, indirect or
-- consequential damages or any damages whatsoever resulting from loss of use,
-- data or profits, whether in an action of contract, negligence or other
-- tortious action, arising out of or in connection with the use or performance
-- of this software.
------------------------------------------------------------------------------

--\f

    procedure X_Convert_Selection (Display   : X_Display;  
                                   Selection : X_Atom;  
                                   Target    : X_Atom;  
                                   Property  : X_Atom;  
                                   Requestor : X_Window;  
                                   Time      : X_Time) is  
    begin

----Lock the display.

        Lock_Display (Display);  
        begin

----Send the request.

            Put_X_Convert_Selection_Request  
               (Display, (Kind      => Convert_Selection,  
                          Length    => X_Convert_Selection_Request'Size / 32,  
                          Pad       => 0,  
                          Requestor => Requestor,  
                          Selection => Selection,  
                          Target    => Target,  
                          Property  => Property,  
                          Time      => Time));

----Catch exceptions.

        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;

----Unlock; sync; return.

        Unlock_Display (Display);  
        Sync_Handle (Display);

    end X_Convert_Selection;

--\f

    function X_Get_Selection_Owner (Display   : X_Display;  
                                    Selection : X_Atom) return X_Window is  
        Rep   : X_Reply_Contents;  
        Succ  : X_Status;  
        Owner : X_Window;  
    begin

----Lock the display.

        Lock_Display (Display);  
        begin

            Put_X_Get_Selection_Owner_Request  
               (Display, (Kind   => Get_Selection_Owner,  
                          Length => X_Get_Selection_Owner_Request'Size / 32,  
                          Pad    => 0,  
                          Id     => Selection));

----Get the reply.

            Get_Reply (Display => Display,  
                       Code    => Get_Selection_Owner,  
                       Reply   => Rep,  
                       Extra   => 0,  
                       Discard => True,  
                       Status  => Succ);  
            if Succ = Failed then  
                Owner := None_X_Window;  
            else  
                Owner := Rep.Get_Selection_Owner.Owner;  
            end if;

----Catch exceptions.

        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;

----Unlock; sync; return.

        Unlock_Display (Display);  
        Sync_Handle (Display);  
        return Owner;

    end X_Get_Selection_Owner;

--\f

    procedure X_Set_Selection_Owner (Display   : X_Display;  
                                     Selection : X_Atom;  
                                     Owner     : X_Window;  
                                     Time      : X_Time) is  
    begin

----Lock the display.

        Lock_Display (Display);  
        begin

            Put_X_Set_Selection_Owner_Request  
               (Display, (Kind      => Set_Selection_Owner,  
                          Length    => X_Set_Selection_Owner_Request'Size / 32,  
                          Pad       => 0,  
                          Selection => Selection,  
                          Window    => Owner,  
                          Time      => Time));

----Catch exceptions.

        exception  
            when others =>  
                Unlock_Display (Display);  
                raise;  
        end;

----Unlock; sync; return.

        Unlock_Display (Display);  
        Sync_Handle (Display);

    end X_Set_Selection_Owner;

--\f

end Xlbp_Selection;