⟦adf2924c4⟧

E3 Source Code



with Ada_Program;
package Compilation_Units is

    -- LRM 10.1
    --
    -- Compilation units are composed of two distinct parts:
    -- A context clause part and a declarative part.
    -- The context clause part may contain actual context clauses
    -- (with and use clauses) and pragmas.
    -- The declaration associated with a compilation unit can either
    -- be a package, procedure, function, or subunit.

    -- Local Renamings:
    subtype Compilation_Unit is Ada_Program.Compilation_Unit;
    subtype Declaration      is Ada_Program.Declaration;
    subtype Context_Clause   is Ada_Program.Context_Clause;
    ---------------------------------------------------------------


    function Unit_Declaration
                (A_Compilation_Unit : Compilation_Unit) return Declaration;
    -- Returns the package, procedure, or function declaration of the
    -- compilation unit.  (Library and Secondary units as defined in the
    -- LRM.  The operations on declarations can be used to further
    -- decompose these elements.


    function Context_Clause_Elements (Of_Compilation_Unit : Compilation_Unit)
                                     return Ada_Program.Element_Iterator;
    -- Returns a list of context clauses and pragmas that
    -- reside in the context part of the compilation unit.

    -- Context clauses are made up of one or more unit references.
    --
    -- ie  with Bar;       -- has one unit reference
    --     use Foo, Bar;   -- has two named unit references
    --
    -- All context clauses have an Image but only their elements
    -- have a name.


    type Context_Clause_Kinds is
       (A_With_Clause, A_Use_Clause, Not_A_Context_Clause);

    function Context_Clause_Kind
                (A_Context_Clause : Context_Clause) return Context_Clause_Kinds;


    function Referenced_Units (A_Context_Clause : Context_Clause)
                              return Ada_Program.Element_Iterator;
    -- Returns a list of identifier references in a context clause


    function Parent_Compilation_Unit (Of_Program_Element : Ada_Program.Element)
                                     return Compilation_Unit;
    -- Returns the compilation unit that contains a particular
    -- program element. If the PROGRAM_ELEMENT in question is a
    -- compilation unit then this is an identity function.


    function Is_Subunit (A_Compilation_Unit : Compilation_Unit) return Boolean;
    -- Returns true if the compilation unit is a package, subprogram, or task
    -- subunit.


    function Subunit_Parent (Of_Subunit : Compilation_Unit)
                            return Compilation_Unit;
    -- Returns the compilation unit that is the parent unit of the subunit.

    function Body_Stub (Of_Subunit : Compilation_Unit) return Declaration;
    -- Returns the subunit declaration in the parent.

    function Is_Main_Program
                (Procedure_Or_Function : Compilation_Unit) return Boolean;
    -- Returns true if the unit has a pragma Main attached.

    pragma Subsystem (Design_Facility, Closed);
    pragma Module_Name (4, 3571);
    pragma Bias_Key (109);
end Compilation_Units;
DataMuseum.dk

Rational R1000/400

⟦adf2924c4⟧ Ada Source

Derivation

E3 Source Code

E3 Meta Data
