DataMuseum.dk

top - metrics - download

    Length: 3712 (0xe80)
    Types: TextFile
    Names: »BOBJ.SA«

└─⟦909f4eb2b⟧ Bits:30009789/_.ft.Ibm2.50006622.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »BOBJ.SA« 
└─⟦ddcd65152⟧ Bits:30009789/_.ft.Ibm2.50006617.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »BOBJ.SA« 

TextFile

           NOLIST
           INCLUDE     RR.FIOEQU.SA
           LIST
           NOFORMAT
 
           TTL         V 0.06   68K EOS PASCAL INITIALIZE RUNTIME ENVIRONMENT
BOBJ       IDNT          0,06   68K EOS PASCAL INITIALIZE RUNTIME ENVIRONMENT
 
           SECTION 8
*
*****************************************************************************
*
*
*          FUNCTION:
*                  THE ROUTINE INITIALIZE THE EOS PASCAL RUNTIME ENVIRONMENT
*
*          REGISTERS:
*          ON ENTRY:
*
*                  D0   FUNCTION
*                  D2   IMPLICIT/EXPLICIT DEALLOC
*                  D3   NUMBER OF FORMALS OR VECTOR NUMBER
*                  D4   DEPENDING ON FUNCTION
*                  D5   FREED BYTES IF FUNCTION = DEALLOC
*
*                  D7   RETURN ADDRESS = -(D7)+.PBOBJ+8
*
*                  A5   FIRST TEMP
*                  A6   TOP VALUE
*                  A7   LAST VALUE
*
*          MODIFIED REGISTERS
*
*                     0 1 2 3 4 5 6 7
*                  A: *     * * * * *
*                  D:       *
*
*          EXTERNALS:
*
*                  .PBOBJ        DEF
*                  .PLJSR        DEF
*                  .PTRAP        REF
*                  .PALSTS       REF
*
*
***************************************************************************
*
           XDEF    .PBOBJ
           XDEF    .PLJSR
           XREF    .PTRAP
           XREF    .PALSTS
 
 
.PBOBJ     EQU     *             ENTRY POINT
           TST     D0            IF D0 = 0 THEN
           BEQ     .PTRAP        CALL TRAP HANDLER
 
           NEG.L   D7
           LEA     .PBOBJ+8(PC,D7.L),A0  A0 := RETURN ADDRESS
           MOVE.L  A7,LVAL-(RTDSZ+8)(A7)
           LEA     -(RTDSZ+8)(A7),A7 A7:= A7-RMASIZE
           MOVEM.L D0/D2/D3/D4/D5/A5/A6,FUNC1(A7)
           MOVE.L  A6,VALPTR(A7)
           MOVEA.L A7,A5         A5:=GLOBALBASE:= A7
         MOVE.B   #$00,TSTFLG(A5)
         TSTOUT 'BOBJ11',(A7),(A6),TSTRTS1
           MOVEA.L A7,A6         A6:=CLOBALBASE:= A7
           CLR.L   SC(A5)        STATEMENT COUNTER:= 0
           MOVE.L  FTEMP(A5),A3  A3:= FIRSTTEMP
           MOVE.L  #-1,(A3)+     HEAP.LENGTH:= -1
           CLR.L   (A3)+         HEAP.LIST:= 0
           MOVE.L  A3,HP(A5)     HEAPPOINTER:=A3:=FIRSTTEMP+8
           MOVE.W  #7,D3         DISPLAY LEVEL
           LEA     DL0(A5),A3    0-7 := 0
BOBJ1      CLR.L   (A3)+
           DBF     D3,BOBJ1
           CLR.L   RMAOBCDS(A5)  OBJ CALL DESC:= 0
           CLR.L   TOPEXCDS(A5)  TOP EXCP DESC:= 0
           CLR.B   INEXC(A5)     IN EXCEPTION:= 0
           CLR.L   EXCPR(A5)     EXCEPTION RESULT:= 0
           CLR.L   EXCPR+4(A5)
           MOVE.L  TVAL(A5),D3
           ADD.L   #(1<<22)-1,D3 NEXT REQUEST ADDR:=
           AND.L   #-(1<<22),D3  ROUNDUP(TOPVAL,2**22)
           MOVE.L  D3,NRA(A5)
           MOVE.B  #2,NMMU(A5)   NEXT MMU:=2
           CLR.L   TMD(A5)       TOP MAP DESC:= NIL = 0
           LEA     .PLJSR(PC),A3 INIT LONG JSR PTR
 
*
* CALL FLOATING POINT INIT IF NEEDED
*
           BSR     INITFP
         TSTOUT 'BOBJ12',SC(A5),RTDSZ(A5),TSTRTS1
           JMP     (A0)
*
* .PLJSR LONG JSR ROUTINE
*
.PLJSR     EQU     *
           MOVE.L  (A7),A4       GET RETURN ADDRESS
           ADD.L   #4,(A7)       CORRECT IT ON STACK
           ADD.L   (A4),A4       CALCULATE DESTINATION
           JMP     (A4)          GO TO IT
*
* FINIT THE COMMON SECTION USED FOR LINKAGE TO THE FLOATING POINT
* PACKAGE IF PRESENT
*
FINIT      SECTION 8
INITFP     RTS                   RETURN TO INIT UNLESS OVERWRITTEN
 
           END
 
 
 
 
 
 
«eof»