|
DataMuseum.dkPresents historical artifacts from the history of: Q1 computer |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about Q1 computer Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 13904 (0x3650)
Types: Q1_Text, reclen=79
Notes: q1file
Names: »V81«
└─⟦256585323⟧ Bits:30008759 50001598
└─⟦this⟧ »V81«
/* V81 SKRIVER UT EN VERIFIKATIONSFÖRTEKNING
ÖVER SAMTLIGA KONTERINGAR I TRANSFIL
V 0:1
PRG JÅ 780915 */
DCL AREAP POINTER,
1 VERSTR BASED(AREAP),
2 KONTO FIXED(11),
2 VERNR FIXED(5),
2 BOKDAG FIXED(5),
2 PERDAG FIXED(5),
2 BELOPP FIXED(11),
2 TEXT CHAR(13),
TRANSL BINARY INIT(34);
/* 34 BYTES */
DCL 1 AREA,
2 CH(100) CHAR(100);
/* 10 000 BYTES */
DCL NR BINARY,
T5 CHAR(5),
MAX BINARY,
RCODE BINARY,
TRANSFIL FILE,
T13 CHAR(13),
KONTOR CHAR(13),
FELTAB(10) CHAR(47) INIT(
'SEKTOR HEADER NOT FOUND',
'READ ERROR',
'WRITE ERROR',
'KEY NOT FOUND',
'NÅGON DISKETT HAR FLYTTATS',
'EN AV FILERNA ÄR FÖR LITEN',
'EN AV FILERNA ÄR SKRIVSKYDAD'),
R BINARY INIT(0),
SIDA BINARY INIT(1),
T14 CHAR(14),
ANT_KONT BINARY INIT(0),
NAMN(2) CHAR(10) INIT('KVV/KWAROS','AROS'),
T25 CHAR(25) INIT('VERIFIKATIONSFÖRTECKNING'),
T60 CHAR(62) INIT(
'BOKDAG PERDAG VER. KONTO BELOPP TEXT'),
P POINTER,
D BASED(P) CHAR(6),
DATUM CHAR(6),
PP POINTER,
1 STRX BASED(PP),
2 X CHAR(2),
2 Y CHAR(2),
2 FIRMA CHAR(1),
2 OP_KOD BINARY,
2 RADANT BINARY,
VERSION CHAR(47) INIT(' V8 Version 1.2 790412');
FILOPEN:PROC;
OPEN TRANSFIL;
CALL SEOF(TRANSFIL);
MAX=UNSPEC(TRANSFIL);
UNSPEC(TRANSFIL)=0;
INPOSTER=0;
RETURN;
END;
POST:PROC;
IF INPOSTER=0 THEN DO;
IF MAX=0 THEN DO;
RCODE=10;
RETURN;
END;
J=255;
IF J>MAX THEN J=MAX;
MAX=MAX-J;
CALL RD(TRANSFIL,AREA,J,RCODE);
IF RCODE¬=0 THEN PUT SKIP LIST('LÄSFEL I TRANSFIL',RCODE);
INPOSTER=J-1;
AREAP=ADDR(AREA);
END;
ELSE DO;
INPOSTER=INPOSTER-1;
UNSPEC(AREAP)=UNSPEC(AREAP)+TRANSL;
END;
RETURN;
END;
KONTORED:PROC;
T13=KONTO;
T5=SUBSTR(T13,1,5);
IF SUBSTR(T13,9,3)¬='000' THEN DO;
KONTOR=T5 CAT '.---.' CAT SUBSTR(T13,9,3);
END;
ELSE DO;
KONTOR=T5;
END;
IF SUBSTR(T13,6,3)¬='000' THEN DO;
SUBSTR(KONTOR,6,4)='.' CAT SUBSTR(T13,6,3);
END;
RETURN;
END;
RUB:PROC;
IF (VERNR=NR) & (R¬=0) THEN DO;
PUT SKIP LIST('*** FORTSÄTTER PÅ NÄSTA SIDA ***');
R=R-1;
NR=-1;
END;
PUT SKIP(R+3) EDIT(NAMN(FIRMA-7))(A(20));
IF Y='2 ' THEN PUT EDIT('PRELIMINÄR')(A(11));
PUT EDIT(T25)(A(35))('19')(A)(DATUM)(A(2))('-')(A)(SUBSTR(DATUM,3,2))
(A)('-')(A)(SUBSTR(DATUM,5,2))(A(4))
('SID')(A(4))(SIDA)(A) SKIP(2) EDIT(T60)(A);
R= RADANT - 5;
SIDA=SIDA+1;
RETURN;
END;
SKRIV:PROC;
PUT SKIP;
IF VERNR¬=NR THEN PUT SKIP EDIT(BOKDAG+780000)(A(8));
ELSE PUT EDIT(' ')(A(8));
IF BOKDAG¬=PERDAG THEN PUT EDIT(PERDAG+780000)(A(8));
ELSE PUT EDIT(' ')(A(8));
IF VERNR¬=NR THEN PUT EDIT(VERNR)(P'ZZZ9',X(3));
ELSE PUT EDIT(' ')(A(7));
PUT EDIT(KONTOR)(A(13))(T14)(A(16));
IF VERNR¬=NR THEN DO;
PUT EDIT(TEXT)(A);
R=R-1;
NR=VERNR;
END;
R=R-1;
RETURN;
END;
/* H Ä R B Ö R J A R H U V U D P R O G R A M M E T */
START: CALL DATCHECK(DATUM);
IF DATUM='0 ' THEN CALL PLOAD('Q ');
UNSPEC(P)=16570;
UNSPEC(PP)=16616;
D='0';
PUT FILE(D) SKIP EDIT(VERSION)(A(96))('UTSKRIFT AV VER.FÖRTECKNING')
(A(45));
CALL CORED(0);
CALL FILOPEN;
IF MAX=0 THEN GO TO SLUT;
L1: CALL POST;
IF RCODE¬=0 THEN GO TO FEL;
ANT_KONT=ANT_KONT+1;
IF R<8 & VERNR¬=NR THEN CALL RUB;
IF R<5 THEN CALL RUB;
CALL KONTORED;
CALL BELRED(BELOPP,T14);
CALL SKRIV;
GO TO L1;
FEL: IF RCODE=10 THEN DO;
IF R¬=0 THEN DO;
PUT SKIP(2) EDIT('ANTAL KONTERINGAR:')(A(19))(ANT_KONT)(A);
PUT SKIP(R-2);
END;
GO TO SLUT;
END;
PUT SKIP(3) LIST('LÄSFEL I TRANSFIL',FELTAB(RCODE)) SKIP(R-3);
SLUT: D=DATUM;
IF Y¬='2 ' THEN CALL PLOAD('V9 ');
CALL PLOAD('Q ');
END;