DataMuseum.dk

top - download

    Length: 2205 (0x89d)
    Types: TextFile
    Names: »B«

└─⟦a7d1ea751⟧ Bits:30000550 8mm tape, Rational 1000, !users!projects 94_04_11
    └─ ⟦129cab021⟧ »DATA« 
        └─⟦this⟧ 

TextFile

with Expression, More_Statements, Scanner, Object, Printer;
package body Statements is

    type Node_Structure is
        record
            Rule : Natural range 0 .. 2 := 0;
            Expr : Expression.Node := Expression.Empty_Node;
            More : More_Statements.Node := More_Statements.Empty_Node;
            Line : Natural;
        end record;

    procedure Parse (N : in out Node) is
    begin  
        N := new Node_Structure;
        N.Line := Scanner.Get_Line_Number;
        if Expression.Is_First (Scanner.Get_Token) then
            N.Rule := 1;
            Expression.Parse (N.Expr);
            More_Statements.Parse (N.More);
        else
            case Scanner.Get_Token is
                when Scanner.T_Renvoyer =>
                    N.Rule := 2;
                    Scanner.Next;
                    Expression.Parse (N.Expr);
                when others =>  
                    null;  
            end case;
        end if;
    end Parse;

    procedure Unparse (N : in Node) is
    begin
        Scanner.Set_Line_Number (N.Line);
        case N.Rule is
            when 0 =>
                null;
            when 1 =>
                Expression.Unparse (N.Expr);
                More_Statements.Unparse (N.More);
            when 2 =>
                Printer.Write ("renvoyer");
                Expression.Unparse (N.Expr);
        end case;
    end Unparse;

    function Is_First (T : Scanner.Token) return Boolean is
        use Scanner;
    begin
        return T = T_Renvoyer or else Expression.Is_First (T);
    end Is_First;

    function Interpret (N : Node;
                        Inherited : Object.Reference := Object.Void_Reference)
                       return Object.Reference is
        Result : Object.Reference;
    begin  
        Scanner.Set_Line_Number (N.Line);
        case N.Rule is
            when 0 =>
                Result := Inherited;
            when 1 =>
                Result := Expression.Interpret (N.Expr);
                Result := More_Statements.Interpret (N.More, Result);
            when 2 =>
                Result := Expression.Interpret (N.Expr);
        end case;
        return Result;
    end Interpret;
end Statements;