DataMuseum.dk

Presents historical artifacts from the history of:

Rational R1000/400 Tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Rational R1000/400 Tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - download
Index: ┃ B T ┃

⟦ef74f54a4⟧ TextFile

    Length: 2242 (0x8c2)
    Types: TextFile
    Names: »B«

Derivation

└─⟦516dceb10⟧ Bits:30000751 8mm tape, Rational 1000, RCI_VADS
    └─ ⟦9a14c9417⟧ »DATA« 
        └─⟦this⟧

TextFile

separate (Library_Extensions)
procedure Acquire_Visibility  
             (Imported_View     :        String;
              Into_View         :        String;
              Remote_Connection :        Rci.Context;
              Status            : in out Simple_Status.Condition) is

    Directory_Result : constant Library_Interface.String_Result :=
       Library_Interface.Remote_Directory (View => Into_View);

    View_Directory : constant String :=
       Su.Lower_Case (Directory_Result.Result (1 .. Directory_Result.Size));

    Imported_Directory_Result : constant Library_Interface.String_Result :=
       Library_Interface.Remote_Directory (View => Imported_View);

    Imported_View_Directory : constant String :=
       Su.Lower_Case (Imported_Directory_Result.Result
                         (1 .. Imported_Directory_Result.Size));

    Import_Command : constant String :=
       "a.path -L " & View_Directory & " -i " & Imported_View_Directory;

begin

    Simple_Status.Initialize (Status);

    -- Sanity check
    -- Don't try and import a view into itself!  VADS allows it but I don't
    -- know what will happen if you do it.  Sounds like a possible infinite
    -- loop when searching the paths????
    --
    if View_Directory = Imported_View_Directory then
        return;
    end if;

    Log.Put_Line  
       (Message => "Executing remote procedure: Acquire_Visibility",
        Kind    => Profile.Sharp_Msg);

    Log.Put_Line  
       (Message => "Executing remote command: " & Import_Command,
        Kind    => Profile.Sharp_Msg);

    Rci.Execute_Command  
       (Command_Line          => Import_Command,
        Remote_Connection     => Remote_Connection,
        Status                => Status,
        Error_Pattern         => "",
        Parse_Error_Output    => False,
        Parse_Standard_Output => False,
        Show_Parsed_Output    => True,
        Trace_Command         => Trace_Rci_Commands);

    if Simple_Status.Error (Status) then
        Log.Put_Line  
           (Message => Simple_Status.Message (Status),
            Kind    => Profile.Negative_Msg);

        Set_Status  
           (Status  => Status,  
            Message => "");
        return;
    end if;

end Acquire_Visibility;