DataMuseum.dk

Presents historical artifacts from the history of:

Bogika Butler

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about Bogika Butler

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦fe4837051⟧ TextFile

    Length: 2560 (0xa00)
    Types: TextFile
    Names: »VPF.SA«

Derivation

└─⟦909f4eb2b⟧ Bits:30009789/_.ft.Ibm2.50006622.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »VPF.SA« 
└─⟦ddcd65152⟧ Bits:30009789/_.ft.Ibm2.50006617.imd Mogens Pelles Zilog 80,000 / EOS projekt
    └─⟦this⟧ »VPF.SA«

TextFile

           NOLIST
           INCLUDE     RR.FIOEQU.SA
           INCLUDE     RR.RTEQU.SA
           LIST
           NOFORMAT
 
           TTL         V 0.04   68K EOS PASCAL VALUE PARAMETER FIXED LENGTH
VPF        IDNT          0,04   68K EOS PASCAL VALUE PARAMETER FIXED LENGTH
 
           SECTION 8
*
*****************************************************************************
*
*
*          FUNCTION:
*                  CHECKS LENGTH OF NEXT FORMAL VALUE PARAMETER, STORE ITS
*                  ADDRESS IN ADDRESS VARIABLE, GIVEN IN A0, AND ADVANCES
*                  LASTVAL. THE ROUTINE CALLS EXCEPT IN CASE OF LENGTH ERROR.
*
*          REGISTERS:
*          ON ENTRY:
*
*                  D0   EXPECTED LENGTH
*                  A0   ADDRESS
*
*          ON EXIT
*                  D0   0: NO MORE VALUE ARG  1: VALUE ARG PROCESSED
*
*          MODIFIED REGISTERS
*
*                     0 1 2 3     4 5 6 7
*                  A:   * *
*                  D: * *
*
*          EXTERNALS:
*
*                  .PVPF         DEF
*                  .PEXCEPT      REF
*
*
***************************************************************************
*
           XDEF    .PVPF
 
           XREF    .PEXCEPT
 
 
.PVPF      EQU     *             ENTRY POINT
         TSTOUT 'VPF-ENTER',FTEMP(A5),RTERRST(A5),TSTRTS3
           SUB.B   #1,EXCPR+ARGNO(A5) NEXT ARGNO
           MOVEA.L VALPTR(A5),A1 A1:= LATEST VALARG
           CMPA.L  LVAL(A5),A1   IF VALPTR>LASTVAL THEN
         IF <GT>   THEN.L
           MOVEA.W -(A1),A2      A2:= NEXT LENGTH
           MOVE.L  A1,D1         D1:= NEXT VALARG :=
           SUB.L   A2,D1         EVEN(LATEST VALARG-NEXTLENGTH-2)
           BCLR    #0,D1
         TSTOUT 'VPF-NEXT',0,0,TSTRTS3
 
           CMP.L   LVAL(A5),D1
         IF <LT>   THEN.S        IF NEXTVAL<LASTVAL
           MOVE.L  #VALARGER,D0  THEN VALARG ERROR
           BSR     .PEXCEPT      EXCEPTION
         ENDI
 
           CMP.L   A2,D0         IF NEXT LENGTH <> EXPECTED LENGTH THEN
         IF <NE>   THEN.S
           MOVE.L  #VALSIZER,D0
           BSR     .PEXCEPT      EXCEPTION
 
         ENDI
 
           MOVE.L  D1,VALPTR(A5) ADVANCE VALPTR
           MOVE.L  D1,(A0)       AND STORE ADDRESS
           MOVEQ   #1,D0
         ELSE.S
           MOVEQ   #0,D0
         ENDI
         TSTOUT 'VPF11',VALPTR(A5),RTERRST(A5),TSTRTS1
         TST       D0                  FOR TEST ONLY
           RTS
 
           END
 
 
 
 
«eof»