DataMuseum.dk

Presents historical artifacts from the history of:

Bogika Butler

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Bogika Butler

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦0a2b6b045⟧ TextFile

    Length: 3200 (0xc80)
    Types: TextFile
    Names: »TLIB.SA«

Derivation

└─⟦909f4eb2b⟧ Bits:30009789/_.ft.Ibm2.50006622.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »TLIB.SA« 
└─⟦ddcd65152⟧ Bits:30009789/_.ft.Ibm2.50006617.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »TLIB.SA«

TextFile

         TTL       V 0.02 EOSPASCAL TEST PRINT
PRINT    IDNT        0,02 EOSPASCAL TEST PRINT
         NOFORMAT
 
         NOLIST
         INCLUDE   RR.FIOEQU.SA
         LIST
 
         XDEF      PRINTTEX
         XDEF      PRINTSTA
         XDEF      PRINTVAR
         XDEF      SETTSTFL
         XDEF      GETTSTFL
 
         SECTION   9
 
REGS     EQU       RTERRST+8
 
*******************************************************************************
* SUBPROGRAM TESTPRINT
*
* TYPE TXT = ARRAY Æ1..ADDRMAXÅ OF CHAR
*      TXTPTR = ^ ÆÅ TXT
*      BLOCK = ARRAY Æ1..ADDRMAXÅ OF INTEGER1
*      BLOCKPTR = ^ ÆÅ BLOCK
*
* PROCEDURE PRINTTEXT ( T: TXTPTR )
PRINTTEX EQU       *
         TSTOUT    'PRINTTEXT',(A7),12(A7),TSTPAS3
IPRINTTE EQU       *
         MOVE.L    (SP)+,A0            RETURN ADDRESS
         MOVEM.L   D0-D7/A0-A6,REGS(A5) SAVE REGS
         MOVE.L    (SP),D4
         ADD.L     SP,D4               TEXT START
         ADDQ.L    #4,SP
         MOVE.L    (SP)+,D2            TEXT LENGTH
         MOVE.L    #KNLTXT,D5
         TRAP      #EOSKNL             PRINT TEXT
         MOVEM.L   REGS(A5),D0-D7/A0-A6 RESTORE REGS
         JMP       (A0)                RETURN
*
* PROCEDURE PRINTSTACK ( T: TXTPTR )
PRINTSTA EQU       *
         TSTOUT    'PRINTSTACK',(A7),12(A7),TSTPAS3
         MOVE.L    (SP)+,A1            RETURN ADDRESS
         BSR.S     IPRINTTE
         MOVE.L    SP,D4               STACK START
         MOVE.L    TVAL(A5),D2
         SUB.L     D4,D2               STACK LENGTH
         MOVE.L    #KNLHEX,D5
         TRAP      #EOSKNL             PRINT STACK
         MOVEM.L   REGS(A5),D0-D7/A0-A6 RESTORE REGS
         JMP       (A1)                RETURN
*
* PROCEDURE PRINTVAR ( T: TXTPTR; V: BLOCKPTR )
PRINTVAR EQU       *
         TSTOUT    'PRINTVAR',(A7),20(A7),TSTPAS3
         MOVE.L    (SP)+,A1            RETURN ADDRESS
         MOVE.L    12(SP),-4(SP)       EXCHANGE PARAMS
         MOVE.L    4(SP),12(SP)             .
         MOVE.L    -4(SP),4(SP)             .
         MOVE.L    8(SP),-4(SP)             .
         MOVE.L    (SP),8(SP)               .
         MOVE.L    -4(SP),(SP)              .
         ADDI.L    #8,(SP)                  .
         SUBI.L    #8,8(SP)                 .
         BSR       IPRINTTE
         MOVE.L    (SP),D4
         ADD.L     SP,D4               VAR START
         ADDQ.L    #4,SP
         MOVE.L    (SP)+,D2            VAR LENGTH
         MOVE.L    #KNLHEX,D5
         TRAP      #EOSKNL             PRINT VAR
         MOVEM.L   REGS(A5),D0-D7/A0-A6 RESTORE REGS
         JMP       (A1)                RETURN
*
* PROCEDURE SETTSTFLG ( FLG: INTEGER )
SETTSTFL EQU       *
         MOVE.L    (SP)+,A1
         MOVE.L    (SP)+,D0
         MOVE.B    D0,TSTFLG(A5)
         JMP       (A1)
*
* FUNCTION GETTSTFLG: INTEGER
GETTSTFL EQU       *
         MOVE.L    (SP)+,A1
         MOVE.L    #0,D0
         MOVE.B    TSTFLG(A5),D0
         MOVE.L    D0,(SP)
         JMP       (A1)
         END
«eof»