DataMuseum.dk

top - metrics - download

    Length: 4514 (0x11a2)
    Types: TextFile
    Notes: R1k Text-file segment

└─⟦8527c1e9b⟧ Bits:30000544 8mm tape, Rational 1000, Arrival backup of disks in PAM's R1000
    └─⟦cfc2e13cd⟧ »Space Info Vol 2« 
        └─⟦7f12c20f4⟧ 
            └─⟦this⟧ 

TextFile

JEU Mon_jeu

ACTION

   Aller
   Allumer
   Decrire
   Manger
   
DEFINITION

   STRUCTURE    Perso ( CHAINE Description, ENTIER Pt_Vie )
   
   ENUMERE      Lumiere ( Eteind, Allume )
   STRUCTURE    Piece ( CHAINE Description, Lumiere Eclairage)
   
   STRUCTURE    Aliment ( CHAINE Description )
   STRUCTURE    Luminaire ( CHAINE Description )

PRESENTATION

   Joueur       OBJET Perso AVEC ("Coucou",100)
   
   Salon        OBJET Piece AVEC ("Le salon... Il y a une issue au nord.", Allume )
   Hall         OBJET Piece AVEC ("Le hall... Il y a une issue a l'est.", Allume )
   Cuisine      OBJET Piece AVEC ("La cuisine... Il y a une issue au sud.", Eteind)
   Chambre      OBJET Piece AVEC ("La chambre... Il y a une issue a l'ouest", Allume)
   
   Pizza        OBJET Aliment AVEC ("Une joile Pizza...")
   
   Lampe        OBJET Luminaire AVEC ("Cool")

   Position_Joueur OBJET Piece INIT Salon
   
LIAISON

   CONNEXION ( Nord, Sud, Est, Ouest )
   
   CREER_CONNEXION ( Salon, Hall, Nord, Delie)
   CREER_CONNEXION ( Hall, Salon, Sud, Delie)
   CREER_CONNEXION ( Hall, Cuisine, Est, Lie)
   CREER_CONNEXION ( Cuisine, Hall, Ouest, Delie)
   CREER_CONNEXION ( Cuisine, Chambre, Sud, Lie)
   CREER_CONNEXION ( Chambre, Cuisine, Nord, Delie)
   CREER_CONNEXION ( Chambre, Salon, Ouest, Lie)
   CREER_CONNEXION ( Salon, Chambre, Est, Delie)
   
   CREER_LIEN ( Chambre, Pizza, Lie )

INTRODUCTION

   AFFICHER ( "Je suis a la recherche d'une pizza dans ma maison..." )

ANIMATION_GENERALE

   POUR 1 ENTREE FAIRE
      Joueur.Pt_Vie := Joueur.Pt_Vie - 10
   FINPOUR
   
   POUR 2 ENTREE FAIRE
      SI Joueur.Pt_Vie >= 80 ALORS
         AFFICHER ( "Il faut se depecher! J'ai faim..." )
      SINON
         SI Joueur.Pt_Vie >= 60 ALORS
            AFFICHER ( "La faim me tenaille." )
         SINON
            SI Joueur.Pt_Vie >= 40 ALORS
               AFFICHER ( "Mon estomac se tortille dans mes talons." )           
            SINON
               SI Joueur.Pt_Vie >= 20 ALORS
                  AFFICHER ( "Je vois tout flou, la faim me diminue." )
               FINSI
            FINSI
         FINSI
      FINSI
   FINPOUR
   
   POUR 2 ENTREE FAIRE
      SI ETAT_CONNEXION (Salon,Nord) = DELIE ALORS
         LIE_CONNEXION (Salon,Nord)
         SI Position_Joueur = Salon ALORS
            AFFICHER ( "Le passage au nord s'est ouvert." )
         SINON
            AFFICHER ( "Le passage au nord s'est ferme." )
         FINSI
      SINON
         DELIE_CONNEXION (Salon,Nord)
         SI Position_Joueur = Salon ALORS
            AFFICHER ( "Le passage au nord s'est ferme." )
         SINON
            AFFICHER ( "Le passage au nord s'est ouvert." )
         FINSI
      FINSI
   FINPOUR

   SI Joueur.Pt_Vie <= 0 ALORS
      AFFICHER ( "Je meurt... (de fain)" )
      FIN
   FINSI

   SI Position_Joueur = Hall ALORS
      AFFICHER ("Vhoua")
      Joueur.Pt_Vie := Joueur.Pt_Vie - 10
   FINSI

ANIMATION_GLOBALE   

   SI [ Aller COMP ] OU [ COMP ] ALORS
      SI EXISTE_CONNEXION ( Position_Joueur, COMP ) = VRAI ALORS
         SI ETAT_CONNEXION ( Position_Joueur, COMP ) = LIE ALORS
            Position_Joueur := DESTINATION_CONNEXION ( Position_Joueur, COMP )
            SI Position_Joueur.Eclairage = Allume ALORS
               AFFICHER ( Position_Joueur.Description )
            SINON
               AFFICHER ( "Il fait tout noir." )
            FINSI
         SINON
            AFFICHER ( "Le passage est bloque." )
         FINSI
      SINON
         AFFICHER ( "Il n'y pas d'issue dans cette direction" )
      FINSI
   FINSI    

   SI [ Decrire ] ALORS
      SI Position_Joueur.Eclairage = Allume ALORS
         AFFICHER ( Position_Joueur.Description )
         AFFICHER ("Il n'y a rien ici.")
      SINON
         AFFICHER ( "Il fait tout noir." )
      FINSI
   FINSI

   SI [ Decrire COMP ] ALORS
      SI ETAT_LIEN ( COMP, Joueur ) = LIE OU ETAT_LIEN ( COMP, Position_Joueur ) = LIE ALORS
         AFFICHER ( COMP.Description )
      SINON
         AFFICHER ( "???" )
      FINSI
   FINSI

ANIMATION_LOCALE

   SI [ Manger Pizza ] ALORS
      SI Position_Joueur = Chambre ALORS
         AFFICHER ( "Oh c'est tres bon..." )
         FIN
      SINON
         AFFICHER ( "Oh oui j'aimerai en manger une toute grosse" )
      FINSI
   FINSI

   SI [ Allumer Lampe ] ET Position_Joueur.Eclairage = Eteind ALORS
      Position_Joueur.Eclairage := Allume
   FINSI

   SI [ Decrire ] ET Position_Joueur = Chambre ALORS
      AFFICHER ( "Oh il y a une jolie pizza." )
   FINSI
FIN